[最適化 Tips] 単位行列

by sekiryou 20 Apr 2010

• Forked from muta244's [最適化 Tips] 変数名の長さによる処理速度の違い
• Diff: 22
• Related works: 21

Tags

最適化
Embed

/**
 * Copyright sekiryou ( http://wonderfl.net/user/sekiryou )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/wett
 */

// forked from muta244's [最適化 Tips] 変数名の長さによる処理速度の違い
package {

import flash.display.*;
import flash.events.*;
import flash.text.*;
import flash.utils.*;

import flash.geom.Matrix;
public class Main extends Sprite
{
    static private const _NUM_TIMES:uint = 1000000;

    private var mtrx:Matrix;
    
    private function _init():void
    {
    		mtrx = new Matrix();
        _debug(
            "各テスト " + _NUM_TIMES + " 回処理させた計算結果 [単位 ： ミリ秒]\n" +
            "(誤差は多少生じます)\n"
        );
        
        _measure("ループのみ", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                
            }
        });
        
        _measure("new Matrix(1,0,0,1,0,0)", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                mtrx = new Matrix(1,0,0,1,0,0);
            }
        });
        
        _measure("matrix.identity()", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                mtrx.identity();
            }
        });
        _measure("a=1;b=0;c=0;d=1;tx=0;ty=0", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                mtrx.a = 1;
                mtrx.b = 0;
                mtrx.c = 0;
                mtrx.d = 1;
                mtrx.tx = 0;
                mtrx.ty = 0;
            }
        });
        
        _debug("\n結果については言及しませんので, 各自ご判断ください.");
    }
    
    private var _field:TextField;
    private var _time:uint;
    
    public function Main():void
    {
        _setup();
        _init();
    }
    
    private function _measure(title:String, func:Function, ...params):void
    {
        _time = getTimer();
        func.apply(null, params);
        _time = getTimer() - _time;
        
        _debug("[ " + title + " ] --> " + _time + " ms");
    }
    
    private function _debug(log:String):void
    {
        _field.appendText(log + "\n");
    }
    
    private function _setup():void
    {
        _field = new TextField();
        _field.width = stage.stageWidth - 40;
        _field.height = stage.stageHeight - 60;
        _field.x = 20;
        _field.y = 60;
        
        var format:TextFormat = _field.defaultTextFormat;
        format.font = "_sans";
        _field.defaultTextFormat = format;
        
        addChild(_field);
        
        var button:Sprite = new Sprite();
        button.graphics.lineStyle(1, 0xBBBBBB);
        button.graphics.beginFill(0xEEEEEE);
        button.graphics.drawRoundRect(0, 0, 100, 20, 5, 5);
        button.graphics.endFill();
        
        addChild(button);
        
        button.x = 20;
        button.y = 20;
        button.mouseChildren = false;
        button.buttonMode = true;
        
        var field:TextField = new TextField();
        field.width = 100;
        field.height = 20;
        field.htmlText = "<p align='center'><font face='_sans'>再計算</span></p>";
        
        button.addChild(field);
        
        button.addEventListener(MouseEvent.CLICK, function ():void
        {
            _field.text = "";
            _init();
        });
    }
}

}