In case Flash no longer exists; a copy of this site is included in the Flashpoint archive's "ultimate" collection.

Dead Code Preservation :: Archived AS3 works from wonderfl.net

マウスに反応して動く円

マウスに反応して動く円
/**
 * Copyright shmdmoto ( http://wonderfl.net/user/shmdmoto )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/mWzX
 */

// forked from shmdmoto's forked from: forked from: 多くの円がマウスを追いかける
// forked from shmdmoto's forked from: 多くの円がマウスを追いかける
// forked from shmdmoto's 多くの円がマウスを追いかける
package 
{
    import flash.events.MouseEvent;
    
    import frocessing.display.F5MovieClip2D;
    /**
     * マウスが近くにくると追いかけるように小円を描く
     * @author shmdmoto
     */
    public class mouseTrack2 extends F5MovieClip2D
    {
        public var posX:Number; // マウスポインタのx座標
        public var posY:Number; // マウスポインタのY座標
        public var circX:Array; // 円の中心のx座標
        public var circY:Array; // 円の中心のy座標
        public var restX:Array; // 円の中心のx座標
        public var restY:Array; // 円の中心のy座標
  
        public function mouseTrack2() {
            super(false);
        }
        public function setup() : void
        {
            var i:int;
            var j:int;
            posX = 0;
            posY = 0;
            restX = new Array(20*20);
            restY = new Array(20*20);
            circX = new Array(20*20);
            circY = new Array(20*20);
            var elNum:int = 0;
            stage.addEventListener(MouseEvent.MOUSE_MOVE, onMove);
            for( i = 0 ; i < 20 ; i++ ) {
                for( j = 0 ; j < 20 ; j++) {
                    restX[elNum] = new Number();
                    restX[elNum] =  stage.stageWidth * j / 20 ;
                    restY[elNum] = new Number();
                    restY[elNum] =  stage.stageHeight * i / 20;
                    circX[elNum] = new Number();
                    circX[elNum] = restX[elNum];
                    circY[elNum] = new Number();
                    circY[elNum] = restY[elNum];
                    elNum++;                    
                }
            } 
        }
        public function draw() : void
        {
            var r:Number;
            fill(255,0,0);
            noStroke();
            for( var i:int = 0 ; i < 20 * 20 ; i++) {
                ellipse(circX[i], circY[i], 10,10);
                r = dist(posX,posY,circX[i],circY[i] );
                if( r > 5 ) {
                    circX[i] = circX[i] - (posX-circX[i])/r/r * 70
                        +(restX[i] - circX[i])*0.05;
                    circY[i] = circY[i] - (posY-circY[i])/r/r * 70
                        +(restY[i] - circY[i])*0.05 ;
                }
            }
        }
        public function onMove(event:MouseEvent):void 
        {
            posX = event.stageX;
            posY = event.stageY;
        }
        
    }
}

// 以下は,動きを記述するためのクラスですので,編集しないでください.
import flash.utils.getTimer;
import frocessing.math.PerlinNoise;
/**
 * Interpolate:指定した時間で,開始値から終値までの過渡的を
 *             記述するクラス
 */
class Interpolate
{
    private static const NOINIT  :int = 1;
    private static const RUNNING :int = 2;
    private static const WAITING :int = 3;
    private static const STOPPED :int = 3;
    private var duration  :Number;
    private var begin     :Number;
    private var end       :Number;
    private var pow       :Number;
    private var tOffset   :Number;
    private var tElapsed  :Number;
    private var prevVal   :Number;
    private var tRestart  :Number;
    public  var status    :int = NOINIT;
    public function Interpolate( t:Number, s:Number, f:Number,
                                 p:Number = 1) {
        begin = prevVal = s;
        end = f;
        duration = t;
        pow = p;
    }
    public function val() :Number {
        var t :Number;
        if( status == NOINIT){
            tOffset = getTimer()/1000;
            prevVal = begin;
            status = RUNNING;
        } else if( status == RUNNING ) {
            t = getTimer()/1000;
            tElapsed = t -tOffset;
            if( tElapsed < duration ) {
                prevVal = begin + ( end - begin )*Math.pow(tElapsed/duration,pow);
            } else {
                prevVal = end;
                status = STOPPED;
            }
        } else if( status == WAITING){
            t = getTimer()/1000;
            if( t >= tRestart) {
                status = RUNNING;
                tOffset = t - tElapsed;        
            }
        }
        return prevVal;
    }
    public function pause() :void
    {
        status = STOPPED;        
    }
    public function cont() :void
    {
        status = RUNNING;
        tOffset = getTimer()/1000-tElapsed;        
    }
    public function start() :void
    {
        status = RUNNING;
        tOffset = getTimer()/1000;                
    }
    public function wait( waitTime :Number ) :void
    {
        status = WAITING;
        tRestart = getTimer() + waitTime;
    }
    
