forked from: あなたのイベントハンドラを教えて！
あなたのイベントハンドラを教えて！
*
* 複数のイベント＆複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
/**
* Copyright imajuk ( http://wonderfl.net/user/imajuk )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/jBI1
*/
/**
* あなたのイベントハンドラを教えて！
*
* 複数のイベント＆複数のインスタンスに
* イベントハンドラを設定するときに
* みなさんの記述方法の違いを知りたい。
*
* [ルール]
* 画面上に3つのボタンが用意されており、
* クリックとロールオーバーの
* イベントハンドラを記述してください。
*/
package {
import flash.utils.Dictionary;
import flash.display.Sprite;
import flash.events.MouseEvent;
public class FlashTest extends Sprite {
private var _btnA:MyButton;
private var _btnB:MyButton;
private var _btnC:MyButton;
private var _label:MyTextField;
private var message_click : Dictionary = new Dictionary(true);
private var message_over : Dictionary = new Dictionary(true);
public function FlashTest() {
// ボタンを作成
_build();
// 自分流のイベントハンドラを記述ください
//=================================
// 自分はバブリングを使うのがすきです。
// Dispatcher(View)とModelはControlerで紐づけます。
// 今回のケースでは簡単なサンプルなのでControlerは辞書です.
//=================================
message_click[_btnA] = "A がクリックされました";
message_click[_btnB] = "B がクリックされました";
message_click[_btnC] = "C がクリックされました";
message_over[_btnA] = "A がロールオーバーされました";
message_over[_btnB] = "B がロールオーバーされました";
message_over[_btnC] = "C がロールオーバーされました";
// クリック
addEventListener(MouseEvent.CLICK, _onMouseClick);
// ロールオーバー
addEventListener(MouseEvent.MOUSE_OVER, _onMouseOver);
}
// Imajuk 流
private function _onMouseClick(e:MouseEvent):void {
_label.text = message_click[e.target];
}
private function _onMouseOver(e:MouseEvent):void {
_label.text = message_over[e.target];
}
/**
* インターフェースを作る
*/
private function _build():void {
_label = new MyTextField();
_label.x = 150; _label.y = 280;
addChild(_label);
_btnA = new MyButton();
_btnA.text = "Button A";
_btnA.x = 70; _btnA.y = 230;
addChild(_btnA);
_btnB = new MyButton();
_btnB.text = "Button B";
_btnB.x = 190; _btnB.y = 230;
addChild(_btnB);
_btnC = new MyButton();
_btnC.text = "Button C";
_btnC.x = 310; _btnC.y = 230;
addChild(_btnC);
}
}
}
import flash.display.*
import flash.text.*;
/**
* MyButton クラスはボタン的な挙動をするようにしたSpriteです。
*/
class MyButton extends Sprite {
private var _text:MyTextField;
/**
* 新しい MyButton インスタンスを作成します。
*/
public function MyButton(){
graphics.beginFill(0x000000);
graphics.drawRoundRect(0, 0, 100, 30, 5, 5);
addChild(_text = new MyTextField);
buttonMode = true;
}
/**
* ボタンの文言を設定します。
*/
public function set text(value:String):void {
_text.text = value;
_text.x = (100 - _text.textWidth) / 2;
_text.y = (30 - _text.textHeight) / 2;
}
}
/**
* MyTextField クラスは適当な初期設定をしただけのテキストフィールドです。
*/
class MyTextField extends TextField {
/**
* 新しい MyTextField インスタンスを作成します。
*/
public function MyTextField() {
defaultTextFormat = new TextFormat("_sans", 12, 0xFF0000);
autoSize = "left";
selectable = false;
mouseEnabled = false;
}
}