forked from: forked from: あなたのイベントハンドラを教えて！coppiee流

by hacker_idMeta 18 Aug 2010

• Forked from coppieee's forked from: あなたのイベントハンドラを教えて！coppiee流
• Diff: 23
• Related works: 18
Embed

/**
 * Copyright hacker_idMeta ( http://wonderfl.net/user/hacker_idMeta )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/dAba
 */


package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    public class FlashTest extends Sprite {
    
        private var _btnA:MyButton;
        private var _btnB:MyButton;
        private var _btnC:MyButton;
        private var _label:MyTextField;

        public function FlashTest() {
            // ボタンを作成
            _build();
            
            // 自分流のイベントハンドラを記述ください
            // coppieee 流
            ([[_btnA, "A"], [_btnB, "B"], [_btnC, "C"]]).forEach(function(b:Array, ...rest):void { 
                ([[MouseEvent.CLICK,"クリック"],[MouseEvent.ROLL_OVER,"ロールオーバー"]]).forEach(function(m:Array,...rest):void{
                    b[0].addEventListener(m[0], function(e:Event):void {
                        _label.text = b[1] +" が"+m[1]+"されました";
                    });
                });
            });
        }
        
        /**
        * インターフェースを作る
        */
        private function _build():void {
            _label = new MyTextField();
            _label.x = 150; _label.y = 280;
            addChild(_label);

            _btnA = new MyButton();
            _btnA.text = "Button A"; 
            _btnA.x = 70; _btnA.y = 230;
            addChild(_btnA);
            
            _btnB = new MyButton();
            _btnB.text = "Button B";
            _btnB.x = 190; _btnB.y = 230;
            addChild(_btnB);
   
            _btnC = new MyButton();            
            _btnC.text = "Button C";
            _btnC.x = 310; _btnC.y = 230;
            addChild(_btnC);
        }
    }
}

import flash.display.*
import flash.text.*;

/**
* MyButton クラスはボタン的な挙動をするようにしたSpriteです。
*/
class MyButton extends Sprite {
    private var _text:MyTextField;
    /**
    * 新しい MyButton インスタンスを作成します。
    */
    public function MyButton(){
        graphics.beginFill(0xFF9900);
        graphics.drawRoundRect(0, 0, 100, 30, 5, 5);
        addChild(_text = new MyTextField);
        buttonMode = true;
    }
    /**
    * ボタンの文言を設定します。
    */
    public function set text(value:String):void {
        _text.text = value;
        _text.x = (100 - _text.textWidth) / 2;
        _text.y = (30 - _text.textHeight) / 2;
    }
}

/**
* MyTextField クラスは適当な初期設定をしただけのテキストフィールドです。
*/
class MyTextField extends TextField {
    /**
    * 新しい MyTextField インスタンスを作成します。
    */
    public function MyTextField() {
        defaultTextFormat = new TextFormat("_sans", 12, 0x000000);
        autoSize = "left";
        selectable = false;
        mouseEnabled = false;
    }
}