In case Flash no longer exists; a copy of this site is included in the Flashpoint archive's "ultimate" collection.

Dead Code Preservation :: Archived AS3 works from wonderfl.net

キラキラみきマスオ

////////////////////////////////////////////////////////////////////////////////
// キラキラみきマスオ
//
// [AS3.0] LightFoliumクラスだ！ (2)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1123
// [AS3.0] MiniVisualizerクラスだ！ (2)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1344
// [AS3.0] TwinkleParticlesクラスだ！ (4)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1371
////////////////////////////////////////////////////////////////////////////////
Get Adobe Flash player
by ProjectNya 04 Apr 2011
/**
 * Copyright ProjectNya ( http://wonderfl.net/user/ProjectNya )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/uM6c
 */

// forked from say's みきマスオ
// forked from say's わかめちゃん
// forked from ProjectNya's 教材：矩形(四角)を描こう！
////////////////////////////////////////////////////////////////////////////////
// キラキラみきマスオ
//
// [AS3.0] LightFoliumクラスだ！ (2)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1123
// [AS3.0] MiniVisualizerクラスだ！ (2)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1344
// [AS3.0] TwinkleParticlesクラスだ！ (4)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1371
////////////////////////////////////////////////////////////////////////////////

package {

    import flash.display.Sprite;
    import flash.events.Event;

    [SWF(backgroundColor="#000000", width="465", height="465", frameRate="30")]

    public class Main extends Sprite {
        private var masuo:Masuo;
        private var twinkle:TwinkleParticles;
        private var se:SoundEffect;
        private static var bgmPath:String = "http://www.project-nya.jp/images/bgm/project.mp3";

        public function Main() {
            init();
        }

        private function init():void {
            graphics.beginFill(0x000000);
            graphics.drawRect(0, 0, 465, 465);
            graphics.endFill();
            //
            masuo = new Masuo(0x333333);
            addChild(masuo);
            masuo.x = 232;
            masuo.y = 232;
            //
            twinkle = new TwinkleParticles();
            addChild(twinkle);
            //
            se = new SoundEffect();
            se.addEventListener(Event.COMPLETE, complete, false, 0, true);
            se.load(bgmPath);
        }
        private function complete(evt:Event):void {
            se.removeEventListener(Event.COMPLETE, complete);
            se.play(0.5, true);
            //
            twinkle.start();
        }

    }

}


//////////////////////////////////////////////////
// Masuoクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.display.Shape;

class Masuo extends Sprite {
    private var color:uint = 0x000000;

    public function Masuo(c:uint = 0x000000) {
        color = c;
        init();
    }

    private function init():void {
        graphics.beginFill(color);
        graphics.drawCircle(0, 20, 150);
        graphics.endFill();

        var ears:Shape;
        ears = new Shape();
        addChild(ears);
        ears.x = 0;
        ears.y = - 100;
        ears.graphics.beginFill(color);
        ears.graphics.drawCircle(-145, 0, 80);
        ears.graphics.drawCircle(145, 0, 80);
        ears.graphics.endFill();
    }

}




//////////////////////////////////////////////////
// TwinkleParticlesクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.events.Event;
import flash.geom.Rectangle;
import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.ColorTransform;
import flash.geom.Point;
import flash.filters.BlurFilter;
import frocessing.color.ColorHSV;

class TwinkleParticles extends Sprite {
    private var masuo:Masuo;
    private var particles:Array;
    private var rect:Rectangle;
    private var bitmapData:BitmapData;
    private var bitmap:Bitmap;
    private var container:Sprite;
    private static var colorTrans:ColorTransform;
    private static var point:Point = new Point();
    private static var blur:BlurFilter;
    private var count:uint = 0;
    private var color:ColorHSV;
    private static var cx:uint = 232;
    private static var cy:uint = 232;
    private static var radius:uint = 160;
    private static var radian:Number = Math.PI/180;
    private var nx:uint = 1;
    private var ny:uint = 1;

    public function TwinkleParticles() {
        particles = new Array();
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init, false, 0, true);
    }

    private function init(evt:Event = null):void {
        removeEventListener(Event.ADDED_TO_STAGE, init);
        rect = new Rectangle(0, 0, stage.stageWidth, stage.stageHeight);
        bitmapData = new BitmapData(rect.width, rect.height, true, 0x00000000);
        bitmap = new Bitmap(bitmapData);
        addChild(bitmap);
        container = new Sprite();
        addChild(container);
        colorTrans = new ColorTransform(1, 1, 1, 0.6, 0, 0, 0, 0);
        blur = new BlurFilter(16, 16, 3);
        color = new ColorHSV(0, 0.5);
        masuo = new Masuo(0xFFFFFF);
        addChild(masuo);
        masuo.x = 232;
        masuo.y = 232;
        masuo.scaleX = masuo.scaleY = 0.05;
    }
    public function start():void {
        addEventListener(Event.ENTER_FRAME, create, false, 0, true);
        addEventListener(Event.ENTER_FRAME, update, false, 0, true);
    }
    private function create(evt:Event):void {
        count += 2;
        if (count%90 == 0) nx = nx%10 + 1;
        if (count%900 == 0) ny = ny%10 + 1;
        color.h = count;
        var particle:Particle = new Particle(color.value);
        var px:Number = cx + radius*Math.sin(count*nx*radian)*Math.cos(count*radian);
        var py:Number = cy + radius*Math.sin(count*ny*radian)*Math.sin(count*radian);
        masuo.x = px;
        masuo.y = py - 10;
        particle.x = px;
        particle.y = py;
        container.addChild(particle);
        particles.push(particle);
    }
    private function update(evt:Event):void {
        for (var n:uint = 0; n < particles.length; n++) {
            var particle:Particle = particles[n];
            particle.update();
            if (particle.life < 0 || particle.y > stage.stageHeight + 50) {
                container.removeChild(particle);
                particles.splice(n, 1);
                particle = null;
            }
        }
        draw();
    }
    private function draw():void {
        bitmapData.lock();
        bitmapData.draw(container, null, colorTrans);
        bitmapData.applyFilter(bitmapData, rect, point, blur);
        bitmapData.unlock();
    }

}


