Alternativa3D WorkControllerを使ってプリミティブの簡単LookAt
Alternativa3D WorkControllerを使ってプリミティブの簡単LookAt
前に、シェーディングの為に、lookAtを計算で実行するサンプルをアップしましたが、
プリミティブ（Object3D）をlookAtさせるだけなら、WalkControllerを使えば簡単にできちゃいます。
ただ、lookAtさせると、プリミティブ（Object3D）自体の方向を任意に変える事ができなくなる上、
思った方向で向いてくれない（y軸(実際にはZ軸)で90度回転してしまう）ので、Object3Dの中にプリミティブをネストして使います。
Alternativa3D を簡単に扱うためのベーシックテンプレート
@author Yasu (clockmaker)
/**
* Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/kO3M
*/
// forked from clockmaker's [Alternativa3D] Basic Template
package {
import alternativ5.engine3d.controllers.WalkController;
import alternativ5.engine3d.materials.FillMaterial;
import alternativ5.engine3d.materials.DevMaterial;
import alternativ5.engine3d.primitives.Box;
import alternativ5.engine3d.primitives.Cone;
import alternativ5.engine3d.events.MouseEvent3D
import alternativ5.engine3d.core.Object3D;
import alternativ5.utils.MathUtils
import alternativ5.types.Point3D;
import flash.display.Sprite;
[SWF(width = 465, height = 465, frameRate = 60)]
/**
* Alternativa3D WorkControllerを使ってプリミティブの簡単LookAt
*
* 前に、シェーディングの為に、lookAtを計算で実行するサンプルをアップしましたが、
* プリミティブ（Object3D）をlookAtさせるだけなら、WalkControllerを使えば簡単にできちゃいます。
*
* ただ、lookAtさせると、プリミティブ（Object3D）自体の方向を任意に変える事ができなくなる上、
* 思った方向で向いてくれない（y軸(実際にはZ軸)で90度回転してしまう）ので、Object3Dの中にプリミティブをネストして使います。
*/
/**
* Alternativa3D を簡単に扱うためのベーシックテンプレート
* @author Yasu (clockmaker)
*/
public class SimpleDemo extends Sprite {
public function SimpleDemo():void {
// テンプレートを作成します
var template:BasicTemplate = new BasicTemplate();
addChild(template);
// プリミティブを作成します
var box:Object3D = new Object3D();
var boxInner:Box = new Box(200, 200, 200);
boxInner.cloneMaterialToAllSurfaces(new FillMaterial(0x0000FF));
boxInner.setMaterialToSurface(new FillMaterial(0x990000),'top');
boxInner.coords=new Point3D(0,200,0);
boxInner.rotationX=MathUtils.toRadian(-90)
template.scene.root.addChild(box);
box.addChild(boxInner);
var cone:Object3D = new Object3D();
var coneInner:Cone = new Cone(200, 100,0,1,4);
coneInner.setMaterialToSurface(new FillMaterial(0x990000),'bottom');
coneInner.setMaterialToSurface(new FillMaterial(0xFF0000),'side');
coneInner.coords=new Point3D(0,0,0);
coneInner.rotationX=MathUtils.toRadian(90)
template.scene.root.addChild(cone);
cone.addChild(coneInner);
// 3Dシーンのルートに追加します
//setDefaultBindingsしなければ、キー操作は無効
var boxController:WalkController = new WalkController(template.stage,box);
boxController.coords = new Point3D(0,200,0);
var coneController:WalkController = new WalkController(template.stage,cone);
coneController.coords = new Point3D(0,0,0);
//外周りの箱の為の角度
var angle:uint=0;
// Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
// レンダリング前に実行したい処理を記述します。
template.onPreRender = function():void {
// 立方体を回転させます (角度はラジアン)
angle++;
var radian:Number= angle/180*Math.PI;
var radian2:Number= angle/180*Math.PI*2;
box.y=Math.sin(radian)*600
box.x=Math.cos(radian2)*600
box.z=Math.cos(radian)*600
boxController.lookAt(cone.coords)
coneController.lookAt(box.coords)
template.cameraContoller.lookAt(new Point3D());
}
}
}
}
/**
* BasicTemplate for Alternativa3D
* Alternativa3Dを扱いやすくするためのテンプレートです
* @author Yasu
*/
import alternativ5.engine3d.controllers.CameraController;
import alternativ5.engine3d.core.Camera3D;
import alternativ5.engine3d.core.Object3D;
import alternativ5.engine3d.core.Scene3D;
import alternativ5.engine3d.display.View;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
class BasicTemplate extends Sprite{
/**
* シーンインスタンスです。
*/
public var scene:Scene3D;
/**
* ビューインスタンスです。
*/
public var view:View;
/**
* カメラインスタンスです。
*/
public var camera:Camera3D;
/**
* カメラコントローラーです。
*/
public var cameraContoller:CameraController;
private var _viewWidth:int;
private var _viewHeight:int;
private var _scaleToStage:Boolean;
/**
* 新しい BasicTemplate インスタンスを作成します。
* @param viewWidth
* @param viewHeight
* @param scaleToStage
*/
public function BasicTemplate(viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true) {
_viewWidth = viewWidth;
_viewHeight = viewHeight;
_scaleToStage = scaleToStage;
// Creating scene
scene = new Scene3D();
scene.splitAnalysis = false; // not analysis for performance
scene.root = new Object3D();
// Adding camera
camera = new Camera3D();
camera.z = -1000;
scene.root.addChild(camera);
// camera contoller
cameraContoller = new CameraController(this);
cameraContoller.camera = camera;
// set view
view = new View();
view.camera = camera;
addChild(view);
// stage
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理をオーバーライドして記述します。
*/
protected function atInit():void {}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理を記述します。
*/
private var _onInit:Function = function():void { };
public function get onInit():Function { return _onInit; }
public function set onInit(value:Function):void {
_onInit = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
protected function atPreRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理を記述します。
*/
private var _onPreRender:Function = function():void{};
public function get onPreRender():Function { return _onPreRender; }
public function set onPreRender(value:Function):void {
_onPreRender = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理をオーバーライドして記述します。
*/
protected function atPostRender():void {
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理を記述します。
*/
protected var _onPostRender:Function = function():void{};
public function get onPostRender():Function { return _onPostRender; }
public function set onPostRender(value:Function):void {
_onPostRender = value;
}
/**
* レンダリングを開始します。
*/
public function startRendering():void {
addEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* レンダリングを停止します。
*/
public function stopRendering():void {
removeEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* シングルレンダリング(レンダリングを一回だけ)を実行します。
*/
public function singleRender():void {
onRenderTick();
}
/**
* @private
*/
private function init(e:Event = null):void {
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.quality = StageQuality.HIGH;
// resize
stage.addEventListener(Event.RESIZE, onResize);
onResize(null);
// render
startRendering();
atInit();
_onInit();
}
/**
* @private
*/
private function onRenderTick(e:Event = null):void {
atPostRender();
_onPostRender();
scene.calculate();
atPreRender();
_onPreRender();
}
/**
* @private
*/
private function onResize(event:Event = null):void {
if (_scaleToStage) {
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}else {
view.width = _viewWidth;
view.height = _viewHeight;
}
}
}