same game remove block algorithm
間違ってさめがめのも作ってしまったのでついでに。
/**
* Copyright o8que ( http://wonderfl.net/user/o8que )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/axQg
*/
// forked from o8que's forked from: match 3 puzzle remove block algorithm
// forked from bkzen's match 3 puzzle remove block algorithm
package
{
import com.bit101.components.Label;
import com.bit101.components.PushButton;
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.events.Event;
import flash.utils.getTimer;
/**
* マッチ3パズルのアルゴリズムを考える。
* scan メソッドを完成させる。
* なるべく高速で正確な方法を考える。
* grid を Array で保持することが気に入らない等の場合は
* それらを変更しても良いものとする。
*
* @author jc at bk-zen.com
*/
[SWF (backgroundColor = "0xFFFFFF", frameRate = "30", width = "465", height = "465")]
public class Test3 extends Sprite
{
private const colors: Array = [0xCC0000, 0x00CC00, 0x0000CC, 0x660000, 0x006600, 0x000066];
private const numColors: int = 3;
private const w: int = 8;
private const h: int = 8;
private const gridLength: int = w * h;
private var grid: Array;
private var view: BitmapData;
private var bmp: Bitmap;
private var label: Label;
private var btn: PushButton;
private var resetBtn: PushButton;
public function Test3()
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
private function init(e: Event = null): void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
//
grid = [];
for (var raw:int = 0; raw < h; raw++) {
grid[raw] = [];
for (var col:int = 0; col < w; col++) {
grid[raw][col] = new Cell(Math.random() * numColors, col, raw);
}
}
view = new BitmapData(w, h, false, 0);
addChild(bmp = new Bitmap(view));
bmp.scaleX = bmp.scaleY = 20;
btn = new PushButton(this, 0, bmp.height + 5, "scan", onClickScan);
label = new Label(this, btn.width + 5, btn.y, "result: ");
resetBtn = new PushButton(this, 0, btn.y + btn.height + 5, "reset", onClickReset);
draw();
}
private function reset():void
{
var i: int, c: Cell;
for (i = 0; i < gridLength; i ++)
{
c = grid[int(i / w)][i % w];
c.type = Math.random() * numColors | 0, c.removed = false;
}
draw();
}
/**
* 1. 縦・横で同じ色が3つ以上連なっていた場合にそれらの Cell removed を true にする。
* 2. 連なったCellの塊がいくつあるかを数える。
* @return 連なったCellの塊がいくつあるか
*/
private function scan(): int
{
var raw:int, col:int;
var matches:Array; // マッチしたCellを保持するリスト
var value:int = 0; // return value
// スキャン済みCellチェック用のリストを作成する
var scannedCells:Array = [];
for (raw = 0; raw < h; raw++) {
scannedCells[raw] = [];
for (col = 0; col < w; col++) {
scannedCells[raw][col] = false;
}
}
// 左上から右下へ順に走査する
for (raw = 0; raw < h; raw++) {
for (col = 0; col < w; col++) {
// 既にスキャン済みのCellなら次のCellへ
if (scannedCells[raw][col]) { continue; }
matches = [];
scanCell(grid[raw][col]);
// マッチ数が3以上なら、
// 全てのCellを削除し、見つけた塊の数を一つ増やす
if (matches.length >= 3) {
for (var i:int = 0; i < matches.length; i++) {
matches[i].removed = true;
}
value++;
}
}
}
return value;
function scanCell(cell:Cell):void {
// マッチリストに追加
matches.push(cell);
// スキャン済みCellにチェックを入れる
scannedCells[cell.y][cell.x] = true;
// Cellに隣接する上下左右のCellを調べる
var dx:Array = [0, -1, 1, 0];
var dy:Array = [ -1, 0, 0, 1];
for (var i:int = 0; i < 4; i++) {
var testX:int = Math.max(0, Math.min(cell.x + dx[i], w - 1));
var testY:int = Math.max(0, Math.min(cell.y + dy[i], h - 1));
if (!scannedCells[testY][testX] && (grid[testY][testX].type == cell.type)) {
scanCell(grid[testY][testX]);
}
}
}
}
/**
* grid を view に反映します。
*/
private function draw():void
{
var i: int, c: Cell, t: int;
view.lock();
for (i = 0; i < gridLength; i ++)
{
c = grid[int(i / w)][i % w];
t = c.type + (c.removed ? 3 : 0);
view.setPixel(i % w, i / w, colors[t]);
}
view.unlock();
}
private function onClickScan(e: Event):void
{
var t: int = getTimer(), c: int;
c = scan();
label.text = "result : " + (getTimer() - t) + " [ms] remove cnt : " + c;
// 最後に view に反映する。
draw();
}
private function onClickReset(e: Event):void
{
reset();
}
}
}
class Cell
{
public var type: int;
public var x: int, y: int;
public var removed: Boolean;
function Cell(t: int, x: int, y: int)
{
type = t;
this.x = x;
this.y = y;
}
}