//////////////////////////////////////////////////
// Particleクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.filters.GlowFilter;

class Particle extends Sprite {
    private var glow:GlowFilter;
    private var _width:uint = 12;
    private var _height:uint = 18;
    private var blur:uint = 8;
    private static var color:uint = 0xFFFFFF;
    private static var max:uint = 50;
    public var life:int = max;
    private static var radius:Number = 3;
    private var dx:Number = 0;
    private var gravity:Number = - 6;
    private static var acceleration:Number = 0.8;

    public function Particle(rgb:uint = 0xFFFFFF, w:uint = 12, h:uint = 18, b:uint = 8) {
        _width = w;
        _height = h;
        blur = b;
        glow = new GlowFilter(rgb, 1, blur, blur, 2, 3, false, false);
        draw();
        init();
    }

    private function init():void {
        dx = Math.random()*radius*2 - radius;
    }
    public function update():void {
        if (life < 0) return;
        life --;
        x += dx;
        gravity += acceleration;
        y += gravity;
        alpha = (life/max < 0.5) ? life*2/max : 1;
        blink();
    }
    private function blink():void {
        if (life%4 == 0) {
            visible = false;
        } else {
            visible = true;
        }
    }
    private function draw():void {
        graphics.beginFill(color);
        graphics.moveTo(0, -_height/2);
        graphics.curveTo(0, 0, -_width/2, 0);
        graphics.curveTo(0, 0, 0, _height/2);
        graphics.curveTo(0, 0, _width/2, 0);
        graphics.curveTo(0, 0, 0, -_height/2);
        graphics.endFill();
        filters = [glow];
    }

}


//////////////////////////////////////////////////
// SoundEffectクラス
//////////////////////////////////////////////////

import flash.events.EventDispatcher;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.net.URLRequest;
import flash.media.SoundLoaderContext;

class SoundEffect extends EventDispatcher {
    public var id:String;
    private var sound:Sound;
    private var channel:SoundChannel;
    private var level:Number;
    private var volume:Number = 1;
    private var looping:Boolean = false;
    public var initialized:Boolean = false;
    public var playing:Boolean = false;

    public function SoundEffect() {
    }

    public function init(Snd:Class):void {
        sound = new Snd();
    }
    public function load(filePath:String):void {
        sound = new Sound();
        sound.addEventListener(ProgressEvent.PROGRESS, progress, false, 0, true);
        sound.addEventListener(Event.COMPLETE, initialize, false, 0, true);
        try {
            sound.load(new URLRequest(filePath), new SoundLoaderContext(10, true));
        } catch (err:Error) {
            trace(err.message);
        }
    }
    private function progress(evt:ProgressEvent):void {
        dispatchEvent(evt);
    }
    private function initialize(evt:Event):void {
        initialized = true;
        channel = sound.play();
        channel.stop();
        dispatchEvent(evt);
    }
    public function play(lv:Number, loop:Boolean = false):void {
        playing = true;
        if (channel) channel.stop();
        level = lv;
        looping = loop;
        channel = sound.play();
        var transform:SoundTransform = channel.soundTransform;
        transform.volume = level*volume;
        channel.soundTransform = transform;
        if (looping) {
            channel.addEventListener(Event.SOUND_COMPLETE, complete, false, 0, true);
        }
    }
    public function stop():void {
        playing = false;
        if (channel) {
            channel.stop();
            channel.removeEventListener(Event.SOUND_COMPLETE, complete);
        }
    }
    public function setVolume(v:Number):void {
        volume = v;
        if (channel) {
            var transform:SoundTransform = channel.soundTransform;
            transform.volume = level*volume;
            channel.soundTransform = transform;
        }
    }
    private function complete(evt:Event):void {
        channel.removeEventListener(Event.SOUND_COMPLETE, complete);
        if (looping) {
            channel = sound.play(0);
            channel.addEventListener(Event.SOUND_COMPLETE, complete, false, 0, true);
            var transform:SoundTransform = channel.soundTransform;
            transform.volume = level*volume;
            channel.soundTransform = transform;
        } else {
            playing = false;
        }
    }

}