flash on 2009-12-9

このクラスでは、頂点インデックスの使い方を示します。

by psyark 09 Dec 2009

Tags

wonderfl本
Embed

/**
 * Copyright psyark ( http://wonderfl.net/user/psyark )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/zZnm
 */

package {
	import flash.display.*;
	import flash.events.*;
	import flash.geom.*;
	
	[SWF(width=465,height=465,frameRate=60,backgroundColor=0x000000)]
	/**
	 * このクラスでは、頂点インデックスの使い方を示します。
	 */
	public class Test12 extends Sprite {
		private var viewport:Shape;
		private var vertices:Vector.<Number>;
		private var uvtData:Vector.<Number>;
		private var indices:Vector.<int>;
		private var worldMatrix:Matrix3D;
		private var viewMatrix:Matrix3D;
		private var projection:PerspectiveProjection;
		private var texture:BitmapData;
		
		public function Test12() {
			// 描画対象となるShapeを作成し、表示リストに追加します。
			viewport = new Shape();
			viewport.x = stage.stageWidth  * 0.5;
			viewport.y = stage.stageHeight * 0.5;
			addChild(viewport);
			
			createMesh();
			
			worldMatrix = new Matrix3D();
			viewMatrix = new Matrix3D();
			viewMatrix.appendTranslation(0, 0, 200);
			projection = new PerspectiveProjection();
			projection.fieldOfView = 60;
			
			texture = new BitmapData(512, 512, false);
			texture.perlinNoise(100, 100, 5, 0, true, true, 7);
			
			addEventListener(Event.ENTER_FRAME, enterFrameHandler);
		}
		
		/**
		 * 3D形状を作成します
		 */
		private function createMesh():void {
			vertices = new Vector.<Number>();
			uvtData = new Vector.<Number>();
			indices = new Vector.<int>();
			
			vertices.push(-50, -50, -50); // 0
			vertices.push(+50, -50, -50); // 1
			vertices.push(-50, +50, -50); // 2
			vertices.push(+50, +50, -50); // 3
			vertices.push(-50, -50, +50); // 4
			vertices.push(+50, -50, +50); // 5
			vertices.push(-50, +50, +50); // 6
			vertices.push(+50, +50, +50); // 7
			uvtData.push(1/3, 0, 0);
			uvtData.push(2/3, 0, 0);
			uvtData.push(1/3, 1, 0);
			uvtData.push(2/3, 1, 0);
			uvtData.push(0/3, 0, 0);
			uvtData.push(3/3, 0, 0);
			uvtData.push(0/3, 1, 0);
			uvtData.push(3/3, 1, 0);
			
			// 前面
			indices.push(0, 2, 1, 1, 2, 3);
			// 上面
			indices.push(4, 0, 5, 5, 0, 1);
			// 右側面
			indices.push(5, 1, 7, 7, 1, 3);
			// 底面
			indices.push(7, 3, 6, 6, 3, 2);
			// 左側面
			indices.push(6, 2, 4, 4, 2, 0);
			// 背面
			indices.push(5, 7, 4, 4, 7, 6);
		}
		
		/**
		 * フレームごとの処理
		 */
		private function enterFrameHandler(event:Event):void {
			update();
			render();
		}
		
		/**
		 * 更新
		 */
		private function update():void {
			worldMatrix.appendRotation(0.4, Vector3D.X_AXIS);
			worldMatrix.appendRotation(1, Vector3D.Y_AXIS);
		}
		
		/**
		 * 描画
		 */
		private function render():void {
			// World行列、View行列、Projection行列を結合して一つの行列にする
			var m:Matrix3D = new Matrix3D();
			m.append(worldMatrix);
			m.append(viewMatrix);
			m.append(projection.toMatrix3D());
			
			// 上記の行列を使って頂点座標を投影する
			var projected:Vector.<Number> = new Vector.<Number>();
			Utils3D.projectVectors(m, vertices, projected, uvtData);
			
			viewport.graphics.clear();
			viewport.graphics.lineStyle(-1, 0xFFFFFF);
			viewport.graphics.beginBitmapFill(texture, null, false, true);
			viewport.graphics.drawTriangles(projected, indices, uvtData, TriangleCulling.POSITIVE);
			viewport.graphics.endFill();
		}
	}
}