Alternativa3D Sprite3DとSpriteMaterial（SpriteTextureMateria)
Alternativa3D Sprite3DとSpriteMaterial（SpriteTextureMaterial）
papervision3dでできてもAlternativa3Dではどうすれば？シリーズ、第3弾
国内では、ほとんど触られていない模様の、Alternativa3D Sprite3Dの使用例です。
Point!!
Sprite3Dは、cameraに対し常に垂直に表示されるObject3Dの子クラス。
SpriteMaterial及び、SpriteTextureMaterialはSprite3D用のマテリアル。
プリミティブやMeshでは使用できません。
同じ大きさで、Planeを作成し、同じ動作をさせていますので、その違いを、確認してみてください。
@narutohyper
Alternativa3D を簡単に扱うためのベーシックテンプレート
@author Yasu (clockmaker)
/**
* Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/iaFR
*/
// forked from clockmaker's [Alternativa3D] Basic Template
package {
import alternativ5.engine3d.materials.SpriteTextureMaterial;
import alternativ5.engine3d.materials.TextureMaterial
import alternativ5.engine3d.materials.DevMaterial
import alternativ5.engine3d.primitives.Box;
import alternativ5.engine3d.primitives.Plane;
import alternativ5.engine3d.core.Sprite3D;
import alternativ5.types.Texture;
import alternativ5.types.Point3D;
import flash.display.Sprite;
import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.Event;
[SWF(width = 465, height = 465, frameRate = 60)]
/**
* Alternativa3D Sprite3DとSpriteMaterial（SpriteTextureMaterial）
* papervision3dでできてもAlternativa3Dではどうすれば？シリーズ、第3弾
* 国内では、ほとんど触られていない模様の、Alternativa3D Sprite3Dの使用例です。
*
* Point!!
*
* Sprite3Dは、cameraに対し常に垂直に表示されるObject3Dの子クラス。
* SpriteMaterial及び、SpriteTextureMaterialはSprite3D用のマテリアル。
* プリミティブやMeshでは使用できません。
*
* 同じ大きさで、Planeを作成し、同じ動作をさせていますので、その違いを、確認してみてください。
*
* @narutohyper
*/
/**
* Alternativa3D を簡単に扱うためのベーシックテンプレート
* @author Yasu (clockmaker)
*/
public class SimpleDemo extends Sprite {
private var bytesLoaded:Number;
private var bytesTotal:Number;
private var loader:Loader;
public function SimpleDemo():void {
loader = new Loader();
loader.load(new URLRequest("http://marubayashi.net/archive/sample/images/tiger.gif"), new LoaderContext(true));
loader.contentLoaderInfo.addEventListener(Event.COMPLETE,loaded);
}
private function loaded(e:Event):void{
loader.contentLoaderInfo.removeEventListener(Event.COMPLETE,loaded);
// テンプレートを作成します
var template:BasicTemplate = new BasicTemplate();
addChild(template);
//-----------------------------------------------
//Boxの作成
//-----------------------------------------------
// マテリアルを作成します
var materialA:DevMaterial = new DevMaterial();
// プリミティブを作成します
var box:Box = new Box(200, 200, 200);
box.cloneMaterialToAllSurfaces(materialA);
// 3Dシーンのルートに追加します
template.scene.root.addChild(box);
//読み込んだ画像をBitmapData化
var bmd:BitmapData = new BitmapData(loader.content.width, loader.content.height, true, 0x00000000);
bmd.draw(loader);
//-----------------------------------------------
// スプライト3Dの作成
//-----------------------------------------------
// スプライト3D用のマテリアルを作成します
var materialB:SpriteTextureMaterial = new SpriteTextureMaterial(new Texture(bmd),1,true);
// スプライト3Dを作成します
var sp:Sprite3D = new Sprite3D();
sp.material=materialB;
// 3Dシーンのルートに追加します
template.scene.root.addChild(sp);
//-----------------------------------------------
// planeマテリアルの作成
//-----------------------------------------------
// plane用のマテリアルを作成します
var materialC:TextureMaterial = new TextureMaterial(new Texture(bmd),1,true)
// planeプリミティブを作成します
var pn:Plane = new Plane(395,395);
pn.cloneMaterialToAllSurfaces(materialC);
// 3Dシーンのルートに追加します
template.scene.root.addChild(pn);
var angle:uint=0
// Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
// レンダリング前に実行したい処理を記述します。
template.onPreRender = function():void {
// Sprite3DとPlaneを同じように回転させます。
sp.rotationY += 1 * Math.PI / 180;
angle++
var radian:Number= angle/180*Math.PI;
sp.y=Math.sin(radian)*500
sp.x=Math.cos(radian)*500
sp.z=Math.cos(radian)*500
pn.rotationY += 1 * Math.PI / 180;
pn.y=Math.sin(radian)*500
pn.x=Math.cos(radian)*-500
pn.z=Math.cos(radian)*500
// 立方体を回転させます (角度はラジアン)
box.rotationY += 1 * Math.PI / 180;
// マウスがステージの高さ何%の位置にあるか算出
var rateY:Number = mouseY / stage.stageHeight;
// カメラの高さの座標を調整
// イージングの公式 対象の値 += (目標値 - 現在の値) * 減速率
template.camera.y += ( - 1000 * rateY - template.camera.y) * 0.1;
// カメラの座標を中央に向かせる
template.cameraContoller.lookAt(new Point3D());
}
}
}
}
/**
* BasicTemplate for Alternativa3D
* Alternativa3Dを扱いやすくするためのテンプレートです
* @author Yasu
*/
import alternativ5.engine3d.controllers.CameraController;
import alternativ5.engine3d.core.Camera3D;
import alternativ5.engine3d.core.Object3D;
import alternativ5.engine3d.core.Scene3D;
import alternativ5.engine3d.display.View;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
class BasicTemplate extends Sprite{
/**
* シーンインスタンスです。
*/
public var scene:Scene3D;
/**
* ビューインスタンスです。
*/
public var view:View;
/**
* カメラインスタンスです。
*/
public var camera:Camera3D;
/**
* カメラコントローラーです。
*/
public var cameraContoller:CameraController;
private var _viewWidth:int;
private var _viewHeight:int;
private var _scaleToStage:Boolean;
/**
* 新しい BasicTemplate インスタンスを作成します。
* @param viewWidth
* @param viewHeight
* @param scaleToStage
*/
public function BasicTemplate(viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true) {
_viewWidth = viewWidth;
_viewHeight = viewHeight;
_scaleToStage = scaleToStage;
// Creating scene
scene = new Scene3D();
scene.splitAnalysis = false; // not analysis for performance
scene.root = new Object3D();
// Adding camera
camera = new Camera3D();
camera.z = -1000;
scene.root.addChild(camera);
// camera contoller
cameraContoller = new CameraController(this);
cameraContoller.camera = camera;
// set view
view = new View();
view.camera = camera;
addChild(view);
// stage
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理をオーバーライドして記述します。
*/
protected function atInit():void {}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理を記述します。
*/
private var _onInit:Function = function():void { };
public function get onInit():Function { return _onInit; }
public function set onInit(value:Function):void {
_onInit = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
protected function atPreRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理を記述します。
*/
private var _onPreRender:Function = function():void{};
public function get onPreRender():Function { return _onPreRender; }
public function set onPreRender(value:Function):void {
_onPreRender = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理をオーバーライドして記述します。
*/
protected function atPostRender():void {
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理を記述します。
*/
protected var _onPostRender:Function = function():void{};
public function get onPostRender():Function { return _onPostRender; }
public function set onPostRender(value:Function):void {
_onPostRender = value;
}
/**
* レンダリングを開始します。
*/
public function startRendering():void {
addEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* レンダリングを停止します。
*/
public function stopRendering():void {
removeEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* シングルレンダリング(レンダリングを一回だけ)を実行します。
*/
public function singleRender():void {
onRenderTick();
}
/**
* @private
*/
private function init(e:Event = null):void {
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.quality = StageQuality.HIGH;
// resize
stage.addEventListener(Event.RESIZE, onResize);
onResize(null);
// render
startRendering();
atInit();
_onInit();
}
/**
* @private
*/
private function onRenderTick(e:Event = null):void {
atPreRender();
_onPreRender();
scene.calculate();
atPostRender();
_onPostRender();
}
/**
* @private
*/
private function onResize(event:Event = null):void {
if (_scaleToStage) {
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}else {
view.width = _viewWidth;
view.height = _viewHeight;
}
}
}