Alternativa3D Tips さまざまなプリミティブを作る
Alternativa3D Tips さまざまなプリミティブを作る
Alternativa3D に用意されているプリミティブは、Box、Cone、 Plane、Sphere（GeoPlane、GeoSphere）だけで、
Pv3と比べると、PaperPlaneとCylinderが足りません。
まあ、PaperPlaneはどうでもいいとしても、
何かちょろっと作ろうと思った時、円柱が欲しいなーと（丸いボタンとか）思ったりします。
で、自作クラス作ろうか、break氏のEasyCreateMesh使おうか、と色々思案してたのですが、
ふと、円柱って、Sphereいじればできるんじゃね？っと思ったので、さくっと作ろうかとも思ったのですが、、
ここで、一つ、気になってたことを思い出しました。
Coneのコンストラクタ引数にある、height:Number = 100, bottomRadius:Number = 100, topRadius:Number = 0, のtopRadius:Number = 0ってなんだ？と...
PV3Dでは、Coneはradius:Number = 100, height:Number = 100,のみ
つまり、これは上面の大きさも変えられるということ？
で、色々やってみてできたのが、このサンプルです。
textureテストのBox以外、すべて、Coneでできています。
こんな仕様だから、Cylinderがなかったのねと、一人で納得ｗｗ
@narutohyper
Alternativa3D を簡単に扱うためのベーシックテンプレート
@author Yasu (clockmaker)
/**
* Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/nz7E
*/
package {
import alternativ5.engine3d.materials.FillMaterial;
import alternativ5.engine3d.materials.TextureMaterial;
import alternativ5.engine3d.materials.TextureMaterialPrecision
import alternativ5.engine3d.primitives.Cone;
import alternativ5.engine3d.primitives.Box;
import alternativ5.engine3d.primitives.Sphere
import alternativ5.engine3d.core.Object3D;
import alternativ5.engine3d.core.Mesh;
import alternativ5.engine3d.core.Vertex;
import alternativ5.types.Point3D;
import alternativ5.types.Texture;
import alternativ5.utils.*
import flash.display.Sprite;
import flash.display.BlendMode;
import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.display.GradientType;
import flash.geom.Matrix;
[SWF(width = 465, height = 465, frameRate = 24,backgroundColor=0xFFFFFF)]
/**
* Alternativa3D Tips さまざまなプリミティブを作る
*
* Alternativa3D に用意されているプリミティブは、Box、Cone、 Plane、Sphere（GeoPlane、GeoSphere）だけで、
* Pv3と比べると、PaperPlaneとCylinderが足りません。
* まあ、PaperPlaneはどうでもいいとしても、
* 何かちょろっと作ろうと思った時、円柱が欲しいなーと（丸いボタンとか）思ったりします。
*
* で、自作クラス作ろうか、break氏のEasyCreateMesh使おうか、と色々思案してたのですが、
* ふと、円柱って、Sphereいじればできるんじゃね？っと思ったので、さくっと作ろうかとも思ったのですが、、
* ここで、一つ、気になってたことを思い出しました。
*
* Coneのコンストラクタ引数にある、height:Number = 100, bottomRadius:Number = 100, topRadius:Number = 0, のtopRadius:Number = 0ってなんだ？と...
* PV3Dでは、Coneはradius:Number = 100, height:Number = 100,のみ
* つまり、これは上面の大きさも変えられるということ？
*
* で、色々やってみてできたのが、このサンプルです。
* textureテストのBox以外、すべて、Coneでできています。
*
*
* こんな仕様だから、Cylinderがなかったのねと、一人で納得ｗｗ
*
* @narutohyper
*/
/**
* Alternativa3D を簡単に扱うためのベーシックテンプレート
* @author Yasu (clockmaker)
*/
public class SimpleDemo extends Sprite {
public function SimpleDemo():void {
// テンプレートを作成します
var template:BasicTemplate = new BasicTemplate();
addChild(template);
template.camera.z = -500;
var base:Object3D=new Object3D;
template.scene.root.addChild(base);
// プリミティブを作成します
//三角形
var column3:Cone = new Cone(50,50,50,1,3)
column3.setMaterialToSurface(new FillMaterial(0x9999CC),'side');
column3.setMaterialToSurface(new FillMaterial(0xCCCCFF),'top');
column3.setMaterialToSurface(new FillMaterial(0x666699),'bottom');
column3.coords=new Point3D(0,0,0)
base.addChild(column3);
//四角形
var column4:Cone = new Cone(50,50,50,1,4)
column4.setMaterialToSurface(new FillMaterial(0x99CC99),'side');
column4.setMaterialToSurface(new FillMaterial(0xCCFFCC),'top');
column4.setMaterialToSurface(new FillMaterial(0x669966),'bottom');
column4.coords=new Point3D(-100,100,100)
base.addChild(column4);
//五角形
var column5:Cone = new Cone(50,50,50,1,5)
column5.setMaterialToSurface(new FillMaterial(0xCC9999),'side');
column5.setMaterialToSurface(new FillMaterial(0xFFCCCC),'top');
column5.setMaterialToSurface(new FillMaterial(0x996666),'bottom');
column5.coords=new Point3D(-100,-100,100)
base.addChild(column5);
//六角形
var column6:Cone = new Cone(50,50,50,1,6)
column6.setMaterialToSurface(new FillMaterial(0xCC99CC),'side');
column6.setMaterialToSurface(new FillMaterial(0xFFEEFF),'top');
column6.setMaterialToSurface(new FillMaterial(0x994499),'bottom');
column6.coords=new Point3D(-100,100,-100)
base.addChild(column6);
//三十六角形
var column36:Cone = new Cone(50,50,50,1,36)
column36.setMaterialToSurface(new FillMaterial(0x99CCCC),'side');
column36.setMaterialToSurface(new FillMaterial(0xEEFFFF),'top');
column36.setMaterialToSurface(new FillMaterial(0x449999),'bottom');
column36.coords=new Point3D(100,-100,-100)
base.addChild(column36);
//おまけ1・・・三角錐
var column2:Cone = new Cone(60,50,0,1,3)
//sideの塗りわけができないので、sideのfaceを、それぞれ、別のサーフェースにする
column2.removeSurface(column2.getSurfaceById('side'))
column2.createSurface(['0_0'],'side_0')
column2.createSurface(['1_0'],'side_1')
column2.createSurface(['2_0'],'side_2')
column2.setMaterialToSurface(new FillMaterial(0xCC8833),'side_0');
column2.setMaterialToSurface(new FillMaterial(0xFFA14F),'side_1');
column2.setMaterialToSurface(new FillMaterial(0xFFD897),'side_2');
column2.setMaterialToSurface(new FillMaterial(0xCC6600),'bottom');
column2.coords=new Point3D(-100,-100,-100)
base.addChild(column2);
//おまけ2・・・10角形を改造して星にする・・・が、裏（bottom）の面がひっくり返ってしまって見えなくなってしまうｗ
var column10:Cone = new Cone(50,50,50,1,10)
column10.setMaterialToSurface(new FillMaterial(0xCCCC00),'side');
column10.setMaterialToSurface(new FillMaterial(0xFFFF66),'top');
column10.coords=new Point3D(100,-100,100)
base.addChild(column10);
var v1:Vertex;
var v2:Vertex;
var tx:Number;
var ty:Number;
var r:Number;
for (var i:uint=0;i<10;i++) {
v1=column10.getVertexById(i+'_'+0)
v2=column10.getVertexById(i+'_'+1)
if (i%2==0) {
r=30
} else {
r=50
}
tx=Math.cos(MathUtils.toRadian(360/10*i))*r
ty=Math.sin(MathUtils.toRadian(360/10*i))*r
v1.x=tx
v1.y=ty
v2.x=tx
v2.y=ty
}
column10.removeSurface('bottom')
column10.removeFace('bottom')
/*
//なので、一度bottomのSurface,Faceを作り直す。
//が！！時計回り、半時計周りどちらも試したけど、ひっくり返ったまま。
//column10.createFace(['0_0', '1_0', '2_0', '3_0', '4_0', '5_0', '6_0', '7_0', '8_0', '9_0'],'bottom')
//column10.createFace(['9_0', '8_0', '7_0', '6_0', '5_0', '4_0', '3_0', '2_0', '1_0', '0_0'],'bottom')
//しょうがないので、中心点を作って、５枚のfaceを新たに作り、Surfaceに割り付けるｗ
*/
column10.createVertex(0,0,-25,'b_0')
column10.createFace(['0_0','9_0','b_0','1_0'],'bottom0')
column10.createFace(['8_0','7_0','b_0','9_0'],'bottom1')
column10.createFace(['6_0','5_0','b_0','7_0'],'bottom2')
column10.createFace(['4_0','3_0','b_0','5_0'],'bottom3')
column10.createFace(['2_0','1_0','b_0','3_0'],'bottom4')
column10.createSurface(['bottom0','bottom1','bottom2','bottom3','bottom4'],'bottom')
column10.setMaterialToSurface(new FillMaterial(0x9999944),'bottom');
//で、星の完成
//おまけ3・・・バグの検証？Coneには、TextureMaterialが貼り付けられない
//2010/02/15修正 triangulate = trueで貼り付けられました。
//var columnError:Cone = new Cone(50,50,50,1,4)
var columnError:Cone = new Cone(50,50,50,1,4,false,true)
columnError.coords=new Point3D(100,100,-100)
base.addChild(columnError);
var box:Box = new Box(50,70,70)
box.coords=new Point3D(100,100,100)
base.addChild(box);
var sphere:Sphere=new Sphere(50,8,8,false,true);
sphere.coords=new Point3D(100,0,100);
base.addChild(sphere);
//テスト用グラデーションのマテリアルを作成する
var bmd1:BitmapData=new BitmapData(100,100,false,0xFF000000)
var bmd2:BitmapData=new BitmapData(100,100,false,0xFF000000)
var tempSprite:Sprite=new Sprite();
var colors:Array=new Array(0xCCCCCC,0x333333)
var alphas:Array=new Array(1,1)
var ratios:Array=new Array(0,255)
var matrix:Matrix=new Matrix()
matrix.createGradientBox(100,100,Math.PI/3,0,0)
tempSprite.graphics.beginGradientFill(GradientType.LINEAR,colors, alphas, ratios, matrix)
tempSprite.graphics.drawRect(0,0,100,100)
bmd1.draw(tempSprite)
bmd2.draw(tempSprite)
//ConeとBox両方に同じ様に、TextureMaterialを貼り付ける
columnError.cloneMaterialToAllSurfaces(new TextureMaterial(new Texture(bmd1),1,true,true,BlendMode.NORMAL,-1,0x000000,TextureMaterialPrecision.BEST));
box.cloneMaterialToAllSurfaces(new TextureMaterial(new Texture(bmd2),1,true,true,BlendMode.NORMAL,-1,0x000000,TextureMaterialPrecision.BEST));
sphere.cloneMaterialToAllSurfaces(new TextureMaterial(new Texture(bmd2),1,true,true,BlendMode.NORMAL,-1,0x000000,TextureMaterialPrecision.BEST));
//明るい面が上に行くように回転
//column.rotationX = MathUtils.toRadian(90)
// Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
// レンダリング前に実行したい処理を記述します。
template.onPreRender = function():void {
// 立方体を回転させます (角度はラジアン)
base.rotationY += 1 * Math.PI / 180;
box.rotationY += 5 * Math.PI / 180;
sphere.rotationY += 5 * Math.PI / 180;
columnError.rotationY += 5 * Math.PI / 180;
column2.rotationY += 5 * Math.PI / 180;
column3.rotationY += 5 * Math.PI / 180;
column4.rotationY += 5 * Math.PI / 180;
column5.rotationY += 5 * Math.PI / 180;
column6.rotationY += 5 * Math.PI / 180;
column10.rotationY += 5 * Math.PI / 180;
column36.rotationY += 5 * Math.PI / 180;
// マウスがステージの高さ何%の位置にあるか算出
var rateY:Number = mouseY / stage.stageHeight;
// カメラの高さの座標を調整
// イージングの公式 対象の値 += (目標値 - 現在の値) * 減速率
template.camera.y += ( - 1000 * rateY - template.camera.y) * 0.1;
// カメラの座標を中央に向かせる
template.cameraContoller.lookAt(new Point3D());
}
}
}
}
import alternativ5.engine3d.controllers.CameraController;
import alternativ5.engine3d.core.Camera3D;
import alternativ5.engine3d.core.Object3D;
import alternativ5.engine3d.core.Scene3D;
import alternativ5.engine3d.display.View;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
/**
* BasicTemplate for Alternativa3D
* Alternativa3Dを扱いやすくするためのテンプレートです
* @author Yasu
*/
class BasicTemplate extends Sprite{
/**
* シーンインスタンスです。
*/
public var scene:Scene3D;
/**
* ビューインスタンスです。
*/
public var view:View;
/**
* カメラインスタンスです。
*/
public var camera:Camera3D;
/**
* カメラコントローラーです。
*/
public var cameraContoller:CameraController;
private var _viewWidth:int;
private var _viewHeight:int;
private var _scaleToStage:Boolean;
/**
* 新しい BasicTemplate インスタンスを作成します。
* @param viewWidth
* @param viewHeight
* @param scaleToStage
*/
public function BasicTemplate(viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true) {
_viewWidth = viewWidth;
_viewHeight = viewHeight;
_scaleToStage = scaleToStage;
// Creating scene
scene = new Scene3D();
scene.splitAnalysis = false; // not analysis for performance
scene.root = new Object3D();
// Adding camera
camera = new Camera3D();
camera.z = -1000;
scene.root.addChild(camera);
// camera contoller
cameraContoller = new CameraController(this);
cameraContoller.camera = camera;
// set view
view = new View();
view.camera = camera;
addChild(view);
// stage
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理をオーバーライドして記述します。
*/
protected function atInit():void {}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理を記述します。
*/
private var _onInit:Function = function():void { };
public function get onInit():Function { return _onInit; }
public function set onInit(value:Function):void {
_onInit = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
protected function atPreRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理を記述します。
*/
private var _onPreRender:Function = function():void{};
public function get onPreRender():Function { return _onPreRender; }
public function set onPreRender(value:Function):void {
_onPreRender = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理をオーバーライドして記述します。
*/
protected function atPostRender():void {
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理を記述します。
*/
protected var _onPostRender:Function = function():void{};
public function get onPostRender():Function { return _onPostRender; }
public function set onPostRender(value:Function):void {
_onPostRender = value;
}
/**
* レンダリングを開始します。
*/
public function startRendering():void {
addEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* レンダリングを停止します。
*/
public function stopRendering():void {
removeEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* シングルレンダリング(レンダリングを一回だけ)を実行します。
*/
public function singleRender():void {
onRenderTick();
}
/**
* @private
*/
private function init(e:Event = null):void {
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.quality = StageQuality.HIGH;
// resize
stage.addEventListener(Event.RESIZE, onResize);
onResize(null);
// render
startRendering();
atInit();
_onInit();
}
/**
* @private
*/
private function onRenderTick(e:Event = null):void {
atPostRender();
_onPostRender();
scene.calculate();
atPreRender();
_onPreRender();
}
/**
* @private
*/
private function onResize(event:Event = null):void {
if (_scaleToStage) {
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}else {
view.width = _viewWidth;
view.height = _viewHeight;
}
}
}