CustomMaterial [Alternativa3D 7.6 TIPS]
Materialクラスを継承、拡張して、オリジナルなマテリアルを作成。
とりあえず、FillMaterialに、頂点を描画するMaterialを作成してみた。
2011/01/12 7.5から7.6仕様に変更
/**
* Copyright narutohyper ( http://wonderfl.net/user/narutohyper )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/8JoW
*/
// forked from narutohyper's Alternativa3D 7.5 Template
package
{
import alternativ7.engine3d.materials.FillMaterial;
import alternativ7.engine3d.primitives.Plane;
import alternativ7.engine3d.controllers.SimpleObjectController
import flash.display.Sprite;
import flash.events.Event;
import alternativ7.engine3d.core.Object3DContainer
/**
*
* Alternativa3D 7.6
*
* Materialクラスを継承、拡張してOriginalのTextureを作ってみる
*
* @author narutohyper
*/
[SWF(backgroundColor="#000000", frameRate="100", width="800", height="600")]
public class Main extends Sprite
{
public function Main():void {
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
private function init(e:Event=null):void {
removeEventListener(Event.ADDED_TO_STAGE, init);
//AlternativaTemplate作成
var scene:AlternativaTemplate = new AlternativaTemplate(this)
//Materialの作成
var material1:VertexMaterial = new VertexMaterial(0x666666, 1, 0,0x0);
var objectContainer:Object3DContainer = new Object3DContainer()
scene.container.addChild(objectContainer);
//Plane
var plane1:Plane = new Plane(300,300,4,4)
plane1.setMaterialToAllFaces(material1);
objectContainer.addChild(plane1);
//カメラの調整
//カメラはControllerに関連付けている為、x,y,zで直接位置を指定できないので
//SimpleController.setObjectPosXYZを使用
scene.cameraController.setObjectPosXYZ(0,-500,500)
scene.cameraController.lookAtXYZ(0, 0, 0)
//ObjectControllerの作成
//MouseDragで、Objectを回転させる為のController
var objectController:SimpleObjectController = new SimpleObjectController(stage,objectContainer,100)
objectController.unbindAll()
scene.onPreRender = function():void {
objectController.update();
}
//描画開始
scene.startRendering()
}
}
}
import alternativ7.engine3d.materials.Material;
import alternativ7.engine3d.materials.FillMaterial;
import alternativ7.engine3d.alternativa3d;
import alternativ7.engine3d.core.Camera3D;
import alternativ7.engine3d.core.Canvas;
import alternativ7.engine3d.core.Face;
import alternativ7.engine3d.core.Vertex;
import alternativ7.engine3d.core.Wrapper;
import flash.geom.Point;
use namespace alternativa3d;
/**
* CustomMaterial
*
* FillMaterialを継承して、頂点に赤丸を置くMaterial
*
* @author narutohyper
*/
class VertexMaterial extends FillMaterial
{
private var _vertexLength:Number
private var _vertexColor:Number
public function VertexMaterial(color:int = 8355711, alpha:Number = 1, lineThickness:Number = -1, lineColor:int = 16777215,vertexLength:Number=2,vertexColor:int=0xFF0000)
{
_vertexLength = vertexLength;
_vertexColor = vertexColor;
super(color,alpha,lineThickness,lineColor);
}
override alternativa3d function draw(camera:Camera3D, canvas:Canvas, list:Face, distance:Number):void {
var viewSizeX:Number = camera.viewSizeX;
var viewSizeY:Number = camera.viewSizeY;
var next:Face;
var vertex:Vertex;
var wrapper:Wrapper;
var cx:Number;
var cy:Number;
var face:Face
var counter:int = 0;
camera.numDraws++;
var vertices:Vector.<Point> = new Vector.<Point>();
for (face = list; face != null; face = next) {
next = face.processNext;
face.processNext = null;
//面の描画
var commands:Vector.<int> = new Vector.<int>();
var coords:Vector.<Number> = new Vector.<Number>();
counter = 0;
for (wrapper = face.wrapper; wrapper != null; wrapper = wrapper.next) {
vertex = wrapper.vertex;
cx = vertex.cameraX * viewSizeX / vertex.cameraZ;
cy = vertex.cameraY * viewSizeY / vertex.cameraZ;
commands[counter] = (counter)?2:1;
coords[counter * 2] = cx;
coords[counter * 2 + 1] = cy;
counter++;
if (vertex.drawId != camera.numDraws) {
vertices.push(new Point(cx,cy))
vertex.drawId = camera.numDraws;
}
}
canvas.gfx.beginFill(this.color, this.alpha);
canvas.gfx.lineStyle(this.lineThickness, this.lineColor);
canvas.gfx.drawPath(commands, coords);
canvas.gfx.endFill();
}
counter = vertices.length;
for (var i:int = 0; i < counter;i++) {
canvas.gfx.beginFill(_vertexColor);
canvas.gfx.lineStyle();
canvas.gfx.drawCircle(vertices[i].x, vertices[i].y, _vertexLength);
canvas.gfx.endFill();
}
}
}
/**
* BasicTemplate for Alternativa3D 7.5
* Alternativa3D 7.5を扱いやすくするためのテンプレートです
* @author narutohyper & clockmaker
*
*/
import alternativ7.engine3d.containers.BSPContainer;
import alternativ7.engine3d.containers.ConflictContainer;
import alternativ7.engine3d.containers.DistanceSortContainer;
import alternativ7.engine3d.containers.KDContainer;
import alternativ7.engine3d.containers.LODContainer;
import alternativ7.engine3d.controllers.SimpleObjectController;
import alternativ7.engine3d.core.Camera3D;
import alternativ7.engine3d.core.Object3DContainer;
import alternativ7.engine3d.core.View;
import flash.display.DisplayObject;
import flash.display.DisplayObjectContainer;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
class AlternativaTemplate extends Sprite
{
/**
* 子オブジェクトを最適な方法でソートするコンテナ
* (ConflictContainer)
*/
public static const CONFLICT:String = 'conflict';
/**
* 子オブジェクトをBSP(バイナリ空間分割法)によってソートするコンテナ
* (BSPContainer)
*/
public static const BSP:String = 'bsp';
/**
* 子オブジェクトをカメラからのZ値でソートするコンテナ
* (DistanceSortContainer)
*/
public static const ZSORT:String = 'zsort';
/**
* KDツリー(http://ja.wikipedia.org/wiki/Kd%E6%9C%A8)によってソートするコンテナ
* (KDContainer)
*/
public static const KD:String = 'kd';
/**
* detalizationと子オブジェクトの距離でソートするコンテナ（詳細は調査中）
* (LODContainer)
*/
public static const LOD:String = 'lod';
/**
* 3dオブジェクト格納するコンテナインスタンス。
*/
public var container:Object3DContainer;
/**
* ビューインスタンスです。
*/
public var view:View;
/**
* カメラインスタンスです。
*/
public var camera:Camera3D;
/**
* カメラコントローラーです。
*/
public var cameraController:SimpleObjectController;
private var _mc:DisplayObjectContainer;
private var _viewWidth:int;
private var _viewHeight:int;
private var _scaleToStage:Boolean;
private var _containerType:String;
/**
* 新しい Alternativa3DTemplate インスタンスを作成します。
* @param mc
* @param containerType
* @param viewWidth
* @param viewHeight
* @param scaleToStage
*/
public function AlternativaTemplate(mc:DisplayObjectContainer,containerType:String=CONFLICT,viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true)
{
_mc = mc;
_mc.addChild(this);
_containerType = containerType;
_viewWidth = viewWidth;
_viewHeight = viewHeight;
_scaleToStage = scaleToStage;
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
/**
* 初期化されたときに実行されるイベントです。
* 初期化時に実行したい処理をオーバーライドして記述します。
*/
protected function atInit():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
protected function atPreRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング前に実行したい処理をオーバーライドして記述します。
*/
private var _onPreRender:Function = function():void{};
public function get onPreRender():Function { return _onPreRender; }
public function set onPreRender(value:Function):void
{
_onPreRender = value;
}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理をオーバーライドして記述します。
*/
protected function atPostRender():void {}
/**
* Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
* レンダリング後に実行したい処理を記述します。
*/
private var _onPostRender:Function = function():void{};
public function get onPostRender():Function { return _onPostRender; }
public function set onPostRender(value:Function):void
{
_onPostRender = value;
}
/**
* レンダリングを開始します。
*/
public function startRendering():void
{
addEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* レンダリングを停止します。
*/
public function stopRendering():void
{
removeEventListener(Event.ENTER_FRAME, onRenderTick);
}
/**
* シングルレンダリング(レンダリングを一回だけ)を実行します。
*/
public function singleRender():void
{
onRenderTick();
}
/**
* @private
*/
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
// entry point
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
stage.quality = StageQuality.HIGH;
//Root objectの作成
if (_containerType == CONFLICT) {
container = new ConflictContainer();
} else if (_containerType == BSP) {
container = new BSPContainer();
} else if (_containerType == ZSORT) {
container = new DistanceSortContainer();
} else if (_containerType == KD) {
container = new KDContainer();
} else if (_containerType == LOD) {
container = new LODContainer();
}
//Viewの作成
view = new View(stage.stageWidth, stage.stageHeight);
_mc.addChild(view);
//cameraの作成
camera = new Camera3D();
camera.view = view;
camera.x = 0;
camera.y = -500;
camera.z = 0;
container.addChild(camera);
// Camera controller
cameraController = new SimpleObjectController(stage, camera, 10);
cameraController.mouseSensitivity = 0;
cameraController.unbindAll();
cameraController.lookAtXYZ(0, 0, 0);
onResize();
stage.addEventListener(Event.RESIZE, onResize);
atInit();
}
/**
* @private
*/
private function onResize(e:Event = null):void
{
if (_scaleToStage)
{
view.width = stage.stageWidth;
view.height = stage.stageHeight;
}
else
{
view.width = _viewWidth;
view.height = _viewHeight;
}
}
/**
* @private
*/
private function onRenderTick(e:Event = null):void
{
atPreRender();
_onPreRender();
cameraController.update();
camera.render();
atPostRender();
_onPostRender();
}
}