create Mesh and set UV [Alternativa3D 7.6 TIPS]
UVを設定する
5.6に比べ、7.6ではUV設定が、Vertexと関連付ける形式に変更された為、非常に設定しやすくなりました。
しかし、その便利さと引き換えに、同じVertexでもUVマッピングが違う場合は
同じGeometry内でも、別Vertexを用意しないといけなくなりました。
このあたりは、オリジナルのプリミティブを作成する場合に、ちょっとはまるところかもしれません。
2011/01/12 7.5から7.6仕様に変更
/**
* Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/tDWd
*/
// forked from narutohyper's Alternativa3D 7.5 Template
package
{
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.Vertex;
import alternativ7.engine3d.loaders.MaterialLoader;
import alternativ7.engine3d.materials.TextureMaterial;
import alternativ7.engine3d.objects.Mesh;
import flash.display.Sprite;
import flash.events.Event;
import flash.system.LoaderContext;
/**
* Alternativa3D 7.6
*
* UVを設定する
*
* 5.6に比べ、7.6ではUV設定が、Vertexと関連付ける形式に変更された為、非常に設定しやすくなりました。
*
* しかし、その便利さと引き換えに、同じVertexでもUVマッピングが違う場合は
* 同じGeometry内でも、別Vertexを用意しないといけなくなりました。
* このあたりは、オリジナルのプリミティブを作成する場合に、ちょっとはまるところかもしれません。
*
* ...
* @author narutohyper
*/
[SWF(backgroundColor="#000000", frameRate="100", width="800", height="600")]
public class Main extends Sprite
{
public function Main():void {
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
private function init(e:Event=null):void {
removeEventListener(Event.ADDED_TO_STAGE, init);
//AlternativaTemplate作成
var scene:AlternativaTemplate = new AlternativaTemplate(this);
//まとめてcontrolするために、core.Object3DContainerを作成し、各Objectを入れ子にする
var animeObject:Object3DContainer = new Object3DContainer;
scene.container.addChild(animeObject);
//外部読み込み画像によるmaterial
var textureMaterial:TextureMaterial = new TextureMaterial(null, false, true);
textureMaterial.diffuseMapURL = 'http://assets.wonderfl.net/images/related_images/e/e9/e987/e9876c502c9e9693205335e106de6baa8865c1a6m';
var textures:Vector.<TextureMaterial> = new Vector.<TextureMaterial>(1);
textures[0] = textureMaterial;
var context:LoaderContext = new LoaderContext(true);
var materialLoader:MaterialLoader = new MaterialLoader();
materialLoader.load(textures,context);
var vertex:Array = [];
var RADIAN:Number = Math.PI / 180;
//UVを設定しない三角形なPlaneを作成
var meshTriangleNonUV:Mesh = new Mesh();
//UVを設定しない場合、UV値は0,0になるので、画像の左上のPixelで塗りつぶされる（実際には、0,0のPixelが拡大）
vertex[0] = meshTriangleNonUV.addVertex(Math.cos(-90*RADIAN)*200,Math.sin(-90*RADIAN)*200,0);
vertex[1] = meshTriangleNonUV.addVertex(Math.cos( 30*RADIAN)*200,Math.sin( 30*RADIAN)*200,0);
vertex[2] = meshTriangleNonUV.addVertex(Math.cos(150*RADIAN)*200,Math.sin(150*RADIAN)*200,0);
meshTriangleNonUV.addTriFace(vertex[0], vertex[1], vertex[2], null, 'faceFront');
meshTriangleNonUV.addTriFace(vertex[0], vertex[2], vertex[1], null, 'faceBack');
meshTriangleNonUV.calculateNormals();
meshTriangleNonUV.setMaterialToAllFaces(textureMaterial);
animeObject.addChild(meshTriangleNonUV);
meshTriangleNonUV.x=0;
meshTriangleNonUV.y=150;
//UVを設定した三角形なPlaneを作成(UVは画像に対し等比)
var meshTriangleSetUV:Mesh = new Mesh();
var tu:Number;
var tv:Number;
var tw:Number;
var th:Number;
var tx:Number;
var ty:Number;
tw = Math.sin(90 * RADIAN) * 400;
th = Math.sin(90 * RADIAN) * 400;
tx = Math.cos( -90 * RADIAN) * 200;
ty = Math.sin( -90 * RADIAN) * 200;
tu = (tx + tw / 2) / tw;
tv = (ty + th / 2) / th;
trace(tw,th);
vertex[0] = meshTriangleSetUV.addVertex(tx, ty, 0, tu, tv, 'v1');
tx = Math.cos(30 * RADIAN) * 200;
ty = Math.sin(30 * RADIAN) * 200;
tu = (tx + tw / 2) / tw;
tv = (ty + th / 2) / th;
vertex[1] = meshTriangleSetUV.addVertex(tx, ty, 0, tu, tv, 'v2');
tx = Math.cos(150 * RADIAN) * 200;
ty = Math.sin(150 * RADIAN) * 200;
tu = (tx + tw / 2) / tw;
tv = (ty + th / 2) / th;
vertex[2] = meshTriangleSetUV.addVertex(tx, ty, 0, tu, tv, 'v3');
meshTriangleSetUV.addTriFace(vertex[0], vertex[1], vertex[2], null, 'faceFront');
meshTriangleSetUV.addTriFace(vertex[0], vertex[2], vertex[1], null, 'faceBack');
meshTriangleSetUV.calculateNormals();
meshTriangleSetUV.setMaterialToAllFaces(textureMaterial);
animeObject.addChild(meshTriangleSetUV);
meshTriangleSetUV.x=-200;
meshTriangleSetUV.y=-150;
//UVを設定した三角形なPlaneを作成(UVは画像にフィット)
var meshTriangleSetUV2:Mesh = new Mesh();
tw = Math.cos( 30 * RADIAN) * 400;
th = Math.cos( 30 * RADIAN) * 400;
tx = Math.cos( -90 * RADIAN) * 200;
ty = Math.sin( -90 * RADIAN) * 200;
tu = 0.5;
tv = 0;
vertex[0] = meshTriangleSetUV2.addVertex(tx, ty, 0, tu, tv, 'v1');
tx = Math.cos(30 * RADIAN) * 200;
ty = Math.sin(30 * RADIAN) * 200;
tu = 1;
tv = 1;
vertex[1] = meshTriangleSetUV2.addVertex(tx, ty, 0, tu, tv, 'v2');
tx = Math.cos(150 * RADIAN) * 200;
ty = Math.sin(150 * RADIAN) * 200;
tu = 0;
tv = 1;
vertex[2] = meshTriangleSetUV2.addVertex(tx, ty, 0, tu, tv, 'v3');
meshTriangleSetUV2.addTriFace(vertex[0], vertex[1], vertex[2], null, 'faceFront');
meshTriangleSetUV2.addTriFace(vertex[0], vertex[2], vertex[1], null, 'faceBack');
meshTriangleSetUV2.calculateNormals();
meshTriangleSetUV2.setMaterialToAllFaces(textureMaterial);
animeObject.addChild(meshTriangleSetUV2);
meshTriangleSetUV2.x=200;
meshTriangleSetUV2.y=-150;
//カメラの調整
//カメラはControllerに関連付けている為、x,y,zで直接位置を指定できないので
//SimpleController.setObjectPosXYZを使用
scene.cameraController.setObjectPosXYZ(0, -1500, 500);
scene.cameraController.lookAtXYZ(0, 0, 0);
//ObjectControllerの作成
//MouseDragで、Objectを回転させる為のController
var objectController:SimpleObjectController = new SimpleObjectController(stage,animeObject,100);
objectController.unbindAll();
scene.onPreRender = function():void {
objectController.update();
}
//描画開始
scene.startRendering();
}
}
}
/**
* BasicTemplate for Alternativa3D 7.5
* Alternativa3D 7.5を扱いやすくするためのテンプレートです
* @author narutohyper & clockmaker
*
*/
import alternativ7.engine3d.containers.BSPContainer;
import alternativ7.engine3d.containers.ConflictContainer;
import alternativ7.engine3d.containers.DistanceSortContainer;
import alternativ7.engine3d.containers.KDContainer;
import alternativ7.engine3d.containers.LODContainer;
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Camera3D;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.View;
import flash.display.DisplayObject;
import flash.display.DisplayObjectContainer;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
class AlternativaTemplate extends Sprite
{
/**
* 子オブジェクトを最適な方法でソートするコンテナ
* (ConflictContainer)
*/
public static const CONFLICT:String = 'conflict';
/**
* 子オブジェクトをBSP(バイナリ空間分割法)によってソートするコンテナ
* (BSPContainer)
*/
public static const BSP:String = 'bsp';
/**
* 子オブジェクトをカメラからのZ値でソートするコンテナ
* (DistanceSortContainer)
*/
public static const ZSORT:String = 'zsort';
/**
* KDツリー(http://ja.wikipedia.org/wiki/Kd%E6%9C%A8)によってソートするコンテナ
* (KDContainer)
*/
public static const KD:String = 'kd';
/**
* detalizationと子オブジェクトの距離でソートするコンテナ（詳細は調査中）
* (LODContainer)
*/
public static const LOD:String = 'lod';
/**
* 3dオブジェクト格納するコンテナインスタンス。
*/
public var container:Object3DContainer;
/**
* ビューインスタンスです。
*/
public var view:View;
/**
* カメラインスタンスです。
*/
public var camera:Camera3D;
/**
* カメラコントローラーです。
*/
public var cameraController:SimpleObjectController;
private var _mc:DisplayObjectContainer;
private var _viewWidth:int;
private var _viewHeight:int;
private var _scaleToStage:Boolean;
private var _containerType:String;
/**
* 新しい Alternativa3DTemplate インスタンスを作成します。
* @param mc
* @param containerType
* @param viewWidth
* @param viewHeight
* @param scaleToStage
*/
public function AlternativaTemplate(mc:DisplayObjectContainer,containerType:String=CONFLICT,viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true)
{
_mc = mc;
_mc.addChild(this);
_containerType = containerType;
_viewWidth = viewWidth;
_viewHeight = viewHeight;
_scaleToStage = scaleToStage;
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理をオーバーライドして記述します。
*/
protected function atInit():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
protected function atPreRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
private var _onPreRender:Function = function():void{};
public function get onPreRender():Function { return _onPreRender; }
public function set onPreRender(value:Function):void
{
_onPreRender = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理をオーバーライドして記述します。
*/
protected function atPostRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理を記述します。
*/
private var _onPostRender:Function = function():void{};
public function get onPostRender():Function { return _onPostRender; }
public function set onPostRender(value:Function):void
{
_onPostRender = value;
}
/**
* レンダリングを開始します。
*/
public function startRendering():void
{
addEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* レンダリングを停止します。
*/
public function stopRendering():void
{
removeEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* シングルレンダリング(レンダリングを一回だけ)を実行します。
*/
public function singleRender():void
{
onRenderTick();
}
/**
* @private
*/
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
// entry point
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.quality = StageQuality.HIGH;
//Root objectの作成
if (_containerType == CONFLICT) {
container = new ConflictContainer();
} else if (_containerType == BSP) {
container = new BSPContainer();
} else if (_containerType == ZSORT) {
container = new DistanceSortContainer();
} else if (_containerType == KD) {
container = new KDContainer();
} else if (_containerType == LOD) {
container = new LODContainer();
}
//Viewの作成
view = new View(stage.stageWidth, stage.stageHeight);
_mc.addChild(view);
//cameraの作成
camera = new Camera3D();
camera.view = view;
camera.x = 0;
camera.y = -500;
camera.z = 0;
container.addChild(camera);
// Camera controller
cameraController = new SimpleObjectController(stage, camera, 10);
cameraController.mouseSensitivity = 0;
cameraController.unbindAll();
cameraController.lookAtXYZ(0, 0, 0);
onResize();
stage.addEventListener(Event.RESIZE, onResize);
atInit();
}
/**
* @private
*/
private function onResize(e:Event = null):void
{
if (_scaleToStage)
{
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}
else
{
view.width = _viewWidth;
view.height = _viewHeight;
}
}
/**
* @private
*/
private function onRenderTick(e:Event = null):void
{
atPreRender();
_onPreRender();
cameraController.update();
camera.render();
atPostRender();
_onPostRender();
}
}