BitmapData.fillRect(rect, ARGB)
/**
* Copyright ProjectNya ( http://wonderfl.net/user/ProjectNya )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/rUPt
*/
////////////////////////////////////////////////////////////////////////////////
// BitmapData.fillRect(rect, ARGB)
////////////////////////////////////////////////////////////////////////////////
package {
import flash.display.Sprite;
import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
import frocessing.color.ColorHSV;
[SWF(backgroundColor="#FFFFFF", width="465", height="465", frameRate="30")]
public class Main extends Sprite {
private var wavelet:Wavelet;
private var bitmap:Bitmap;
private var fillBtn:Btn;
private var colorizeBtn:Btn;
public function Main() {
//Wonderfl.capture_delay(1);
init();
}
private function init():void {
var rect:Rectangle = new Rectangle(50, 50, 365, 365);
wavelet = new Wavelet(rect);
addChild(wavelet);
wavelet.x = 50;
wavelet.y = 50;
var color:ColorHSV = new ColorHSV();
color.hsv(210, 0.6, 1);
var color1:uint = color.value;
color.hsv(220, 1, 1);
var color2:uint = color.value;
wavelet.color(color1, color2);
//
var bitmapData:BitmapData = new BitmapData(265, 265, true, 0xFF000000);
bitmap = new Bitmap(bitmapData);
addChild(bitmap);
bitmap.x = 100;
bitmap.y = 100;
//
fillBtn = new Btn();
addChild(fillBtn);
fillBtn.x = 272;
fillBtn.y = 445;
fillBtn.init({label: "fill"});
fillBtn.addEventListener(MouseEvent.CLICK, fill, false, 0, true);
colorizeBtn = new Btn();
addChild(colorizeBtn);
colorizeBtn.x = 192;
colorizeBtn.y = 445;
colorizeBtn.init({label: "colorize"});
colorizeBtn.addEventListener(MouseEvent.CLICK, colorize, false, 0, true);
colorizeBtn.enabled = false;
}
private function fill(evt:MouseEvent):void {
fillBtn.enabled = false;
colorizeBtn.enabled = true;
bitmap.bitmapData.fillRect(bitmap.bitmapData.rect, 0x66000000);
}
private function colorize(evt:MouseEvent):void {
colorizeBtn.enabled = false;
fillBtn.enabled = true;
bitmap.bitmapData.fillRect(bitmap.bitmapData.rect, 0xFF000000);
}
}
}
//////////////////////////////////////////////////
// Waveletクラス
//////////////////////////////////////////////////
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Matrix;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.filters.BlurFilter;
import flash.geom.Rectangle;
import flash.geom.Point;
import flash.display.BlendMode;
import flash.filters.ColorMatrixFilter;
//import com.quasimondo.geom.ColorMatrix;
class Wavelet extends Sprite {
private var rect:Rectangle;
private var wavelet:BitmapData;
private var noise:BitmapData;
private var overlay:Shape;
private static var scale:Number = 1.6;
private var color1:uint;
private var color2:uint;
public function Wavelet(r:Rectangle) {
rect = r;
}
public function color(c1:uint, c2:uint):void {
color1 = c1;
color2 = c2;
draw();
}
private function draw():void {
wavelet = new BitmapData(rect.width, rect.height, false);
noise = new BitmapData(rect.width/scale, rect.height/scale, false);
noise.noise(1, 0, 255, 7, true);
var blur:BlurFilter = new BlurFilter(20, 0, 3);
noise.applyFilter(noise, noise.rect, new Point(), blur);
var matrix:Matrix = new Matrix();
matrix.scale(scale, scale);
var colorMatrixFilter:ColorMatrixFilter = new ColorMatrixFilter();
//var colorMatrix:ColorMatrix = new ColorMatrix();
//colorMatrix.adjustContrast(0.6);
//colorMatrixFilter.matrix = colorMatrix.matrix;
colorMatrixFilter.matrix = adjustContrast(0.6);
noise.applyFilter(noise, noise.rect, new Point(), colorMatrixFilter);
wavelet.draw(noise, matrix, null, BlendMode.DIFFERENCE);
drawOverlay();
addChild(new Bitmap(wavelet));
}
private function adjustContrast(s:Number):Array {
var r:Number;
var g:Number;
var b:Number;
r = g = b = s + 1;
return [r, 0, 0, 0, (128 * (1 - r)), 0, g, 0, 0, (128 * (1 - g)), 0, 0, b, 0, (128 * (1 - b)), 0, 0, 0, 1, 0];
}
private function drawOverlay():void {
overlay = new Shape();
var colors:Array = [color1, color2]
var alphas:Array = [1, 1];
var ratios:Array = [0, 255];
var matrix:Matrix = new Matrix();
matrix.createGradientBox(rect.width, rect.height, 0.5*Math.PI, 0, 0);
overlay.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, matrix, SpreadMethod.REFLECT, InterpolationMethod.RGB, 0);
overlay.graphics.drawRect(0, 0, rect.width, rect.height);
overlay.graphics.endFill();
wavelet.draw(overlay, null, null, BlendMode.HARDLIGHT);
wavelet.draw(overlay, null, null, BlendMode.OVERLAY);
}
}
//////////////////////////////////////////////////
// Btnクラス
//////////////////////////////////////////////////
import flash.display.Sprite;
import flash.display.Shape;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.AntiAliasType;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
import flash.filters.GlowFilter;
import flash.events.MouseEvent;
class Btn extends Sprite {
public var id:uint;
private var shade:Shape;
private var bottom:Shape;
private var light:Shape;
private var base:Shape;
private var txt:TextField;
private var label:String = "";
private static var fontType:String = "_ゴシック";
private var _width:uint = 60;
private static var _height:uint = 20;
private static var corner:uint = 5;
private var type:uint = 1;
private static var bColor:uint = 0xFFFFFF;
private static var sColor:uint = 0x000000;
private static var upColor:uint = 0x666666;
private static var overColor:uint = 0x333333;
private static var offColor:uint = 0x999999;
private static var gColor:uint = 0x0099FF;
private var blueGlow:GlowFilter;
private var shadeGlow:GlowFilter;
private var _clicked:Boolean = false;
private var _enabled:Boolean = true;
public function Btn() {
}
public function init(option:Object):void {
if (option.id != undefined) id = option.id;
if (option.label != undefined) label = option.label;
if (option.width != undefined) _width = option.width;
if (option.type != undefined) type = option.type;
draw();
}
private function draw():void {
switch (type) {
case 1 :
bColor = 0xFFFFFF;
sColor = 0x000000;
upColor = 0x666666;
overColor = 0x333333;
offColor = 0x999999;
break;
case 2 :
bColor = 0x000000;
sColor = 0xFFFFFF;
upColor = 0x666666;
overColor = 0x999999;
offColor = 0x333333;
break;
}
blueGlow = new GlowFilter(gColor, 0.6, 5, 5, 2, 3, false, true);
shadeGlow = new GlowFilter(sColor, 0.3, 4, 4, 2, 3, false, true);
shade = new Shape();
bottom = new Shape();
light = new Shape();
base = new Shape();
txt = new TextField();
addChild(shade);
addChild(bottom);
addChild(light);
addChild(base);
addChild(txt);
createBase(shade, _width, _height, corner, sColor);
shade.filters = [shadeGlow];
createBase(bottom, _width, _height, corner, sColor, 0.3);
createBase(light, _width, _height, corner, gColor);
light.filters = [blueGlow];
createBase(base, _width, _height, corner, bColor);
txt.x = -_width*0.5;
txt.y = -_height*0.5;
txt.width = _width;
txt.height = _height - 1;
txt.type = TextFieldType.DYNAMIC;
txt.selectable = false;
//txt.embedFonts = true;
//txt.antiAliasType = AntiAliasType.ADVANCED;
var tf:TextFormat = new TextFormat();
tf.font = fontType;
tf.size = 12;
tf.align = TextFormatAlign.CENTER;
txt.defaultTextFormat = tf;
txt.text = label;
enabled = true;
mouseChildren = false;
}
private function rollOver(evt:MouseEvent):void {
_over();
}
private function rollOut(evt:MouseEvent):void {
_up();
}
private function press(evt:MouseEvent):void {
_down();
}
private function release(evt:MouseEvent):void {
_up();
}
private function click(evt:MouseEvent):void {
}
private function _up():void {
txt.y = -_height*0.5;
txt.textColor = upColor;
base.y = -1;
light.visible = false;
light.y = -1;
}
private function _over():void {
txt.y = -_height*0.5;
txt.textColor = overColor;
base.y = -1;
light.visible = true;
light.y = -1;
}
private function _down():void {
txt.y = -_height*0.5 + 1;
txt.textColor = overColor;
base.y = 0;
light.visible = true;
light.y = 0;
}
private function _off():void {
txt.y = -_height*0.5 + 1;
txt.textColor = offColor;
base.y = 0;
light.visible = false;
light.y = 0;
}
public function get clicked():Boolean {
return _clicked;
}
public function set clicked(param:Boolean):void {
_clicked = param;
enabled = !_clicked;
if (_clicked) {
_down();
} else {
_up();
}
}
public function get enabled():Boolean {
return _enabled;
}
public function set enabled(param:Boolean):void {
_enabled = param;
buttonMode = _enabled;
mouseEnabled = _enabled;
useHandCursor = _enabled;
if (_enabled) {
_up();
addEventListener(MouseEvent.MOUSE_OVER, rollOver, false, 0, true);
addEventListener(MouseEvent.MOUSE_OUT, rollOut, false, 0, true);
addEventListener(MouseEvent.MOUSE_DOWN, press, false, 0, true);
addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
addEventListener(MouseEvent.CLICK, click, false, 0, true);
} else {
_off();
removeEventListener(MouseEvent.MOUSE_OVER, rollOver);
removeEventListener(MouseEvent.MOUSE_OUT, rollOut);
removeEventListener(MouseEvent.MOUSE_DOWN, press);
removeEventListener(MouseEvent.MOUSE_UP, release);
removeEventListener(MouseEvent.CLICK, click);
}
}
private function createBase(target:Shape, w:uint, h:uint, c:uint, color:uint, alpha:Number = 1):void {
target.graphics.beginFill(color, alpha);
target.graphics.drawRoundRect(-w*0.5, -h*0.5, w, h, c*2);
target.graphics.endFill();
}
}