forked from: あなたのイベントハンドラを教えて！
あなたのイベントハンドラを教えて！
*
* 複数のイベント＆複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
/**
* Copyright bkzen ( http://wonderfl.net/user/bkzen )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/sqhL
*/
// forked from clockmaker's あなたのイベントハンドラを教えて！
/**
* あなたのイベントハンドラを教えて！
*
* 複数のイベント＆複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
*/
package {
import flash.display.Sprite;
import flash.events.MouseEvent;
public class FlashTest extends Sprite {
private var _btnA:MyButton;
private var _btnB:MyButton;
private var _btnC:MyButton;
private var _label:MyTextField;
public function FlashTest() {
// ボタンを作成
_build();
// 自分流のイベントハンドラを記述ください
// クリック
_btnA.addEventListener(MouseEvent.CLICK, click::onMouseEvent);
_btnB.addEventListener(MouseEvent.CLICK, click::onMouseEvent);
_btnC.addEventListener(MouseEvent.CLICK, click::onMouseEvent);
// ロールオーバー
_btnA.addEventListener(MouseEvent.ROLL_OVER, rollover::onMouseEvent);
_btnB.addEventListener(MouseEvent.ROLL_OVER, rollover::onMouseEvent);
_btnC.addEventListener(MouseEvent.ROLL_OVER, rollover::onMouseEvent);
}
rollover function onMouseEvent(e:MouseEvent):void
{
_label.text = e.target.text + " をロールオーバーしました";
}
click function onMouseEvent(e:MouseEvent): void
{
_label.text = e.target.text + " をクリックしました";
}
/**
* インターフェースを作る
*/
private function _build():void {
_label = new MyTextField();
_label.x = 150; _label.y = 280;
addChild(_label);
_btnA = new MyButton();
_btnA.text = "Button A";
_btnA.x = 70; _btnA.y = 230;
addChild(_btnA);
_btnB = new MyButton();
_btnB.text = "Button B";
_btnB.x = 190; _btnB.y = 230;
addChild(_btnB);
_btnC = new MyButton();
_btnC.text = "Button C";
_btnC.x = 310; _btnC.y = 230;
addChild(_btnC);
}
}
}
namespace rollover = "rollover";
namespace click = "click";
import flash.display.*
import flash.text.*;
/**
* MyButton クラスはボタン的な挙動をするようにしたSpriteです。
*/
class MyButton extends Sprite {
private var _text:MyTextField;
/**
* 新しい MyButton インスタンスを作成します。
*/
public function MyButton(){
graphics.beginFill(0x000000);
graphics.drawRoundRect(0, 0, 100, 30, 5, 5);
addChild(_text = new MyTextField);
buttonMode = true;
}
/**
* ボタンの文言を設定します。
*/
public function set text(value:String):void {
_text.text = value;
_text.x = (100 - _text.textWidth) / 2;
_text.y = (30 - _text.textHeight) / 2;
}
public function get text(): String { return _text.text; }
}
/**
* MyTextField クラスは適当な初期設定をしただけのテキストフィールドです。
*/
class MyTextField extends TextField {
/**
* 新しい MyTextField インスタンスを作成します。
*/
public function MyTextField() {
defaultTextFormat = new TextFormat("_sans", 12, 0xFF0000);
autoSize = "left";
selectable = false;
mouseEnabled = false;
}
}