フォードの円 -Ford circle-
/**
* Copyright Aquioux ( http://wonderfl.net/user/Aquioux )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/pTrv
*/
package {
import flash.display.Graphics;
import flash.display.Sprite;
[SWF(width = "465", height = "465", frameRate = "30", backgroundColor = "#FFFFFF")]
/**
* ファレイ数列とフォードの円 Farey sequence & Ford circle
*/
public class Main extends Sprite {
// ファレイ数列から計算されたフォードの円の座標値を一次元配列で格納
private var data_:Vector.<Number>;
/**
* コンストラクタ
*/
public function Main() {
setup();
draw();
}
// セットアップ
private function setup():void {
// ファレイ数列を作る
var farey:Vector.<String> = Calculator.createFareySequence(8)
// フォードの円の座標値を求める
data_ = Calculator.calcFordCircleCenter(farey);
}
// 描画
private function draw():void {
var g:Graphics = this.graphics;
var scale:int = stage.stageWidth;
var len:int = data_.length;
for (var i:int = 0; i < len; i += 2) {
var posX:Number = data_[i];
var posY:Number = data_[i + 1];
g.beginFill(0x0);
g.drawCircle(posX * scale, (1 - posY) * scale, posY * scale);
g.endFill();
}
}
}
}
//package {
/**
* ファレイ数列とフォードの円 Farey sequence & Ford circle
*/
/*public*/ class Calculator {
// F1 のファレイ数列
private static const FAREY1:Vector.<String> = Vector.<String>(["0/1", "1/1"]);
/**
* ファレイ数列の生成
* @param degree ファレイ数列が対応する整数
* @return ファレイ数列
*/
public static function createFareySequence(degree:uint):Vector.<String> {
var currentData:Vector.<String> = new Vector.<String>();
var nextData:Vector.<String> = new Vector.<String>();
var prevStr1:String = null;
currentData = FAREY1;
// ファレイ数列に対応する i をインクリメントする
for (var i:int = 2; i <= degree; i++) {
var len:int = currentData.length;
// i-1 に対応するファレイ数列から i に対応するファレイ数列を作るため、ファレイ数列の要素を爪弾く
for (var j:int = 1; j < len; j++) {
var str0:String = currentData[j - 1];
var str1:String = currentData[j];
var uints0:Vector.<int> = stringToInt(str0);
var uints1:Vector.<int> = stringToInt(str1);
var a:uint = uints0[0]; // 小さい分数の分子
var b:uint = uints0[1]; // 小さい分数の分母
var c:uint = uints1[0]; // 大きい分数の分子
var d:uint = uints1[1]; // 大きい分数の分母
// 前回の str1 の確認
if ((prevStr1) && (prevStr1 != str0)) nextData.push(prevStr1);
// 今回の str0 をデータとして登録
nextData.push(str0);
// 中間数の計算および評価
var mediant:String = null;
var denominator:uint = b + d;
if (denominator <= degree) mediant = String(a + c) + "/" + String(denominator);
if (mediant) nextData.push(mediant);
// ファレイ数列の要素爪弾く前の準備
prevStr1 = str1;
}
// ループを抜けた（i に対応するファレイ数列ができた）ので、最後の分数 str1（= "1/1"）を登録
nextData.push(str1);
// ファレイ数列に対応する整数をインクリメントする前の準備
currentData = nextData;
nextData = new Vector.<String>();
prevStr1 = null;
}
currentData.fixed = true;
return currentData;
}
/**
* ファレイ数列のシフト
* 0 ～ 1の範囲から scale ～ scale+1 の範囲の値にシフトする
* @param farey 元データ
* @param scale シフト値
* @return シフト後のデータ
*/
public static function shift(farey:Vector.<String>, scale:int):Vector.<String> {
var ret:Vector.<String> = new Vector.<String>();
var len:int = farey.length;
for (var i:int = 0; i < len; i++) {
// String から Number に
var fraction:Vector.<int> = stringToInt(farey[i]);
var numerator:Number = Number(fraction[0]);
var denominator:Number = Number(fraction[1]);
// シフト計算
numerator += denominator * scale;
// 再び分数の形式にして置換
ret.push(String(numerator) + "/" + String(denominator));
}
ret.fixed = true;
return ret;
}
/**
* ファレイ数列からフォードの円の中心座標を計算
* @param farey ファレイ数列
* @return フォードの円の中心座標を一次元配列で格納した Vector
*/
public static function calcFordCircleCenter(farey:Vector.<String>):Vector.<Number> {
var data:Vector.<Number> = new Vector.<Number>();
var len:int = farey.length;
for (var i:int = 0; i < len; i++) {
// String から Number に
var fraction:Vector.<int> = stringToInt(farey[i]);
var numerator:Number = Number(fraction[0]);
var denominator:Number = Number(fraction[1]);
// 座標値
var posX:Number = numerator / denominator;
var posY:Number = 1 / (denominator * denominator * 2);
data.push(posX, posY);
}
data.fixed = true;
return data;
}
// ファレイ数列のひとつの要素を String から、分子・分母の二つの uint に変換
private static function stringToInt(data:String):Vector.<int> {
var d:Array = data.split("/");
return Vector.<int>([int(d[0]), int(d[1])]);
}
}
//}