Dead Code Preservation :: Archived AS3 works from wonderfl.net

forked from: Container & Sorting [Alternativa3D 7.5 TIPS]

ソートタイプを混合した場合の表示。
球側がBSPで、板側がZsortの場合、板が複雑に区切られてしまう。
おそらく、両者がBSPの場合最適な区切られ方をするが、片方のみだとZsort側が優先的に切られる。
逆に言えば区切られるほうをこれで調節することが可能?
/**
 * Copyright tail_y ( http://wonderfl.net/user/tail_y )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/ssSv
 */

// forked from narutohyper's Container & Sorting  [Alternativa3D 7.5 TIPS]
// forked from narutohyper's Alternativa3D 7.5 Template
package{
	import alternativ7.engine3d.controllers.SimpleObjectController;
	import alternativ7.engine3d.core.Sorting;
	import alternativ7.engine3d.materials.FillMaterial;
	import alternativ7.engine3d.primitives.Plane;
	import alternativ7.engine3d.primitives.Sphere;

	import com.bit101.components.RadioButton;

	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
    
    /**
     * Alternativa3D 7.5
     *
     * Sortモードの切り替え
     *
     * Containerは子オブジェクトを最適な方法でソートするコンテナ
     * ConflictContainerを使用。
     *
     * 各Objectごとに、Object3D.sorting プロパティでソートモードを切り替えます。
     * 切り替えられるSortingは
     * Sorting.DYNAMIC_BSP (バイナリ空間分割によるソート。Polygon欠けが無くなる。重い)
     * Sorting.AVERAGE_Z (カメラからの距離(Z値)によるソート。早いがPolygon欠けが発生する)
     * Sorting.NONE (設定しない・orting.AVERAGE_Z同等?)
     *
     * ...
     * @author narutohyper
     */
    [SWF(backgroundColor="#000000", frameRate="100", width="800", height="600")]
    public class Narutohyper_Container_Sorting2 extends Sprite
    {
        public function Narutohyper_Container_Sorting2():void    {
        
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        
        
        private var sphere:Sphere;
        private var plane:Plane;
        
        private function init(e:Event=null):void {
            removeEventListener(Event.ADDED_TO_STAGE, init);
        
            //AlternativaTemplate作成
            var scene:AlternativaTemplate = new AlternativaTemplate(this);

            //Materialの作成
            var material:FillMaterial = new FillMaterial(0x666666, 1, 0,0x0);
            
            //Plane
            plane = new Plane(300, 300, 4, 4);
            plane.setMaterialToAllFaces(material);
            scene.container.addChild(plane);
            
            sphere = new Sphere();
            sphere.setMaterialToAllFaces(material);
            scene.container.addChild(sphere);
            
            
            //カメラの調整
            //カメラはControllerに関連付けている為、x,y,zで直接位置を指定できないので
            //SimpleController.setObjectPosXYZを使用
            scene.cameraController.setObjectPosXYZ(0,-500,500);
            scene.cameraController.lookAtXYZ(0, 0, 0);
            //ObjectControllerの作成
            //MouseDragで、Objectを回転させる為のController
            var objectController:SimpleObjectController = new SimpleObjectController(stage,plane,100);
            objectController.unbindAll();
            
            scene.onPreRender = function():void {
                objectController.update();
            };
            
            //描画開始
            scene.startRendering();
            
            
            settingPanel();
            

        }
        

        private function settingPanel():void {
            var base:Sprite = new Sprite();
            addChild(base);
            base.graphics.beginFill(0xFFFFFF);
            base.graphics.drawRect(0, 0, 300, 30);
            
            new RadioButton(base, 10, 8, 'NONE', true, onNone);
            new RadioButton(base, 60, 8, 'ZSORT', false, onZsort);
            new RadioButton(base, 110, 8, 'BSP', false, onBsp);
            new RadioButton(base, 160, 8, 'sphereBSP', false, onBspZsort);
            new RadioButton(base, 230, 8, 'planeBSP', false, onZsortBsp);


            function onNone(e:MouseEvent):void {
                plane.sorting = Sorting.NONE;
                sphere.sorting = Sorting.NONE;
            }
            
            function onBsp(e:MouseEvent):void {
                plane.sorting = Sorting.DYNAMIC_BSP;
                sphere.sorting = Sorting.DYNAMIC_BSP;
            }
            
            function onZsort(e:MouseEvent):void {
                plane.sorting = Sorting.AVERAGE_Z;
                sphere.sorting = Sorting.AVERAGE_Z;
            }
            
            function onBspZsort(e:MouseEvent):void {
                sphere.sorting = Sorting.DYNAMIC_BSP;
                plane.sorting = Sorting.AVERAGE_Z;
            }
            
            function onZsortBsp(e:MouseEvent):void {
                sphere.sorting = Sorting.AVERAGE_Z;
                plane.sorting = Sorting.DYNAMIC_BSP;
            }

            
            
        }

    }
    
}


import alternativ7.engine3d.containers.BSPContainer;
import alternativ7.engine3d.containers.ConflictContainer;
import alternativ7.engine3d.containers.DistanceSortContainer;
import alternativ7.engine3d.containers.KDContainer;
import alternativ7.engine3d.containers.LODContainer;
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Camera3D;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.View;

import flash.display.DisplayObjectContainer;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
/**
 * BasicTemplate for Alternativa3D 7.5
 * Alternativa3D 7.5を扱いやすくするためのテンプレートです
 * @author narutohyper & clockmaker
 *
 */

class AlternativaTemplate extends Sprite
{
    /**
     * 子オブジェクトを最適な方法でソートするコンテナ
     * (ConflictContainer)
     */
    public static const CONFLICT:String = 'conflict';
    /**
     * 子オブジェクトをBSP(バイナリ空間分割法)によってソートするコンテナ
     * (BSPContainer)
     */
    public static const BSP:String = 'bsp';
    
    /**
     * 子オブジェクトをカメラからのZ値でソートするコンテナ
     * (DistanceSortContainer)
     */
    public static const ZSORT:String = 'zsort';
    /**
     * KDツリー(http://ja.wikipedia.org/wiki/Kd%E6%9C%A8)によってソートするコンテナ
     * (KDContainer)
     */
    public static const KD:String = 'kd';
    /**
     * detalizationと子オブジェクトの距離でソートするコンテナ(詳細は調査中)
     * (LODContainer)
     */
    public static const LOD:String = 'lod';
    
    /**
     * 3dオブジェクト格納するコンテナインスタンス。
     */
    public var container:Object3DContainer;

    /**
     * ビューインスタンスです。
     */
    public var view:View;
    
    /**
     * カメラインスタンスです。
     */
    public var camera:Camera3D;
    
    /**
     * カメラコントローラーです。
     */
    public var cameraController:SimpleObjectController;
    
    private var _mc:DisplayObjectContainer;
    private var _viewWidth:int;
    private var _viewHeight:int;
    private var _scaleToStage:Boolean;
    private var _containerType:String;
    
    /**
     * 新しい Alternativa3DTemplate インスタンスを作成します。
     * @param    mc
     * @param    containerType
     * @param    viewWidth
     * @param    viewHeight
     * @param    scaleToStage
     */
    public function AlternativaTemplate(mc:DisplayObjectContainer,containerType:String=CONFLICT,viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true)
    {
        
        _mc = mc;
        _mc.addChild(this);

        _containerType = containerType;
        _viewWidth = viewWidth;
        _viewHeight = viewHeight;
        _scaleToStage = scaleToStage;
        
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }


    /**
     * 初期化されたときに実行されるイベントです。
     * 初期化時に実行したい処理をオーバーライドして記述します。
     */
    protected function atInit():void {}


    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング前に実行したい処理をオーバーライドして記述します。
     */
    protected function atPreRender():void {}
    
    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング前に実行したい処理をオーバーライドして記述します。
     */
    private var _onPreRender:Function = function():void{};
    public function get onPreRender():Function { return _onPreRender; }
    public function set onPreRender(value:Function):void
    {
        _onPreRender = value;
    }
    
    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング後に実行したい処理をオーバーライドして記述します。
     */
    protected function atPostRender():void {}
    
    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング後に実行したい処理を記述します。
     */
    private var _onPostRender:Function = function():void{};
    public function get onPostRender():Function { return _onPostRender; }
    public function set onPostRender(value:Function):void
    {
        _onPostRender = value;
    }
    
    
    /**
     * レンダリングを開始します。
     */
    public function startRendering():void
    {
        addEventListener(Event.ENTER_FRAME, onRenderTick);
    }

    /**
    * レンダリングを停止します。
    */
    public function stopRendering():void
    {
        removeEventListener(Event.ENTER_FRAME, onRenderTick);
    }

    /**
     * シングルレンダリング(レンダリングを一回だけ)を実行します。
     */
    public function singleRender():void
    {
        onRenderTick();
    }

    /**
     * @private
     */
    private function init(e:Event = null):void
    {
        removeEventListener(Event.ADDED_TO_STAGE, init);
        // entry point
        stage.scaleMode = StageScaleMode.NO_SCALE;
        stage.align = StageAlign.TOP_LEFT;
        stage.quality = StageQuality.HIGH;
        
        //Root objectの作成
        if (_containerType == CONFLICT) {
            container = new ConflictContainer();
        } else if (_containerType == BSP) {
            container = new BSPContainer();
        } else if (_containerType == ZSORT) {
            container = new DistanceSortContainer();
        } else if (_containerType == KD) {
            container = new KDContainer();
        } else if (_containerType == LOD) {
            container = new LODContainer();
        }
        //Viewの作成
        view = new View(stage.stageWidth, stage.stageHeight);
        view.interactive=true;
        _mc.addChild(view);

        //cameraの作成
        camera = new Camera3D();
        camera.view = view;
        camera.x = 0;
        camera.y = -500;
        camera.z = 0;
        container.addChild(camera);
        
        // Camera controller
        cameraController = new SimpleObjectController(stage, camera, 10);
        cameraController.mouseSensitivity = 0;
        cameraController.unbindAll();
        cameraController.lookAtXYZ(0, 0, 0);
        
        onResize();
        stage.addEventListener(Event.RESIZE, onResize);
        
        atInit();
    }
    
    /**
     * @private
     */    
    private function onResize(e:Event = null):void 
    {
        if (_scaleToStage)
        {
            view.width = stage.stageWidth;
            view.height = stage.stageHeight;
        } 
        else
        {
            view.width = _viewWidth;
            view.height = _viewHeight;
        }
    }
    
    /**
     * @private
     */    
    private function onRenderTick(e:Event = null):void 
    {
        atPreRender();
        _onPreRender();
        cameraController.update();
        camera.render();
        atPostRender();
        _onPostRender();
    }
    
    
}