重力マウス（全自動しいたけ）
リンクリストにしてみたけどそんなに速くない？？
_bmd.fillRect()を_bmd.setPixel()に変更。
sin(),cos(),atan2(),sqrt()を排除。
Add final class / mouseEnalbled = false by clockmaker
はじめ重力の点が等速円運動してるので、頃合を見計らってクリックしてください。
/**
* Copyright dice ( http://wonderfl.net/user/dice )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/eFcJ
*/
// forked from osamX's 重力マウス（全自動）
// forked from Nicolas's forked from: 重力マウス（プチ軽量化：10万パーティクル）
// forked from clockmaker's 重力マウス（プチ軽量化：10万パーティクル）
// forked from coppieee's 重力マウス（さらに軽量化してみた）
// forked from paq's forked from: 重力マウス（ちょっぴり軽量化してみた）
// forked from fumix's 重力マウス（リンクリストにしてみた）
// forked from undo's 重力マウス
// リンクリストにしてみたけどそんなに速くない？？
//_bmd.fillRect()を_bmd.setPixel()に変更。
//sin(),cos(),atan2(),sqrt()を排除。
// Add final class / mouseEnalbled = false by clockmaker
//はじめ重力の点が等速円運動してるので、頃合を見計らってクリックしてください。
package
{
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.geom.ColorTransform;
import flash.geom.Point;
import flash.geom.Rectangle;
import net.hires.debug.Stats;
[SWF(frameRate='60', width='465', height='465', backgroundColor='0x0')]
import flash.utils.Dictionary;
public class Shiitake extends Sprite
{
private var _bmp:Bitmap;
private var _bmd:BitmapData;
private var _bmdRect:Rectangle;
private var _colorTransform:ColorTransform = new ColorTransform(0.9, 0.8, 0.7, 1.0);
private var _first:Node;
private var _maxNum:int = 100000; // 20万パーティクルでも45fps ぐらいでる
private var _cnt:int = 0;
public function Shiitake(){
if(stage) init(null);
else addEventListener(Event.ADDED_TO_STAGE, init);
return;
}
private function init(evt:Event):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
this.stage.align = StageAlign.TOP_LEFT;
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.quality = "low";
this.stage.frameRate = 120;
this.mouseEnabled = false;
this.mouseChildren = false;
var old:Node;
_bmd = new BitmapData(465, 465, false, 0x000000);
_bmp = new Bitmap(_bmd);
addChild(_bmp);
this._bmdRect = _bmd.rect;
for (var i:int = 0; i < this._maxNum; i++)
{
var n:Node = new Node();
n.pos_x = n.dpos_x = Math.random() * 465 >> 0;
n.pos_y = n.dpos_y = Math.random() * 465 >> 0;
//リンクリスト
if (_first == null) {
old = _first = n;
} else {
old.next = n;
old = n;
}
}
addChild(new Stats());
addEventListener(Event.ENTER_FRAME, onEnter);
}
private function onEnter(evt:Event):void
{
this._bmd.lock();
this._bmd.colorTransform(this._bmdRect, this._colorTransform);
draw(0xffffff);
this._bmd.unlock();
;
}
private function draw(col:uint):void {
var ml:int = 2;
var gravPoint_x:Number;
var gravPoint_y:Number;
var n:Node = _first;
var _c:int;
if (_cnt ++ < 500) {
gravPoint_x = gravPoint_y = 232.5;
} else if(_cnt < 860){
_c = (_cnt - 500) * 2;
gravPoint_x = 230 * Math.sin(_c / 180 * Math.PI ) + 232.5;
gravPoint_y = 230 * Math.cos(_c / 180 * Math.PI ) + 232.5;
} else {
gravPoint_x = gravPoint_y = 232.5;
if (_cnt < 900) {
ml = 100;
} else {
if (_cnt < 1000) {
while (n){
n.pos_x += (n.dpos_x - n.pos_x) * 0.15;
n.pos_y += (n.dpos_y - n.pos_y) * 0.15;
this._bmd.setPixel((n.pos_x) >> 0, n.pos_y >> 0, col);
n = n.next;
}
} else {
while (n){
n.v_x = n.v_y = 0;
n = n.next;
}
_cnt = 0;
}
return;
}
}
do
{
var diff_x:Number = gravPoint_x - n.pos_x;
var diff_y:Number = gravPoint_y - n.pos_y;
var acc:Number = ml / (diff_x * diff_x + diff_y * diff_y);
var acc_x:Number = acc * diff_x;
var acc_y:Number = acc * diff_y;
n.v_x += acc_x;
n.v_y += acc_y;
n.pos_x += n.v_x;
n.pos_y += n.v_y;
n.v_x *= 0.97;
n.v_y *= 0.97;
this._bmd.setPixel((n.pos_x) >> 0, n.pos_y >> 0, col);
}
while (n = n.next);
}
}
}
final class Node
{
public var v_x:Number = 0;
public var v_y:Number = 0;
public var pos_x:Number = 0;
public var pos_y:Number = 0;
public var dpos_x:Number = 0;
public var dpos_y:Number = 0;
public var next:Node;
}