    public function isRunning() :Boolean
    {
        if( status == RUNNING ) {
            return true;
        } else {
            return false;
        }
    }
    public function isStopped() :Boolean
    {
        if( status == STOPPED ) {
            return true;
        } else {
            return false;
        }
    }
    public function isEnd() :Boolean
    {
        if( prevVal >= end) {
            return true;
        } else {
            return false;
        }
    }
}
/**
 * LFO:指定した時間での周期的変動を記述するクラス
 */
class LFO {
    public static const SIN    :int = 1;
    public static const COS    :int = 2;
    public static const SAW    :int = 3;
    public static const TRI    :int = 4;
    public static const SQR    :int = 5;
    public static const ABSSIN :int = 6;
    public static const NOISE  :int = 7;
    private static const NOINIT  :int = 1;
    private static const RUNNING :int = 2;
    private static const WAITING :int = 3;
    private static const STOPPED :int = 4;
    private var period    :Number;
    private var amplitude :Number;
    private var phase     :Number;
    private var offset    :Number;
    private var type      :int = SIN;
    private var isStart   :Boolean;
    private var t_offset  :Number;
    private var status    :int = NOINIT;
    
    public function LFO( prd :Number, amp :Number,
                         of :Number = 0, ph :Number = 0)
    {
        period    = prd;
        amplitude = amp;
        offset    = of;
        phase     = ph;
    }
    public function setPeak( min :Number, max :Number) :void
    {
        offset = (min + max) / 2;
        if( min < max ) {
            amplitude    = (max - min) / 2;
        } else {
            amplitude    = (min - max) / 2;
        }        
    }
    public function setType( t :int ) :void
    {
        type = t;
    }
    public function val( mul :Number=1.0 ) :Number {
        if(status == NOINIT) {
            status = RUNNING;
            t_offset = getTimer() / 1000.0;
            return val();
        } else if(status == RUNNING ) {
            var t :Number = getTimer() / 1000.0 - t_offset;
            var temp :Number;
            switch(type) {
                case SIN :
                    return  offset + mul * amplitude * 
                    Math.sin(2.0 * Math.PI *( t/period + phase) );
                case COS :
                    return  offset + mul * amplitude *
                    Math.cos(2.0 * Math.PI *( t/period + phase) );
                case SAW :
                    temp = t / period + 0.5 + phase - 
                    Math.floor( t / period + 0.5 + phase ) - 0.5;
                    return  offset + 2.0 * mul * amplitude * temp;
                case TRI :
                    temp = t / period + phase - 
                    Math.floor (t / period + phase );
                    if( 0.0 <= temp && temp < 0.25 ) {
                        return offset + mul * amplitude * 4.0 * temp;
                    } else if( temp < 0.75 ) {
                        return offset + mul * amplitude * (  2.0 - 4.0 * temp);
                    } else {
                        return offset + mul * amplitude * ( -4.0 + 4.0 * temp);
                    }
                case SQR :
                    temp = t/period + phase - 
                    Math.floor( t / period + phase);
                    if( temp < 0.5 ){
                        return offset + mul * amplitude;
                    } else {
                        return offset - mul * amplitude;
                    }
                case ABSSIN :
                    return  offset + 
                    Math.abs(mul * amplitude * Math.sin(2.0*Math.PI *( t/period + phase)));
                case NOISE :
                    var p :PerlinNoise = new PerlinNoise(); 
                    return offset -mul * amplitude + 2.0 * mul * amplitude * p.noise(t/period+phase,1);
                default :
                    return 0.0;
            }
        } else {
            return 0.0;
        }        
    }
}