AS3で外部テキストファイルを読んで表示する

by 9re 05 Apr 2011

Embed

/**
 * Copyright 9re ( http://wonderfl.net/user/9re )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/azL9
 */

package {
    import flash.net.URLRequest;
    import flash.events.SecurityErrorEvent;
    import flash.events.IOErrorEvent;
    import flash.text.TextField;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.display.Sprite;
    public class FlashTest extends Sprite {
        /**
         * このURLは存在しない
         */
        private static const URL:String = "http://swf.wonderfl.net/test.txt";
        private var _ldr:URLLoader = new URLLoader;
        private var _tf:TextField = new TextField;
        
        public function FlashTest() {
            _tf.wordWrap = true;
            _tf.width = _tf.height = 465;
            addChild(_tf);
            
            /**
             * 正常読み込み完了時の処理
             */
            _ldr.addEventListener(Event.COMPLETE, _onLoaded);
            /**
             * ファイルが見つからない時の処理
             */
            _ldr.addEventListener(IOErrorEvent.IO_ERROR, _onIOError);
            /**
             * セキュリティのエラーの処理。許可されていない外部サーバーへのアクセス等の時に起きる。
             */
            _ldr.addEventListener(SecurityErrorEvent.SECURITY_ERROR, _onSecurrityError);
            /**
             * 実際に読み込みを行う。
             */
            _ldr.load(new URLRequest(URL));
        }
        
        private function _onLoaded(event:Event):void {
            _logResult('外部テキストの読み込みに成功しました', _ldr.data);
        }
        
        private function _onIOError(event:IOErrorEvent):void {
            _logResult('外部テキストの読み込みに失敗しました', event.toString());
        }
        
        private function _onSecurrityError(event:SecurityErrorEvent):void {
            _logResult('外部テキストの読み込みに失敗しました', event.toString());
        }
        
        private function _logResult(tag:String, str:String):void {
            _tf.text = tag + ': ' + str;
        }
    }
}