Dead Code Preservation :: Archived AS3 works from wonderfl.net

BitmapDataSample9

Get Adobe Flash player
by nutsu 26 Oct 2009
/**
 * Copyright nutsu ( http://wonderfl.net/user/nutsu )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/8Q56
 */

package {
    
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Bitmap;
    import flash.display.BitmapDataChannel;
    import flash.geom.Point;
    import flash.events.Event;
    
    [SWF(width=465,height=465,backgroundColor=0)]
    public class BitmapDataSample9 extends Sprite {
        
        private var bmpdata:BitmapData;
        
        public function BitmapDataSample9() {
            //BitmapDataを作成して表示リストに追加
            bmpdata = new BitmapData( 120, 120, false, 0 );
            var bmp:Bitmap = new Bitmap(bmpdata);
            bmp.scaleX = bmp.scaleY = 4;
            addChild( bmp );
            //イベント
            addEventListener( Event.ENTER_FRAME, enterframe );
        }
        
        private var baseX:Number         = 60;
        private var baseY:Number         = 60;
        private var octaves:uint         = 3;
        private var randomSeed:int       = Math.random()*0xffffffff;
        private var stitch:Boolean       = false;
        private var fractalNoise:Boolean = false;
        private var channelOptions:int   = BitmapDataChannel.RED|BitmapDataChannel.BLUE;
        private var grayScale:Boolean    = false;
        private var offset:Array         = [new Point(),new Point(),new Point()];
        
        private function enterframe(e:Event):void {
            //PerlinNoise
            bmpdata.perlinNoise( baseX, baseY, octaves, randomSeed, 
                                 stitch, fractalNoise, channelOptions, grayScale, offset );
            offset[0].y += 2;
            offset[1].y += 1;
            offset[2].y += 0.5;
        }
    }
}