forked from: BitmapDataSample11
package {
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.filters.BlurFilter;
import flash.geom.ColorTransform;
[SWF(width = 465, height = 465, backgroundColor = 0, frameRate = 60)]
public class wo020411 extends Sprite {
public var bmpdata:BitmapData;
public var colortrans:ColorTransform;
public var filter:BlurFilter;
public var vectormap:BitmapData;
public var particle:Array;
public var particle_number:uint = 250000;
public var size:Number = 465;
// コンストラクタ
public function wo020411() {
// BitmapDataを作成して表示リストに追加
bmpdata = new BitmapData(size, size, false, 0);
addChild(new Bitmap(bmpdata));
// エフェクト初期化
colortrans = new ColorTransform(0.95, 0.99, 0.99);
filter = new BlurFilter(2, 2, 1);
// ベクトルマップとパーティクル初期化
vectormap = new BitmapData(size, size, false, 0);
reset();
// イベント
addEventListener(Event.ENTER_FRAME, enterFrame);
stage.addEventListener(MouseEvent.CLICK, reset);
}
private function reset(e:MouseEvent = null):void {
// ベクトルマップの初期化
var randomSeed:int = Math.random() * 0xFFFFFF;
var coloes:uint = BitmapDataChannel.RED | BitmapDataChannel.GREEN;
vectormap.perlinNoise(size / 2, size / 2, 4, randomSeed, false, true, coloes);
// パーティクルの初期化
particle = new Array(particle_number);
for (var i:int = 0; i < particle_number; i++ ) {
particle[i] = new Particle(Math.random() * size, Math.random() * size);
}
}
private function enterFrame(e:Event):void {
// エフェクトの適用
bmpdata.applyFilter(bmpdata, bmpdata.rect, bmpdata.rect.topLeft, filter);
bmpdata.colorTransform(bmpdata.rect, colortrans);
// パーティクルの描画
bmpdata.lock();
for (var i:int = 0; i < particle_number; i++) {
var p:Particle = particle[i];
// ベクトルマップのPixel値から加速度を算出
var col:uint = vectormap.getPixel(p.x, p.y);
p.ax += ((col >> 16 & 0xff) - 128) * 0.0005;
p.ay += ((col >> 8 & 0xff) - 128) * 0.0005;
// 加速度から速度と位置を算出
p.x += p.vx += p.ax;
p.y += p.vy += p.ay;
if (p.x > size) { p.x -= size; }
else if (p.x < 0) { p.x += size; }
if (p.y > size) { p.y -= size; }
else if (p.y < 0) { p.y += size; }
// Pixelへ描画
bmpdata.setPixel(p.x, p.y, 0xFFFFFF);
// 加速度と速度の減衰
p.ax *= 0.96;
p.ay *= 0.96;
p.vx *= 0.92;
p.vy *= 0.92;
}
bmpdata.unlock();
}
}
}
// パーティクルクラス
class Particle {
// 位置
public var x:Number;
public var y:Number;
// 加速度
public var ax:Number = 0;
public var ay:Number = 0;
// 速度
public var vx:Number = 0;
public var vy:Number = 0;
// コンストラクタ
function Particle(px:Number, py:Number) {
x = px;
y = py;
}
}