OriginalMaterial (MovieClipMaterial) [Alternativa3D 7.6 TIPS]
5.6では実装されていた、MovieClipMaterialは、7.5では実装されていませんでした。
なので、TextureMaterialを継承して、MovieClipMaterialを作成してみました。
なお、Material及び、描画の構造は5.6に比べぐっとシンプルになっていますので、
比較的、拡張は簡単な模様。
同じ要領で、フラットやグローといったシェーディング系のマテリアルも実装できそうです。
ただ、texture（BitmapData）への書き込みをDrawしてるあたりが、ボトルネックになりそうな予感ｗ
2011/01/12 7.5から7.6仕様に変更
/**
* Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/mmay
*/
// forked from narutohyper's Alternativa3D 7.5 Template
package
{
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.Vertex;
import alternativ7.engine3d.loaders.MaterialLoader;
import alternativ7.engine3d.materials.TextureMaterial;
import alternativ7.engine3d.objects.Mesh;
import alternativ7.engine3d.primitives.Box;
import alternativ7.engine3d.primitives.Plane;
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;
import flash.system.LoaderContext;
/**
* Alternativa3D 7.6
*
* 5.6では実装されていた、MovieClipMaterialは、7.5では実装されていませんでした。
* なので、TextureMaterialを継承して、MovieClipMaterialを作成してみました。
*
* なお、Material及び、描画の構造は5.6に比べぐっとシンプルになっていますので、
* 比較的、拡張は簡単な模様。
* 同じ要領で、フラットやグローといったシェーディング系のマテリアルも実装できそうです。
* ただ、texture（BitmapData）への書き込みをDrawしてるあたりが、ボトルネックになりそうな予感ｗ
*
* ...
* @author narutohyper
*/
[SWF(backgroundColor="#000000", frameRate="100", width="800", height="600")]
public class Main extends Sprite
{
public function Main():void {
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
private function init(e:Event=null):void {
removeEventListener(Event.ADDED_TO_STAGE, init);
//AlternativaTemplate作成
var scene:AlternativaTemplate = new AlternativaTemplate(this);
//まとめてcontrolするために、core.Object3DContainerを作成し、各Objectを入れ子にする
var animeObject:Object3DContainer = new Object3DContainer;
scene.container.addChild(animeObject);
//statusの表示
addChild(scene.camera.diagram);
//自作material、MovieClipMaterialによるMaterial作成
//別にSpriteとかでもOKなんだけど、とりあえずMC
var mc:MovieClip = new testMc();
var movieClipMaterial:TextureMaterial = new MovieClipMaterial(mc, false, true);
//オリジナルプリミティブ、PolygonPlaneを使用して、様々な図形を作成
//Planeを作成
var box:Box = new Box(500, 500, 500, 1, 1, 1);
box.setMaterialToAllFaces(movieClipMaterial);
animeObject.addChild(box);
//カメラの調整
//カメラはControllerに関連付けている為、x,y,zで直接位置を指定できないので
//SimpleController.setObjectPosXYZを使用
scene.cameraController.setObjectPosXYZ(0, -1500, 500);
scene.cameraController.lookAtXYZ(0, 0, 0);
//ObjectControllerの作成
//MouseDragで、Objectを回転させる為のController
var objectController:SimpleObjectController = new SimpleObjectController(stage,animeObject,100);
objectController.unbindAll();
scene.onPreRender = function():void {
objectController.update();
}
//描画開始
scene.startRendering();
}
}
}
import alternativ7.engine3d.materials.TextureMaterial;
import flash.display.BitmapData;
import flash.display.DisplayObject;
import flash.events.Event;
/**
* TextureMaterialを継承して作成したMovieClipMaterial
*
* @author narutohyper
*/
class MovieClipMaterial extends TextureMaterial
{
private var _mc:DisplayObject;
public function MovieClipMaterial(displayObject:DisplayObject, repeat:Boolean = false, smooth:Boolean = true, mipMapping:int = 0, resolution:Number = 1)
{
super(null,repeat,smooth,mipMapping,resolution);
mc = displayObject;
}
public function get mc():DisplayObject { return _mc; }
public function set mc(value:DisplayObject):void
{
_mc = value;
texture = new BitmapData(_mc.width, _mc.height, true, 0);
if (_mc && !_mc.hasEventListener('ENTER_FRAME')) {
_mc.addEventListener(Event.ENTER_FRAME, onEnterFrame);
}
}
private function onEnterFrame(e:Event):void
{
if (mc) {
texture.draw(mc);
}
}
}
import flash.display.MovieClip;
import flash.display.GradientType;
import flash.display.Shape;
import flash.geom.Matrix;
class testMc extends MovieClip {
private var ball:Shape;
private var pitchX:Number = 10;
private var pitchY:Number = 10;
public function testMc() {
var colors:Array=new Array(0x000099,0x000033);
var alphas:Array=new Array(1,1);
var ratios:Array=new Array(0,255);
var matrix:Matrix=new Matrix();
matrix.createGradientBox(800,800,0,0,0);
graphics.beginGradientFill(GradientType.RADIAL,colors, alphas, ratios, matrix);
graphics.drawRect(0, 0, 500, 500);
ball = new Shape();
ball.graphics.beginFill(0xFFFFFF);
ball.graphics.drawRect( -10, -10, 20, 20);
addChild(ball);
pitchX = 10;
pitchY = 10;
ball.x = 100;
ball.y = 50;
addEventListener(Event.ENTER_FRAME, onEnterFrame);
}
private function onEnterFrame(e:Event):void
{
ball.x += pitchX;
ball.y += pitchY;
if (ball.x>500-10) {
ball.x = 500 - 10;
pitchX*=-1;
} else if (ball.x<0+10) {
ball.x = 10;
pitchX*=-1;
}
if (ball.y>500-10) {
ball.y = 500 - 10;
pitchY*=-1;
} else if (ball.y<0+10) {
ball.y = 10;
pitchY*=-1;
}
}
}
/**
* BasicTemplate for Alternativa3D 7.5
* Alternativa3D 7.5を扱いやすくするためのテンプレートです
* @author narutohyper & clockmaker
*
*/
import alternativ7.engine3d.containers.BSPContainer;
import alternativ7.engine3d.containers.ConflictContainer;
import alternativ7.engine3d.containers.DistanceSortContainer;
import alternativ7.engine3d.containers.KDContainer;
import alternativ7.engine3d.containers.LODContainer;
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Camera3D;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.View;
import flash.display.DisplayObject;
import flash.display.DisplayObjectContainer;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
class AlternativaTemplate extends Sprite
{
/**
* 子オブジェクトを最適な方法でソートするコンテナ
* (ConflictContainer)
*/
public static const CONFLICT:String = 'conflict';
/**
* 子オブジェクトをBSP(バイナリ空間分割法)によってソートするコンテナ
* (BSPContainer)
*/
public static const BSP:String = 'bsp';
/**
* 子オブジェクトをカメラからのZ値でソートするコンテナ
* (DistanceSortContainer)
*/
public static const ZSORT:String = 'zsort';
/**
* KDツリー(http://ja.wikipedia.org/wiki/Kd%E6%9C%A8)によってソートするコンテナ
* (KDContainer)
*/
public static const KD:String = 'kd';
/**
* detalizationと子オブジェクトの距離でソートするコンテナ（詳細は調査中）
* (LODContainer)
*/
public static const LOD:String = 'lod';
/**
* 3dオブジェクト格納するコンテナインスタンス。
*/
public var container:Object3DContainer;
/**
* ビューインスタンスです。
*/
public var view:View;
/**
* カメラインスタンスです。
*/
public var camera:Camera3D;
/**
* カメラコントローラーです。
*/
public var cameraController:SimpleObjectController;
private var _mc:DisplayObjectContainer;
private var _viewWidth:int;
private var _viewHeight:int;
private var _scaleToStage:Boolean;
private var _containerType:String;
/**
* 新しい Alternativa3DTemplate インスタンスを作成します。
* @param mc
* @param containerType
* @param viewWidth
* @param viewHeight
* @param scaleToStage
*/
public function AlternativaTemplate(mc:DisplayObjectContainer,containerType:String=CONFLICT,viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true)
{
_mc = mc;
_mc.addChild(this);
_containerType = containerType;
_viewWidth = viewWidth;
_viewHeight = viewHeight;
_scaleToStage = scaleToStage;
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理をオーバーライドして記述します。
*/
protected function atInit():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
protected function atPreRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
private var _onPreRender:Function = function():void{};
public function get onPreRender():Function { return _onPreRender; }
public function set onPreRender(value:Function):void
{
_onPreRender = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理をオーバーライドして記述します。
*/
protected function atPostRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理を記述します。
*/
private var _onPostRender:Function = function():void{};
public function get onPostRender():Function { return _onPostRender; }
public function set onPostRender(value:Function):void
{
_onPostRender = value;
}
/**
* レンダリングを開始します。
*/
public function startRendering():void
{
addEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* レンダリングを停止します。
*/
public function stopRendering():void
{
removeEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* シングルレンダリング(レンダリングを一回だけ)を実行します。
*/
public function singleRender():void
{
onRenderTick();
}
/**
* @private
*/
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
// entry point
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.quality = StageQuality.HIGH;
//Root objectの作成
if (_containerType == CONFLICT) {
container = new ConflictContainer();
} else if (_containerType == BSP) {
container = new BSPContainer();
} else if (_containerType == ZSORT) {
container = new DistanceSortContainer();
} else if (_containerType == KD) {
container = new KDContainer();
} else if (_containerType == LOD) {
container = new LODContainer();
}
//Viewの作成
view = new View(stage.stageWidth, stage.stageHeight);
_mc.addChild(view);
//cameraの作成
camera = new Camera3D();
camera.view = view;
camera.x = 0;
camera.y = -500;
camera.z = 0;
container.addChild(camera);
// Camera controller
cameraController = new SimpleObjectController(stage, camera, 10);
cameraController.mouseSensitivity = 0;
cameraController.unbindAll();
cameraController.lookAtXYZ(0, 0, 0);
onResize();
stage.addEventListener(Event.RESIZE, onResize);
atInit();
}
/**
* @private
*/
private function onResize(e:Event = null):void
{
if (_scaleToStage)
{
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}
else
{
view.width = _viewWidth;
view.height = _viewHeight;
}
}
/**
* @private
*/
private function onRenderTick(e:Event = null):void
{
atPreRender();
_onPreRender();
cameraController.update();
camera.render();
atPostRender();
_onPostRender();
}
}