bitmap：ブラー効果

by _wonder 21 Jan 2010

Embed

/**
 * Copyright _wonder ( http://wonderfl.net/user/_wonder )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/qRhF
 */

// forked from _wonder's forked from: bitmapをランダムで：色をランダム
// forked from _wonder's bitmapをランダムで：色をランダム
// forked from _wonder's bitmapをランダムで
// forked from _wonder's bitmap基本
package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Bitmap;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.display.BlendMode;
    import flash.filters.BlurFilter;
    
    [SWF(width=465,height=465,backgroundColor=0)]
    public class BitmapData1 extends Sprite {
        
        private var bmpdata:BitmapData;
        private var sprite:Sprite;
        private var matrix:Matrix;
        private var colortrans:ColorTransform;
        private var filter:BlurFilter;
        
        public function BitmapData1() {
            bmpdata = new BitmapData(465, 465, false, 0);
            addChild( new Bitmap(bmpdata) );
            
            sprite = newFig( 0, 0, 40, 0XFFFFFF);
            matrix = new Matrix();
            colortrans = new ColorTransform();
            filter = new BlurFilter( 2, 2, 1 );
            
            addEventListener( Event.ENTER_FRAME, enterframe );
            stage.addEventListener( MouseEvent.CLICK, reset );
        }
        
        private function enterframe(e:Event):void{
            bmpdata.applyFilter( bmpdata, bmpdata.rect, bmpdata.rect.topLeft, filter );
            
            matrix.identity();
            var s:Number = Math.random()*2;
            matrix.scale( s, s );
            matrix.rotate( Math.PI * Math.random() );
            matrix.translate( mouseX, mouseY );
            
            colortrans.greenMultiplier = mouseX / 465;
            colortrans.blueMultiplier = mouseY / 465;
            colortrans.alphaMultiplier = Math.random();
            
            bmpdata.draw( sprite, matrix, colortrans, BlendMode.DIFFERENCE );
        }
        
        private function reset(e:MouseEvent):void{
            bmpdata.fillRect( bmpdata.rect, 0X000000 );
        }
        
        private function newFig(cx:Number, cy:Number, size:Number, col:uint):Sprite{
            var shape:Sprite = new Sprite();
            shape.graphics.lineStyle(0, 0X000000, 0.3);
            shape.graphics.beginFill( col );
            shape.graphics.drawCircle( cx, cy, size*0.5 );
            shape.graphics.drawCircle( cx, cy, size*0.4 );
            var w:Number = size*0.6;
            var h:Number = size*0.15;
            shape.graphics.drawRect( cx-w/2, cy-h/2, w, h );
            shape.graphics.endFill();
            return shape;
        }
    }
}