あなたのイベントハンドラを教えて！＠clockmaker流
あなたのイベントハンドラを教えて！
*
* 複数のイベント＆複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
/**
* Copyright clockmaker ( http://wonderfl.net/user/clockmaker )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/kk15
*/
// forked from clockmaker's あなたのイベントハンドラを教えて！
/**
* あなたのイベントハンドラを教えて！
*
* 複数のイベント＆複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
*/
package {
import flash.display.Sprite;
import flash.events.MouseEvent;
public class FlashTest extends Sprite {
private var _btnA:MyButton;
private var _btnB:MyButton;
private var _btnC:MyButton;
private var _label:MyTextField;
public function FlashTest() {
// ボタンを作成
_build();
// 自分流のイベントハンドラを記述ください
// ClockMaker 流
// クリック
_btnA.clickFuncs.push( function():void{ _label.text = "A がクリックされました"; } );
_btnB.clickFuncs.push( function():void{ _label.text = "B がクリックされました"; } );
_btnC.clickFuncs.push( function():void{ _label.text = "C がクリックされました"; } );
//
_btnA.overFuncs.push( function():void{ _label.text = "A がロールオーバーされました"; } );
_btnB.overFuncs.push( function():void{ _label.text = "B がロールオーバーされました"; } );
_btnC.overFuncs.push( function():void{ _label.text = "C がロールオーバーされました"; } );
}
/**
* インターフェースを作る
*/
private function _build():void {
_label = new MyTextField();
_label.x = 150; _label.y = 280;
addChild(_label);
_btnA = new MyButton();
_btnA.text = "Button A";
_btnA.x = 70; _btnA.y = 230;
addChild(_btnA);
_btnB = new MyButton();
_btnB.text = "Button B";
_btnB.x = 190; _btnB.y = 230;
addChild(_btnB);
_btnC = new MyButton();
_btnC.text = "Button C";
_btnC.x = 310; _btnC.y = 230;
addChild(_btnC);
}
}
}
import flash.display.*
import flash.text.*;
import flash.events.*;
/**
* MyButton クラスはボタン的な挙動をするようにしたSpriteです。
*/
import flash.events.Event;
class MyButton extends Sprite {
private var _text:MyTextField;
/**
* 新しい MyButton インスタンスを作成します。
*/
public function MyButton(){
graphics.beginFill(0x000000);
graphics.drawRoundRect(0, 0, 100, 30, 5, 5);
addChild(_text = new MyTextField);
buttonMode = true;
addEventListener(MouseEvent.CLICK, _onClick);
addEventListener(MouseEvent.ROLL_OVER, _onRollOver);
}
/**
* ボタンの文言を設定します。
*/
public function set text(value:String):void {
_text.text = value;
_text.x = (100 - _text.textWidth) / 2;
_text.y = (30 - _text.textHeight) / 2;
}
// pushしておけばいくつもでもイベントハンドラ追加できるよ
public var clickFuncs:Vector.<Function> = new Vector.<Function>;
public var overFuncs:Vector.<Function> = new Vector.<Function>;
private function _onClick(e:Event):void {
for(var i:int=0; i < clickFuncs.length; i++) {
if(clickFuncs[i] is Function) clickFuncs[i]();
}
}
private function _onRollOver(e:Event):void {
for(var i:int=0; i < overFuncs.length; i++) {
if(overFuncs[i] is Function) overFuncs[i]();
}
}
public function destory():void {
// removeEventListenerとVector.<Function>をnullすればメモリ対策もOK
}
}
/**
* MyTextField クラスは適当な初期設定をしただけのテキストフィールドです。
*/
class MyTextField extends TextField {
/**
* 新しい MyTextField インスタンスを作成します。
*/
public function MyTextField() {
defaultTextFormat = new TextFormat("_sans", 12, 0xFF0000);
autoSize = "left";
selectable = false;
mouseEnabled = false;
}
}