In case Flash no longer exists; a copy of this site is included in the Flashpoint archive's "ultimate" collection.

Dead Code Preservation :: Archived AS3 works from wonderfl.net

あなたのイベントハンドラを教えて!

あなたのイベントハンドラを教えて!
*
* 複数のイベント&複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
Get Adobe Flash player
by clockmaker 01 Jun 2010
/**
 * Copyright clockmaker ( http://wonderfl.net/user/clockmaker )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/43Ln
 */

/**
* あなたのイベントハンドラを教えて!
*
* 複数のイベント&複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
*/
package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    public class FlashTest extends Sprite {
    
        private var _btnA:MyButton;
        private var _btnB:MyButton;
        private var _btnC:MyButton;
        private var _label:MyTextField;

        public function FlashTest() {
            // ボタンを作成
            _build();
            
            // 自分流のイベントハンドラを記述ください
            
            // ClockMaker 流
            // クリック
            _btnA.addEventListener(MouseEvent.CLICK, _onMouseEvent);
            _btnB.addEventListener(MouseEvent.CLICK, _onMouseEvent);
            _btnC.addEventListener(MouseEvent.CLICK, _onMouseEvent);
            // ロールオーバー
            _btnA.addEventListener(MouseEvent.ROLL_OVER, _onMouseEvent);
            _btnB.addEventListener(MouseEvent.ROLL_OVER, _onMouseEvent);
            _btnC.addEventListener(MouseEvent.ROLL_OVER, _onMouseEvent);
        }
        
        // ClockMaker 流
        private function _onMouseEvent(e:MouseEvent):void {
             // タイプを判別
             switch(e.type){
                 case MouseEvent.CLICK:
                     // 対象を判別
                     switch(e.currentTarget){
                         case _btnA: _label.text = "A がクリックされました"; break;
                         case _btnB: _label.text = "B がクリックされました"; break;
                         case _btnC: _label.text = "C がクリックされました"; break;
                     }
                     break;
                 case MouseEvent.ROLL_OVER:
                     // 対象を判別
                     switch(e.currentTarget){
                         case _btnA: _label.text = "A がロールオーバーされました"; break;
                         case _btnB: _label.text = "B がロールオーバーされました"; break;
                         case _btnC: _label.text = "C がロールオーバーされました"; break;
                     }
                     break;
             }
        }
        
        /**
        * インターフェースを作る
        */
        private function _build():void {
            _label = new MyTextField();
            _label.x = 150; _label.y = 280;
            addChild(_label);

            _btnA = new MyButton();
            _btnA.text = "Button A"; 
            _btnA.x = 70; _btnA.y = 230;
            addChild(_btnA);
            
            _btnB = new MyButton();
            _btnB.text = "Button B";
            _btnB.x = 190; _btnB.y = 230;
            addChild(_btnB);
   
            _btnC = new MyButton();            
            _btnC.text = "Button C";
            _btnC.x = 310; _btnC.y = 230;
            addChild(_btnC);
        }
    }
}

import flash.display.*
import flash.text.*;

/**
* MyButton クラスはボタン的な挙動をするようにしたSpriteです。
*/
class MyButton extends Sprite {
    private var _text:MyTextField;
    /**
    * 新しい MyButton インスタンスを作成します。
    */
    public function MyButton(){
        graphics.beginFill(0x000000);
        graphics.drawRoundRect(0, 0, 100, 30, 5, 5);
        addChild(_text = new MyTextField);
        buttonMode = true;
    }
    /**
    * ボタンの文言を設定します。
    */
    public function set text(value:String):void {
        _text.text = value;
        _text.x = (100 - _text.textWidth) / 2;
        _text.y = (30 - _text.textHeight) / 2;
    }
}

/**
* MyTextField クラスは適当な初期設定をしただけのテキストフィールドです。
*/
class MyTextField extends TextField {
    /**
    * 新しい MyTextField インスタンスを作成します。
    */
    public function MyTextField() {
        defaultTextFormat = new TextFormat("_sans", 12, 0xFF0000);
        autoSize = "left";
        selectable = false;
        mouseEnabled = false;
    }
}