In case Flash no longer exists; a copy of this site is included in the Flashpoint archive's "ultimate" collection.

Dead Code Preservation :: Archived AS3 works from wonderfl.net

intersectRay & Camera3D.calculateRay [Alternativa3D 7.6 TIPS]

Camera3D.calculateRayを使う事で、View上のx.y座標から、伸ばした視線の先にあるObject3Dの情報を得る事ができます。
なお、Ver7.5.1からの対応ですので、ローカルで試す場合は、最新のSWCを入手してください。

2011/01/12 7.5から7.6仕様に変更

2011/01/12 7.5から7.6仕様に変更

↑↓←→キーで、マーカーを移動。
SPACEキーで、HIT
(SPACEキーは、日本語入力解除してください:P)
Get Adobe Flash player
by narutohyper 23 Oct 2012
/**
 * Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/cylw
 */

// forked from narutohyper's Alternativa3D 7.5 Template
package
{
    import alternativ7.engine3d.controllers.SimpleObjectController;
    import alternativ7.engine3d.core.Object3DContainer;
    import alternativ7.engine3d.core.RayIntersectionData;
    import alternativ7.engine3d.materials.TextureMaterial;
    import alternativ7.engine3d.primitives.Box;
    import alternativ7.engine3d.primitives.Plane;
    import flash.display.BitmapData;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.KeyboardEvent;
    import flash.filters.*;
    import flash.geom.Point;
    import flash.geom.Vector3D;
    import flash.ui.Keyboard;
    
    
    /**
     * Alternativa3D 7.6
     *
     * interactive
     * intersectRay & Camera3D.calculateRay
     *
     * @author narutohyper
     */
    [SWF(backgroundColor="#000000", frameRate="100", width="800", height="600")]
    public class Main extends Sprite
    {
        
        private var box:Box;
        private var objectController:SimpleObjectController;
        private var ob:Object3DContainer;
        private var scene:AlternativaTemplate;
        private var plane:Plane;
        private var marker:Sprite;
        
        public function Main():void    {
        
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        
        private function init(e:Event=null):void {
            removeEventListener(Event.ADDED_TO_STAGE, init);
        
            //AlternativaTemplate作成
            scene = new AlternativaTemplate(this);

            
            //
            var materials:Vector.<TextureMaterial> = new Vector.<TextureMaterial>(6);
            for (var i:int = 0; i < 7; i++)
            {
                var color:uint = (i == 6) ? 0xCCFFCC:0xFFFFFF;
                
                var bmd:BitmapData = new BitmapData(500, 500, false, color);
                materials[i] = new TextureMaterial(bmd);
            }
            
            ob = new Object3DContainer();
            scene.container.addChild(ob);
            
            box = new Box(500,500,500,1,1,1,false,false,materials[0],materials[1],materials[2],materials[3],materials[4],materials[5]);
            ob.addChild(box);
            scene.cameraController.setObjectPosXYZ(0, -1000,0);
            scene.cameraController.lookAtXYZ(0, 0, 0);
            
            plane = new Plane(2000, 2000);
            plane.setMaterialToAllFaces(materials[6]);
            scene.container.addChild(plane);
            plane.z = -600;
            
            //ObjectControllerの作成
            //MouseDragで、Objectを回転させる為のController
            objectController = new SimpleObjectController(stage, ob, 100);
            objectController.mouseSensitivity = 0.5;
            objectController.unbindAll();
            
            var RADIAN:Number = Math.PI/180;
            scene.onPreRender = function():void {
                objectController.update();
            }
            
            //markerの作成
            marker = new Sprite();
            marker.graphics.lineStyle(2, 0xFF0000);
            marker.graphics.drawCircle(0, 0, 50);
            marker.graphics.drawCircle(0, 0, 25);
            marker.graphics.moveTo(0, -60);
            marker.graphics.lineTo(0, 60);
            marker.graphics.moveTo( -60, 0);
            marker.graphics.lineTo(60, 0);
            addChild(marker);
            marker.x=scene.view.width/2;
            marker.y=scene.view.height/2;
            //描画開始
            scene.startRendering();
            
            stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
            
            

        }
        
        private function onKeyDown(e:KeyboardEvent):void
        {
            switch(e.keyCode) {
                case Keyboard.DOWN:
                    marker.y += 10;
                break;
                case Keyboard.UP:
                    marker.y -= 10;
                break;
                case Keyboard.LEFT:
                    marker.x -= 10;
                break;
                case Keyboard.RIGHT:
                    marker.x += 10;
                break;
                case Keyboard.SPACE:
                    hit();
                break;
            }
        }
        
        
        private function hit():void {
            var origin:Vector3D = new Vector3D();
            var direction:Vector3D = new Vector3D();
            scene.camera.calculateRay(origin, direction, marker.x, marker.y);
            
            var data:RayIntersectionData = scene.container.intersectRay(origin, direction);
            if (data != null) {
                var texture:BitmapData = (data.face.material as TextureMaterial).texture;
                var uv:Point = data.face.getUV(data.point);
                var spot:Shape = new Shape();
                spot.graphics.beginFill(0x0000FF);
                spot.graphics.drawCircle( uv.x * texture.width, uv.y * texture.height, 25);
                spot.x=uv.x;
                spot.y=uv.y;
                texture.draw(spot);
                
            }
        }
        
    
    }
    
}


/**
 * BasicTemplate for Alternativa3D 7.5
 * Alternativa3D 7.5を扱いやすくするためのテンプレートです
 * @author narutohyper & clockmaker
 *
 */
import alternativ7.engine3d.containers.BSPContainer;
import alternativ7.engine3d.containers.ConflictContainer;
import alternativ7.engine3d.containers.DistanceSortContainer;
import alternativ7.engine3d.containers.KDContainer;
import alternativ7.engine3d.containers.LODContainer;
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Camera3D;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.View;
import flash.display.DisplayObject;

import flash.display.DisplayObjectContainer;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;

import flash.events.Event;

class AlternativaTemplate extends Sprite
{
    /**
     * 子オブジェクトを最適な方法でソートするコンテナ
     * (ConflictContainer)
     */
    public static const CONFLICT:String = 'conflict';
    /**
     * 子オブジェクトをBSP(バイナリ空間分割法)によってソートするコンテナ
     * (BSPContainer)
     */
    public static const BSP:String = 'bsp';
    
    /**
     * 子オブジェクトをカメラからのZ値でソートするコンテナ
     * (DistanceSortContainer)
     */
    public static const ZSORT:String = 'zsort';
    /**
     * KDツリー(http://ja.wikipedia.org/wiki/Kd%E6%9C%A8)によってソートするコンテナ
     * (KDContainer)
     */
    public static const KD:String = 'kd';
    /**
     * detalizationと子オブジェクトの距離でソートするコンテナ(詳細は調査中)
     * (LODContainer)
     */
    public static const LOD:String = 'lod';
    
    /**
     * 3dオブジェクト格納するコンテナインスタンス。
     */
    public var container:Object3DContainer;

    /**
     * ビューインスタンスです。
     */
    public var view:View;
    
    /**
     * カメラインスタンスです。
     */
    public var camera:Camera3D;
    
    /**
     * カメラコントローラーです。
     */
    public var cameraController:SimpleObjectController;
    
    private var _mc:DisplayObjectContainer;
    private var _viewWidth:int;
    private var _viewHeight:int;
    private var _scaleToStage:Boolean;
    private var _containerType:String;
    
    /**
     * 新しい Alternativa3DTemplate インスタンスを作成します。
     * @param    mc
     * @param    containerType
     * @param    viewWidth
     * @param    viewHeight
     * @param    scaleToStage
     */
    public function AlternativaTemplate(mc:DisplayObjectContainer,containerType:String=CONFLICT,viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true)
    {
        
        _mc = mc;
        _mc.addChild(this);

        _containerType = containerType;
        _viewWidth = viewWidth;
        _viewHeight = viewHeight;
        _scaleToStage = scaleToStage;
        
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }


    /**
     * 初期化されたときに実行されるイベントです。
     * 初期化時に実行したい処理をオーバーライドして記述します。
     */
    protected function atInit():void {}


    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング前に実行したい処理をオーバーライドして記述します。
     */
    protected function atPreRender():void {}
    
    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング前に実行したい処理をオーバーライドして記述します。
     */
    private var _onPreRender:Function = function():void{};
    public function get onPreRender():Function { return _onPreRender; }
    public function set onPreRender(value:Function):void
    {
        _onPreRender = value;
    }
    
    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング後に実行したい処理をオーバーライドして記述します。
     */
    protected function atPostRender():void {}
    
    /**
     * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
     * レンダリング後に実行したい処理を記述します。
     */
    private var _onPostRender:Function = function():void{};
    public function get onPostRender():Function { return _onPostRender; }
    public function set onPostRender(value:Function):void
    {
        _onPostRender = value;
    }
    
    
    /**
     * レンダリングを開始します。
     */
    public function startRendering():void
    {
        addEventListener(Event.ENTER_FRAME, onRenderTick);
    }

    /**
    * レンダリングを停止します。
    */
    public function stopRendering():void
    {
        removeEventListener(Event.ENTER_FRAME, onRenderTick);
    }

    /**
     * シングルレンダリング(レンダリングを一回だけ)を実行します。
     */
    public function singleRender():void
    {
        onRenderTick();
    }

    /**
     * @private
     */
    private function init(e:Event = null):void
    {
        removeEventListener(Event.ADDED_TO_STAGE, init);
        // entry point
        stage.scaleMode = StageScaleMode.NO_SCALE;
        stage.align = StageAlign.TOP_LEFT;
        stage.quality = StageQuality.HIGH;
        
        //Root objectの作成
        if (_containerType == CONFLICT) {
            container = new ConflictContainer();
        } else if (_containerType == BSP) {
            container = new BSPContainer();
        } else if (_containerType == ZSORT) {
            container = new DistanceSortContainer();
        } else if (_containerType == KD) {
            container = new KDContainer();
        } else if (_containerType == LOD) {
            container = new LODContainer();
        }
        //Viewの作成
        view = new View(stage.stageWidth, stage.stageHeight);
        _mc.addChild(view);

        //cameraの作成
        camera = new Camera3D();
        camera.view = view;
        camera.x = 0;
        camera.y = -500;
        camera.z = 0;
        container.addChild(camera);
        
        // Camera controller
        cameraController = new SimpleObjectController(stage, camera, 10);
        cameraController.mouseSensitivity = 0;
        cameraController.unbindAll();
        cameraController.lookAtXYZ(0, 0, 0);
        
        onResize();
        stage.addEventListener(Event.RESIZE, onResize);
        
        atInit();
    }
    
    /**
     * @private
     */    
    private function onResize(e:Event = null):void 
    {
        if (_scaleToStage)
        {
            view.width = stage.stageWidth;
            view.height = stage.stageHeight;
        } 
        else
        {
            view.width = _viewWidth;
            view.height = _viewHeight;
        }
    }
    
    /**
     * @private
     */    
    private function onRenderTick(e:Event = null):void 
    {
        atPreRender();
        _onPreRender();
        cameraController.update();
        camera.render();
        atPostRender();
        _onPostRender();
    }
    
    
}