重力マウス（500000パーティクル）カメラ色情報を取得 画像が見えすぎる

リンクリストにしてみたけどそんなに速くない？？
_bmd.fillRect()を_bmd.setPixel()に変更。
sin(),cos(),atan2(),sqrt()を排除。
Add final class / mouseEnalbled = false by clockmaker
CJ Cat: Used vector instead of linked list.

by s26 07 Jun 2010

Tags

Particle
Embed

/**
 * Copyright s26 ( http://wonderfl.net/user/s26 )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/ydWp
 */

// forked from s26's 重力マウス（50000パーティクル） with カメラ色情報を取得
// forked from clockmaker's 重力マウス（プチ軽量化：10万パーティクル）
// forked from coppieee's 重力マウス（さらに軽量化してみた）
// forked from paq's forked from: 重力マウス（ちょっぴり軽量化してみた）
// forked from fumix's 重力マウス（リンクリストにしてみた）
// forked from undo's 重力マウス
//　リンクリストにしてみたけどそんなに速くない？？
//_bmd.fillRect()を_bmd.setPixel()に変更。
//sin(),cos(),atan2(),sqrt()を排除。
// Add final class / mouseEnalbled = false by clockmaker
// CJ Cat: Used vector instead of linked list.
package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.geom.ColorTransform;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.media.Camera;
	import flash.media.Video;
	import flash.utils.ByteArray;

	[SWF(frameRate='60', width='465', height='465', backgroundColor='0xe')]

	import flash.utils.Dictionary;
	public class main extends Sprite {
		private var _bmp:Bitmap;
		private var _bmd:BitmapData;
		private var _bmdRect:Rectangle;
		private var _colorTransform:ColorTransform = new ColorTransform(0.7, 0.7, 0.7, 1.0);

		private const _maxNum:int = 500000; //50万パーティクルでも45fpsぐらいでる
		private var _cnt:int = 0;
		
		private const _particleData:Vector.<Number> = new Vector.<Number>(_maxNum * 4, true);
		
		private var camera:Camera;
		private var video:Video;
		
		private var bmd:BitmapData
		
		public function main() {
			camera = Camera.getCamera();
			if (camera != null) {
				video = new Video(480,360);
				video.attachCamera(camera);
				bmd = new BitmapData(video.width, video.height)
				init()
			}
		}
		
		 
		private function init():void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			
			this.stage.align = StageAlign.TOP_LEFT;
			this.stage.scaleMode = StageScaleMode.NO_SCALE;
			this.stage.quality = "low";
			this.stage.frameRate = 60;
			this.mouseEnabled = false;
			this.mouseChildren = false;
		
			_bmd = new BitmapData(465, 465, false, 0x000000);
			_bmp = new Bitmap(_bmd);
			addChild(_bmp);
			this._bmdRect = _bmd.rect;
			
			var i0:int, i1:int, i2:int, i3:int;
			i0 = 0;
			while (i0 < _maxNum) {
				i1 = i0;
				i2 = ++i1;
				i3 = ++i2;
				i3++;
				
				_particleData[i0] = Math.random() * 465 >> 0;
				_particleData[i1] = Math.random() * 465 >> 0;
				_particleData[i2] = 0;
				_particleData[i3] = 0;
				
				i0 = ++i3;
			}
			
			addEventListener(Event.ENTER_FRAME, onEnter);
		}

		private function onEnter(evt:Event):void {
			bmd.draw(video);
			var ccc = ((Math.sin(new Date().getTime()/700)+1)/2)%360
			var gravPoint_x:Number = mouseX;
			var gravPoint_y:Number = mouseY;
			//var n:Node = _first;
			var calc:Boolean = _cnt % 4 == 0;
			
			this._bmd.lock();
			
			var i0:int, i1:int, i2:int, i3:int;
			i0 = 0;
			while (i0 < _maxNum)
			{
				i1 = i0;
				i2 = ++i1;
				i3 = ++i2;
				i3++;
				
				// 4回に1回ぐらいの処理に
				if(calc){
					var diff_x:Number = gravPoint_x - _particleData[i0];;
					var diff_y:Number = gravPoint_y - _particleData[i1];
					var acc:Number = 200 / (diff_x * diff_x + diff_y * diff_y);
					var acc_x:Number = acc * diff_x;
					var acc_y:Number = acc * diff_y;
					_particleData[i2] += acc * diff_x;
					_particleData[i3] += acc * diff_y;
				}
				
				_particleData[i0] += _particleData[i2];
				_particleData[i1] += _particleData[i3];
				
				_particleData[i2] *= 0.96;
				_particleData[i3] *= 0.96;
				
				if(calc)
				{
					if (_particleData[i0] > 465)
						_particleData[i0] -= 465;
					else if (_particleData[i0] < 0)
						_particleData[i0] += 465;
					if (_particleData[i1] > 465)
						_particleData[i1] -= 465;
					else if (_particleData[i1] < 0)
						_particleData[i1] += 465;
				}
				var cd:uint = bmd.getPixel(_particleData[i0], _particleData[i1])
				this._bmd.setPixel(_particleData[i0], _particleData[i1] , cd);
				i0 = ++i3;
			}
			this._bmd.colorTransform(this._bmdRect, this._colorTransform);
			this._bmd.unlock();
			
			_cnt++;
		}
	}
}