2値化 (2)

//////////////////////////////////////////////////////////////////////////////
[AS3.0] BitmapDataUtilsクラスに挑戦！ (2)
http://www.project-nya.jp/modules/weblog/details.php?blog_id=1100
ローカルのファイルを読み込んで2値化するよ！
//////////////////////////////////////////////////////////////////////////////

by ProjectNya 27 May 2010

Tags

threshold 特效卷
Embed

/**
 * Copyright ProjectNya ( http://wonderfl.net/user/ProjectNya )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/5S53
 */

////////////////////////////////////////////////////////////////////////////////
// [AS3.0] BitmapDataUtilsクラスに挑戦！ (2)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1100
//
// ローカルのファイルを読み込んで2値化するよ！
////////////////////////////////////////////////////////////////////////////////

package {

	import flash.display.Sprite;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.events.Event;
	import flash.events.MouseEvent;

	[SWF(backgroundColor="#FFFFFF", width="465", height="465", frameRate="30")]

	public class Main extends Sprite {
		private var loader:FileLoader;
		private var bitmap:Bitmap;
		private var bitmapData:BitmapData;
		private var loadBtn:Btn;
		private var menu:Menu;
		private var operationList:Array;
		private var operation:String = BitmapDataUtils.THRESHOLD_LOW;
		private var slider:Slider;
		private var threshold:uint = 127;

		public function Main() {
			Wonderfl.capture_delay(10);
			init();
		}

		private function init():void {
			graphics.beginFill(0xCCCCCC);
			graphics.drawRect(51, 34, 362, 362);
			graphics.endFill();
			loader = new FileLoader();
			loader.addEventListener(Event.INIT, initialize, false, 0, true);
			bitmap = new Bitmap();
			bitmap.x = 52;
			bitmap.y = 35;
			addChild(bitmap);
			var label:Label = new Label();
			addChild(label);
			label.x = 62;
			label.y = 10;
			label.text = "binarize";
			label.textColor = 0x333333;
			loadBtn = new Btn();
			addChild(loadBtn);
			loadBtn.x = 90;
			loadBtn.y = 415;
			loadBtn.init({label: "load"});
			loadBtn.addEventListener(MouseEvent.CLICK, load, false, 0, true);
			operationList = new Array();
			operationList.push({label: "lower", value: BitmapDataUtils.THRESHOLD_LOW});
			operationList.push({label: "higher", value: BitmapDataUtils.THRESHOLD_HIGH});
			menu = new Menu();
			addChild(menu);
			menu.x = 282;
			menu.y = 10;
			menu.init({label: "operation", width: 80});
			menu.dataProvider = operationList;
			menu.initialize(0);
			menu.addEventListener(CompoEvent.SELECT, select, false, 0, true);
			menu.enabled = false;
			slider = new Slider();
			slider.x = 144;
			slider.y = 400;
			addChild(slider);
			slider.init({label: "threshold", width: 255, min: 0, max: 255, grid: 5, init: 127});
			slider.addEventListener(CompoEvent.CHANGE, change, false, 0, true);
			slider.enabled = false;
		}
		private function load(evt:MouseEvent):void {
			loader.load();
			menu.enabled = false;
			slider.enabled = false;
		}
		private function initialize(evt:Event):void {
			reset();
			bitmapData = evt.target.bitmapData;
			bitmap.bitmapData = bitmapData;
			bitmap.scaleX = bitmap.scaleY = 1;
			var bw:Number = 360/bitmap.width;
			var bh:Number = 360/bitmap.height;
			var scale:Number = Math.min(bw, bh);
			bitmap.scaleX = bitmap.scaleY = scale;
			bitmap.x = uint(360 - bitmap.width)/2 + 52;
			bitmap.y = uint(360 - bitmap.height)/2 + 35;
			apply();
		}
		private function select(evt:CompoEvent):void {
			operation = operationList[evt.value].value;
			apply();
		}
		private function change(evt:CompoEvent):void {
			threshold = evt.value;
			apply();
		}
		private function apply():void {
			bitmap.bitmapData = BitmapDataUtils.binarize(bitmapData, operation, threshold);
		}
		private function reset():void {
			menu.initialize(0);
			menu.enabled = true;
			operation = operationList[0].value
			slider.reset();
			slider.enabled = true;
			threshold = 127;
		}

	}

}


//////////////////////////////////////////////////
//	FileLoaderクラス
//////////////////////////////////////////////////

import flash.events.EventDispatcher;
import flash.net.FileReference;
import flash.net.FileFilter;
import flash.display.Loader;
import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.events.DataEvent;
import flash.events.IOErrorEvent;
import flash.events.HTTPStatusEvent;
import flash.events.SecurityErrorEvent;

class FileLoader extends EventDispatcher {
	private var file:FileReference;
	private static var typeFilter:Array;
	public var data:*;
	private var loader:Loader;
	public var bitmapData:BitmapData;

	public function FileLoader() {
		init();
	}

	private function init():void {
		file = new FileReference();
		file.addEventListener(Event.SELECT, select, false, 0, true);
		file.addEventListener(Event.CANCEL, cancel, false, 0, true);
		file.addEventListener(Event.OPEN, open, false, 0, true);
		file.addEventListener(ProgressEvent.PROGRESS, progress, false, 0, true);
		file.addEventListener(Event.COMPLETE, complete, false, 0, true);
		file.addEventListener(IOErrorEvent.IO_ERROR, ioerror, false, 0, true);
		file.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus, false, 0, true);
		file.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror, false, 0, true);
		var fileFilter:FileFilter = new FileFilter("画像ファイル", "*.jpg;*.gif;*.png");
		typeFilter = [fileFilter];
		loader = new Loader();
   		loader.contentLoaderInfo.addEventListener(Event.INIT, initialize, false, 0, true);
	}
	public function load():void {
		file.browse(typeFilter);
	}
	private function select(evt:Event):void {
		file.load();
		dispatchEvent(evt);
	}
	private function cancel(evt:Event):void {
		dispatchEvent(evt);
	}
	private function open(evt:Event):void {
		dispatchEvent(evt);
	}
	private function progress(evt:ProgressEvent):void {
		dispatchEvent(evt);
	}
	private function complete(evt:Event):void {
		data = evt.target.data;
		loader.loadBytes(data);
		dispatchEvent(evt);
	}
	private function ioerror(evt:IOErrorEvent):void {
		dispatchEvent(evt);
	}
	private function httpstatus(evt:HTTPStatusEvent):void {
		dispatchEvent(evt);
	}
	private function securityerror(evt:SecurityErrorEvent):void {
		dispatchEvent(evt);
	}
	private function initialize(evt:Event):void {
		bitmapData = null;
		var bitmap:Bitmap = Bitmap(evt.target.content);
		bitmapData = bitmap.bitmapData;
		dispatchEvent(evt);
	}

}


//////////////////////////////////////////////////
//	BitmapDataUtilsクラス
//////////////////////////////////////////////////

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;
import flash.filters.ColorMatrixFilter;

class BitmapDataUtils {
	private static var point:Point = new Point();
	private static var rLuma:Number = 0.212671;
	private static var gLuma:Number = 0.71516;
	private static var bLuma:Number = 0.072169;
	public static const THRESHOLD_LOW:String = "<=";
	public static const THRESHOLD_HIGH:String = ">=";

	public function BitmapDataUtils() {
	}

	public static function grayscale(bd:BitmapData):BitmapData {
		var bitmapData:BitmapData = new BitmapData(bd.width, bd.height, false);
		var colorMatrixFilter:ColorMatrixFilter = new ColorMatrixFilter([rLuma, gLuma, bLuma, 0, 0, rLuma, gLuma, bLuma, 0, 0, rLuma, gLuma, bLuma, 0, 0, 0, 0, 0, 1, 0]);
		var rect:Rectangle = new Rectangle(0, 0, bd.width, bd.height);
		bitmapData.applyFilter(bd, rect, point, colorMatrixFilter);
		return bitmapData;
	}
	public static function binarize(bd:BitmapData, operation:String, threshold:uint):BitmapData {
		var bitmapData:BitmapData = new BitmapData(bd.width, bd.height, true, 0xFFFFFFFF);
		var rect:Rectangle = new Rectangle(0, 0, bd.width, bd.height);
		bitmapData.threshold(bd, rect, point, operation, threshold, 0xFF000000, 255, false);
		return bitmapData;
	}
	public static function posterize(bd:BitmapData, tones:uint):BitmapData {
		if (tones < 2) return bd;
		var bitmapData:BitmapData = new BitmapData(bd.width, bd.height, false);
		var rect:Rectangle = new Rectangle(0, 0, bd.width, bd.height);
		var rPalette:Array = new Array();
		var gPalette:Array = new Array();
		var bPalette:Array = new Array();
		var min:uint = 0;
		var max:uint = 255;
		for (var t:uint = 1; t <= tones; t++) {
			max = Math.floor(256*t/tones);
			var color:uint = Math.floor(255*(t-1)/(tones-1));
			for (var n:uint = min; n < max; n++) {
				rPalette[n] = color << 16;
				gPalette[n] = color << 8;
				bPalette[n] = color;
			}
			min = max;
		}
		bitmapData.paletteMap(bd, rect, point, rPalette, gPalette, bPalette);
		return bitmapData;
	}

}


//////////////////////////////////////////////////
//	PhotoLoaderクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.net.URLRequest;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.HTTPStatusEvent;
import flash.events.SecurityErrorEvent;
import flash.display.Bitmap;
import flash.system.LoaderContext;

class PhotoLoader extends Sprite {
	private var loader:Loader;
	private var info:LoaderInfo;
	public var content:*;
	private var smoothing:Boolean;
	public static const IO_ERROR:String = IOErrorEvent.IO_ERROR;
	public static const HTTP_STATUS:String = HTTPStatusEvent.HTTP_STATUS;
	public static const SECURITY_ERROR:String = SecurityErrorEvent.SECURITY_ERROR;
	public static const INIT:String = Event.INIT;
	public static const COMPLETE:String = Event.COMPLETE;

	public function PhotoLoader() {
		loader = new Loader();
		info = loader.contentLoaderInfo;
	}

	public function load(file:String, s:Boolean = false):void {
		smoothing = s;
		info.addEventListener(IOErrorEvent.IO_ERROR, ioerror, false, 0, true);
		info.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus, false, 0, true);
		info.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror, false, 0, true);
		info.addEventListener(Event.INIT, initialize, false, 0, true);
		info.addEventListener(Event.COMPLETE, complete, false, 0, true);
		try {
			loader.load(new URLRequest(file), new LoaderContext(true));
		} catch (err:Error) {
			trace(err.message);
		}
	}
	public function unload():void {
		loader.unload();
	}
	private function ioerror(evt:IOErrorEvent):void {
		loader.unload();
		dispatchEvent(new Event(PhotoLoader.IO_ERROR));
	}
	private function httpstatus(evt:HTTPStatusEvent):void {
		dispatchEvent(new Event(PhotoLoader.HTTP_STATUS));
	}
	private function securityerror(evt:SecurityErrorEvent):void {
		dispatchEvent(new Event(PhotoLoader.SECURITY_ERROR));
	}
	private function initialize(evt:Event):void {
		if (smoothing) {
			content = Bitmap(info.content);
			content.smoothing = true;
		} else {
			content = info.content;
		}
		dispatchEvent(new Event(PhotoLoader.INIT));
	}
	private function complete(evt:Event):void {
		info.removeEventListener(IOErrorEvent.IO_ERROR, ioerror);
		info.removeEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus);
		info.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror);
		info.removeEventListener(Event.INIT, initialize);
		info.removeEventListener(Event.COMPLETE, complete);
		addChild(loader);
		dispatchEvent(new Event(PhotoLoader.COMPLETE));
	}
	public function centerize():void {
		content.x = -uint(content.width*0.5);
		content.y = -uint(content.height*0.5);
	}

}


//////////////////////////////////////////////////
//	Menuクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.display.Shape;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.AntiAliasType;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
import flash.events.MouseEvent;
import flash.geom.ColorTransform;

class Menu extends Sprite {
	public var id:uint;
	private var selectedID:uint;
	private var selectedItem:TextField;
	private var tab:Sprite;
	private var base:Shape;
	private var txt:TextField;
	private var label:String = "";
	private static var fontType:String = "_ゴシック";
	private var _width:uint = 60;
	private static var _height:uint = 20;
	private static var tHeight:uint = 20;
	private static var bColor:uint = 0xFFFFFF;
	private static var cColor:uint = 0x3165B5;
	private static var upColor:uint = 0x000000;
	private static var overColor:uint = 0xFFFFFF;
	private static var offColor:uint = 0x999999;
	private static var bColorTrans:ColorTransform;
	private static var cColorTrans:ColorTransform;
	private var child:MenuChild;
	private var dataList:Array;
	private var _enabled:Boolean = true;
	private var _selected:Boolean = false;

	public function Menu() {
	}

	public function init(option:Object):void {
		if (option.id != undefined) id = option.id;
		if (option.label != undefined) label = option.label;
		if (option.width != undefined) _width = option.width;
		draw();
	}
	private function draw():void {
		bColorTrans = new ColorTransform();
		bColorTrans.color = bColor;
		cColorTrans = new ColorTransform();
		cColorTrans.color = cColor;
		selectedItem = new TextField();
		tab = new Sprite();
		base = new Shape();
		txt = new TextField();
		addChild(selectedItem);
		addChild(tab);
		tab.addChild(base);
		tab.addChild(txt);
		selectedItem.x = _width + 5;
		selectedItem.y = 1;
		selectedItem.width = _width;
		selectedItem.height = _height - 1;
		selectedItem.type = TextFieldType.DYNAMIC;
		selectedItem.selectable = false;
		//selectedItem.embedFonts = true;
		//selectedItem.antiAliasType = AntiAliasType.ADVANCED;
		var tfl:TextFormat = new TextFormat();
		tfl.font = fontType;
		tfl.size = 12;
		tfl.align = TextFormatAlign.LEFT;
		selectedItem.defaultTextFormat = tfl;
		createBox(base, _width, _height);
		txt.y = 1;
		txt.width = _width;
		txt.height = _height - 1;
		txt.type = TextFieldType.DYNAMIC;
		txt.selectable = false;
		//txt.embedFonts = true;
		//txt.antiAliasType = AntiAliasType.ADVANCED;
		var tf:TextFormat = new TextFormat();
		tf.font = fontType;
		tf.size = 12;
		tf.align = TextFormatAlign.CENTER;
		txt.defaultTextFormat = tf;
		txt.text = label;
		_up();
		enabled = true;
		tab.mouseChildren = false;
	}
	private function rollOver(evt:MouseEvent):void {
		_over();
	}
	private function rollOut(evt:MouseEvent):void {
		up();
	}
	private function press(evt:MouseEvent):void {
		_over();
	}
	private function release(evt:MouseEvent):void {
		_over();
	}
	private function click(evt:MouseEvent):void {
		_over();
		child.opencloseMenu();
	}
	private function up():void {
		if (_selected) {
			_over();
		} else {
			_up();
		}
	}
	private function _up():void {
		txt.textColor = upColor;
		base.transform.colorTransform = bColorTrans;
	}
	private function _over():void {
		txt.textColor = overColor;
		base.transform.colorTransform = cColorTrans;
	}
	private function _off():void {
		txt.textColor = offColor;
		base.transform.colorTransform = bColorTrans;
	}
	public function set dataProvider(list:Array):void {
		dataList = list;
		if (dataList.length > 0) addChildren();
	}
	private function addChildren():void {
		child = new MenuChild(dataList, this);
		addChild(child);
		child.y = tHeight;
		child.visible = false;
		child.addEventListener(MouseEvent.CLICK, select, false, 0, true);
	}
	private function mouseDown(evt:MouseEvent):void {
		if (!hitTestPoint(stage.mouseX, stage.mouseY, true)) {
		child.closeMenu();
		}
	}
	public function initialize(param:uint):void {
		selectedID = param;
		child.selectItem(selectedID);
		show();
	}
	private function select(evt:MouseEvent):void {
		selectedID = evt.target.id;
		var e:CompoEvent = new CompoEvent(CompoEvent.SELECT, selectedID);
		dispatchEvent(e);
		show();
	}
	public function get selected():Boolean {
		return _selected;
	}
	public function set selected(param:Boolean):void {
		_selected = param;
		if (_enabled) up();
		show();
	}
	public function get enabled():Boolean {
		return _enabled;
	}
	public function set enabled(param:Boolean):void {
		_enabled = param;
		tab.buttonMode = _enabled;
		tab.mouseEnabled = _enabled;
		tab.useHandCursor = _enabled;
		if (_enabled) {
			_up();
			tab.addEventListener(MouseEvent.MOUSE_OVER, rollOver, false, 0, true);
			tab.addEventListener(MouseEvent.MOUSE_OUT, rollOut, false, 0, true);
			tab.addEventListener(MouseEvent.MOUSE_DOWN, press, false, 0, true);
			tab.addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
			tab.addEventListener(MouseEvent.CLICK, click, false, 0, true);
			stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown, false, 0, true);
		} else {
			_off();
			tab.removeEventListener(MouseEvent.MOUSE_OVER, rollOver);
			tab.removeEventListener(MouseEvent.MOUSE_OUT, rollOut);
			tab.removeEventListener(MouseEvent.MOUSE_DOWN, press);
			tab.removeEventListener(MouseEvent.MOUSE_UP, release);
			tab.removeEventListener(MouseEvent.CLICK, click);
			stage.removeEventListener(MouseEvent.MOUSE_DOWN, mouseDown);
		}
	}
	private function createBox(target:Shape, w:uint, h:uint):void {
		target.graphics.clear();
		target.graphics.beginFill(bColor);
		target.graphics.drawRect(0, 0, w, h);
		target.graphics.endFill();
	}
	private function show():void {
		var str:String = dataList[selectedID].label;
		selectedItem.text = String(str);
	}

}


import flash.display.Sprite;
import flash.display.Shape;
import flash.events.MouseEvent;
import flash.filters.DropShadowFilter;

class MenuChild extends Sprite {
	private var _width:uint = 100;
	private var _height:uint;
	private static var tHeight:uint = 20;
	private static var bColor:uint = 0xFFFFFF;
	private static var sColor:uint = 0x000000;
	private var dataList:Array;
	private var max:uint;
	private var itemList:Array;
	private var maxWidth:uint = 0;
	private var back:Shape;
	private var shade:DropShadowFilter;
	private var menu:Menu;
	private var opened:Boolean = false;
	private var selectedID:uint;

	public function MenuChild(list:Array, m:Menu) {
		dataList = list;
		max = dataList.length;
		_height = tHeight*max;
		menu = m;
		init();
	}

	private function init():void {
		back = new Shape();
		addChild(back);
		shade = new DropShadowFilter(1, 90, sColor, 0.5, 4, 4, 2, 3, false, false);
		back.filters = [shade];
		itemList = new Array();
		for (var n:uint = 0; n < max; n++) {
			var item:MenuItem = new MenuItem({id: n, label: dataList[n].label});
			addChild(item);
			item.y = tHeight*n;
			itemList.push(item);
			item.addEventListener(MouseEvent.CLICK, select, false, 0, true);
			resizeWidth(item);
		}
	}
	private function select(evt:MouseEvent):void {
		closeMenu();
		selectedID = MenuItem(evt.currentTarget).id;
		checkItem();
	}
	public function selectItem(id:uint):void {
		selectedID = id;
		checkItem();
	}
	public function opencloseMenu():void {
		if (!opened) {
			openMenu();
		} else {
			closeMenu();
		}
	}
	private function openMenu():void {
		opened = true;
		visible = true;
		menu.selected = true;
	}
	public function closeMenu():void {
		opened = false;
		visible = false;
		menu.selected = false;
	}
	private function checkItem():void {
		for (var n:uint = 0; n < itemList.length; n++) {
			var item:MenuItem = itemList[n];
			if (n == selectedID) {
				item.selected = true;
			} else {
				item.selected = false;
			}
		}
	}
	private function resizeWidth(item:MenuItem):void {
		if (item._width > maxWidth) maxWidth = item._width;
		if (itemList.length >= max) resize();
	}
	private function resize():void {
		_width = maxWidth;
		createBox(back, _width, _height);
		for (var n:uint = 0; n < max; n++) {
			var item:MenuItem = itemList[n];
			item._width = maxWidth;
			item.txt.width = item._width - 20;
			createBox(item.base, item._width, item._height);
		}
	}
	private function createBox(target:Shape, w:uint, h:uint):void {
		target.graphics.clear();
		target.graphics.beginFill(bColor);
		target.graphics.drawRect(0, 0, w, h);
		target.graphics.endFill();
	}

}


import flash.display.Sprite;
import flash.display.Shape;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.AntiAliasType;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
import flash.events.MouseEvent;
import flash.geom.ColorTransform;

class MenuItem extends Sprite {
	public var id:uint;
	private var item:Sprite;
	public var base:Shape;
	public var txt:TextField;
	private var check:TextField;
	public var _width:uint = 100;
	public var _height:uint = 20;
	private var label:String = "";
	private static var fontType:String = "_ゴシック";
	private var mark:String = String.fromCharCode(10003);
	private static var checkType:String = "_ゴシック";
	private static var bColor:uint = 0xFFFFFF;
	private static var cColor:uint = 0x3165B5;
	private static var upColor:uint = 0x000000;
	private static var overColor:uint = 0xFFFFFF;
	private static var bColorTrans:ColorTransform;
	private static var cColorTrans:ColorTransform;
	private var _selected:Boolean = false;

	public function MenuItem(option:Object) {
		if (option.id != undefined) id = option.id;
		if (option.label) label = option.label;
		init();
	}

	private function init():void {
		bColorTrans = new ColorTransform();
		bColorTrans.color = bColor;
		cColorTrans = new ColorTransform();
		cColorTrans.color = cColor;
		item = new Sprite();
		base = new Shape();
		txt = new TextField();
		check = new TextField();
		addChild(item);
		item.addChild(base);
		item.addChild(txt);
		item.addChild(check);
		txt.x = 20;
		txt.y = 1;
		txt.width = _width;
		txt.height = _height - 1;
		txt.type = TextFieldType.DYNAMIC;
		txt.selectable = false;
		//txt.embedFonts = true;
		//txt.antiAliasType = AntiAliasType.ADVANCED;
		var tf:TextFormat = new TextFormat();
		tf.font = fontType;
		tf.size = 12;
		tf.align = TextFormatAlign.LEFT;
		txt.defaultTextFormat = tf;
		txt.text = label;
		_width = txt.textWidth + 35;
		check.x = 3;
		check.y = -1;
		check.width = 14;
		check.height = 22;
		check.type = TextFieldType.DYNAMIC;
		check.selectable = false;
		//check.embedFonts = true;
		//check.antiAliasType = AntiAliasType.ADVANCED;
		var tfc:TextFormat = new TextFormat();
		tfc.font = checkType;
		tfc.size = 12;
		tfc.align = TextFormatAlign.CENTER;
		check.defaultTextFormat = tfc;
		check.text = mark;
		check.visible = false;
		buttonMode = true;
		mouseEnabled = true;
		useHandCursor = true;
		_up();
		mouseChildren = false;
		addEventListener(MouseEvent.MOUSE_OVER, rollOver, false, 0, true);
		addEventListener(MouseEvent.MOUSE_OUT, rollOut, false, 0, true);
		addEventListener(MouseEvent.MOUSE_DOWN, press, false, 0, true);
		addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
		addEventListener(MouseEvent.CLICK, click, false, 0, true);
	}
	private function rollOver(evt:MouseEvent):void {
		_over();
	}
	private function rollOut(evt:MouseEvent):void {
		_up();
	}
	private function press(evt:MouseEvent):void {
		_over();
	}
	private function release(evt:MouseEvent):void {
		_up();
	}
	private function click(evt:MouseEvent):void {
		_up();
	}
	private function _up():void {
		txt.textColor = upColor;
		check.textColor = upColor;
		base.transform.colorTransform = bColorTrans;
	}
	private function _over():void {
		txt.textColor = overColor;
		check.textColor = overColor;
		base.transform.colorTransform = cColorTrans;
	}
	public function get selected():Boolean {
		return _selected;
	}
	public function set selected(param:Boolean):void {
		_selected = param;
		check.visible = _selected;
	}

}


//////////////////////////////////////////////////
//	 Sliderクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.display.Shape;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.AntiAliasType;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
import flash.filters.DropShadowFilter;
import flash.filters.GlowFilter;
import flash.geom.Rectangle;
import flash.geom.Matrix;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;
import flash.events.Event;
import flash.events.MouseEvent;

class Slider extends Sprite {
	private var hole:Shape;
	private var line:Sprite;
	private var thumb:Sprite;
	private var light:Shape;
	private var shade:Shape;
	private var base:Shape;
	private var title:TextField;
	private var txt:TextField;
	private var label:String = "";
	private static var fontType:String = "_ゴシック";
	private var _width:uint = 100;
	private static var tHeight:uint = 20;
	private static var bHeight:uint = 30;
	private var grid:uint = 5;
	private static var bColor:uint = 0xFFFFFF;
	private static var tColor:uint = 0x666666;
	private static var gColor:uint = 0x999999;
	private static var mColor:uint = 0x333333;
	private static var bgColor:uint = 0x0099FF;
	private static var sColor:uint = 0x000000;
	private static var offColor:uint = 0x999999;
	private var min:Number = 0;
	private var max:Number = 100;
	private var initValue:Number = 0;
	private var blueGlow:GlowFilter;
	private var shadeDrop:DropShadowFilter;
	private var value:Number;
	private var _enabled:Boolean = true;

	public function Slider() {
	}

	public function init(option:Object):void {
		if (option.label != undefined) label = option.label;
		if (option.width != undefined) _width = option.width;
		if (option.min != undefined) min = option.min;
		if (option.max != undefined) max = option.max;
		if (option.grid != undefined) grid = option.grid;
		if (option.init != undefined) initValue = option.init;
		draw();
	}
	private function draw():void {
		shadeDrop = new DropShadowFilter(1, 90, sColor, 0.5, 4, 4, 2, 3, false, false);
		blueGlow = new GlowFilter(bgColor, 0.6, 5, 5, 2, 3, false, true);
		hole = new Shape();
		line = new Sprite();
		title = new TextField();
		txt = new TextField();
		thumb = new Sprite();
		shade = new Shape();
		light = new Shape();
		base = new Shape();
		addChild(hole);
		addChild(line);
		addChild(title);
		addChild(txt);
		addChild(thumb);
		thumb.addChild(shade);
		thumb.addChild(light);
		thumb.addChild(base);
		hole.y = bHeight;
		createGradientHole(hole, _width, 3);
		line.y = bHeight;
		createGrid(line);
		title.height = tHeight-1;
		title.type = TextFieldType.DYNAMIC;
		title.selectable = false;
		//title.embedFonts = true;
		//title.antiAliasType = AntiAliasType.ADVANCED;
		title.textColor = tColor;
		title.autoSize = TextFieldAutoSize.LEFT;
		var tfl:TextFormat = new TextFormat();
		tfl.font = fontType;
		tfl.size = 12;
		tfl.align = TextFormatAlign.LEFT;
		title.defaultTextFormat = tfl;
		title.text = label;
		//txt.x = title.textWidth;
		txt.x = 50;
		txt.width = 50;
		txt.height = tHeight-1;
		txt.selectable = false;
		//txt.embedFonts = true;
		//txt.antiAliasType = AntiAliasType.ADVANCED;
		var tfr:TextFormat = new TextFormat();
		tfr.font = fontType;
		tfr.size = 12;
		tfr.align = TextFormatAlign.RIGHT;
		txt.defaultTextFormat = tfr;
		reset();
		thumb.y = bHeight;
		createThumb(shade, 8, 20, 12, sColor);
		shade.filters = [shadeDrop];
		createThumb(light, 8, 20, 12, bgColor);
		light.filters = [blueGlow];
		createThumb(base, 8, 20, 12, bColor);
		_up();
		enabled = true;
		thumb.mouseChildren = false;
	}
	private function rollOver(evt:MouseEvent):void {
		_over();
	}
	private function rollOut(evt:MouseEvent):void {
		_up();
	}
	private function press(evt:MouseEvent):void {
		_down();
		var rect:Rectangle = new Rectangle(0, bHeight, _width, 0);
		thumb.startDrag(false, rect);
		thumb.addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
		stage.addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
		stage.addEventListener(Event.MOUSE_LEAVE, leave, false, 0, true);
		thumb.addEventListener(Event.ENTER_FRAME, change, false, 0, true);
	}
	private function release(evt:MouseEvent):void {
		_up();
		thumb.stopDrag();
		checkValue();
		var e:CompoEvent = new CompoEvent(CompoEvent.SELECT, value);
		dispatchEvent(e);
		thumb.removeEventListener(MouseEvent.MOUSE_UP, release);
		stage.removeEventListener(MouseEvent.MOUSE_UP, release);
		stage.removeEventListener(Event.MOUSE_LEAVE, leave);
		thumb.removeEventListener(Event.ENTER_FRAME, change);
	}
	private function leave(evt:Event):void {
		_up();
		thumb.stopDrag();
		checkValue();
		var e:CompoEvent = new CompoEvent(CompoEvent.SELECT, value);
		dispatchEvent(e);
		thumb.removeEventListener(MouseEvent.MOUSE_UP, release);
		stage.removeEventListener(MouseEvent.MOUSE_UP, release);
		stage.removeEventListener(Event.MOUSE_LEAVE, leave);
		thumb.removeEventListener(Event.ENTER_FRAME, change);
	}
	private function _up():void {
		light.visible = false;
	}
	private function _over():void {
		light.visible = true;
	}
	private function _down():void {
		light.visible = true;
	}
	private function _off():void {
		light.visible = false;
		txt.textColor = offColor;
	}
	private function change(evt:Event):void {
		_down();
		checkValue();
		var e:CompoEvent = new CompoEvent(CompoEvent.CHANGE, value);
		dispatchEvent(e);
	}
	private function checkValue():void {
		value = min + Math.round(thumb.x/_width*(max-min));
		txt.text = String(value);
	}
	public function get enabled():Boolean {
		return _enabled;
	}
	public function set enabled(param:Boolean):void {
		_enabled = param;
		if (!_enabled) _off();
		thumb.buttonMode = _enabled;
		thumb.mouseEnabled = _enabled;
		thumb.useHandCursor = _enabled;
		if (_enabled) {
			thumb.addEventListener(MouseEvent.MOUSE_OVER, rollOver, false, 0, true);
			thumb.addEventListener(MouseEvent.MOUSE_OUT, rollOut, false, 0, true);
			thumb.addEventListener(MouseEvent.MOUSE_DOWN, press, false, 0, true);
			thumb.addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
		} else {
			thumb.removeEventListener(MouseEvent.MOUSE_OVER, rollOver);
			thumb.removeEventListener(MouseEvent.MOUSE_OUT, rollOut);
			thumb.removeEventListener(MouseEvent.MOUSE_DOWN, press);
			thumb.removeEventListener(MouseEvent.MOUSE_UP, release);
		}
	}
	public function reset():void {
		thumb.x = _width*(initValue-min)/(max-min);
		value = initValue;
		txt.text = String(value);
	}
	private function createGrid(target:Sprite):void {
		for (var n:uint = 0; n <= grid; n++) {
			var w:uint = Math.floor(_width/grid);
			if (n == 0 || n == grid*0.5 || n == grid) {
				createGridLine(target, w*n, mColor);
				var _txt:TextField = new TextField();
				target.addChild(_txt);
				_txt.x = w*n - 20;
				_txt.y = 13;
				_txt.width = 40;
				_txt.height = 14;
				_txt.selectable = false;
				//_txt.embedFonts = true;
				//_txt.antiAliasType = AntiAliasType.ADVANCED;
				//_txt.antiAliasType = AntiAliasType.NORMAL;
				_txt.textColor = mColor;
				var tfc:TextFormat = new TextFormat();
				tfc.font = fontType;
				tfc.size = 8;
				tfc.align = TextFormatAlign.CENTER;
				_txt.defaultTextFormat = tfc;
				if (n == 0) _txt.text = String(min);
				if (n == grid*0.5) _txt.text = String(min+(max-min)*0.5);
				if (n == grid) _txt.text = String(max);
			} else {
				createGridLine(target, w*n, gColor);
			}
		}
	}
	private function createThumb(target:Shape, w:uint, h:uint, y:uint, color:uint, alpha:Number = 1):void {
		target.graphics.beginFill(color, alpha);
		target.graphics.drawRoundRect(-w*0.5, -y, w, h, w);
		target.graphics.endFill();
	}
	private function createGradientHole(target:Shape, w:uint, c:Number):void {
		var colors:Array = [0x000000, 0x000000];
		var alphas:Array = [0.4, 0];
		var ratios:Array = [0, 255];
		var matrix:Matrix = new Matrix();
		matrix.createGradientBox(w+c*2, c*2, 0.5*Math.PI, -c, -c);
		target.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, matrix, SpreadMethod.PAD, InterpolationMethod.RGB, 0);
		target.graphics.drawRoundRect(-c, -c, w+c*2, c*2, c*2);
		target.graphics.endFill();
	}
	private function createGridLine(target:Sprite, x:uint, color:uint):void {
		target.graphics.lineStyle(0, color);
		target.graphics.moveTo(x, 8);
		target.graphics.lineTo(x, 12);
	}

}


//////////////////////////////////////////////////
// CompoEventクラス
//////////////////////////////////////////////////

import flash.events.Event;

class CompoEvent extends Event {
	public static const SELECT:String = "select";
	public static const CHANGE:String = "change";
	public var value:*;

	public function CompoEvent(type:String, value:*) {
		super(type);
		this.value = value;
	}

	public override function clone():Event {
		return new CompoEvent(type, value);
	}

}


//////////////////////////////////////////////////
//	Labelクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.TextFieldAutoSize;
import flash.text.AntiAliasType;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;

class Label extends Sprite {
	private var txt:TextField;
	private static var fontType:String = "_ゴシック";
	private static var _height:uint = 20;

	public function Label() {
		draw();
	}

	private function draw():void {
		txt = new TextField();
		addChild(txt);
		txt.height = _height - 1;
		txt.autoSize = TextFieldAutoSize.LEFT;
		txt.type = TextFieldType.DYNAMIC;
		txt.selectable = false;
		//txt.embedFonts = true;
		//txt.antiAliasType = AntiAliasType.ADVANCED;
		var tf:TextFormat = new TextFormat();
		tf.font = fontType;
		tf.size = 12;
		tf.align = TextFormatAlign.LEFT;
		txt.defaultTextFormat = tf;
	}
	public function set text(param:String):void {
		txt.text = param;
	}
	public function set textColor(param:uint):void {
		txt.textColor = param;
	}

}


//////////////////////////////////////////////////
// Btnクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.display.Shape;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.AntiAliasType;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
import flash.filters.GlowFilter;
import flash.events.MouseEvent;

class Btn extends Sprite {
	public var id:uint;
	private var shade:Shape;
	private var bottom:Shape;
	private var light:Shape;
	private var base:Shape;
	private var txt:TextField;
	private var label:String = "";
	private static var fontType:String = "_ゴシック";
	private var _width:uint = 60;
	private static var _height:uint = 20;
	private static var corner:uint = 5;
	private var type:uint = 1;
	private static var bColor:uint = 0xFFFFFF;
	private static var sColor:uint = 0x000000;
	private static var upColor:uint = 0x666666;
	private static var overColor:uint = 0x333333;
	private static var offColor:uint = 0x999999;
	private static var gColor:uint = 0x0099FF;
	private var blueGlow:GlowFilter;
	private var shadeGlow:GlowFilter;
	private var _clicked:Boolean = false;
	private var _enabled:Boolean = true;

	public function Btn() {
	}

	public function init(option:Object):void {
		if (option.id != undefined) id = option.id;
		if (option.label != undefined) label = option.label;
		if (option.width != undefined) _width = option.width;
		if (option.type != undefined) type = option.type;
		draw();
	}
	private function draw():void {
		switch (type) {
		case 1 :
			bColor = 0xFFFFFF;
			sColor = 0x000000;
			upColor = 0x666666;
			overColor = 0x333333;
			offColor = 0x999999;
			break;
		case 2 :
			bColor = 0x000000;
			sColor = 0xFFFFFF;
			upColor = 0x666666;
			overColor = 0x999999;
			offColor = 0x333333;
			break;
		}
		blueGlow = new GlowFilter(gColor, 0.6, 5, 5, 2, 3, false, true);
		shadeGlow = new GlowFilter(sColor, 0.3, 4, 4, 2, 3, false, true);
		shade = new Shape();
		bottom = new Shape();
		light = new Shape();
		base = new Shape();
		txt = new TextField();
		addChild(shade);
		addChild(bottom);
		addChild(light);
		addChild(base);
		addChild(txt);
		createBase(shade, _width, _height, corner, sColor);
		shade.filters = [shadeGlow];
		createBase(bottom, _width, _height, corner, sColor, 0.3);
		createBase(light, _width, _height, corner, gColor);
		light.filters = [blueGlow];
		createBase(base, _width, _height, corner, bColor);
		txt.x = -_width*0.5;
		txt.y = -_height*0.5;
		txt.width = _width;
		txt.height = _height - 1;
		txt.type = TextFieldType.DYNAMIC;
		txt.selectable = false;
		//txt.embedFonts = true;
		//txt.antiAliasType = AntiAliasType.ADVANCED;
		var tf:TextFormat = new TextFormat();
		tf.font = fontType;
		tf.size = 12;
		tf.align = TextFormatAlign.CENTER;
		txt.defaultTextFormat = tf;
		txt.text = label;
		enabled = true;
		mouseChildren = false;
	}
	private function rollOver(evt:MouseEvent):void {
		_over();
	}
	private function rollOut(evt:MouseEvent):void {
		_up();
	}
	private function press(evt:MouseEvent):void {
		_down();
	}
	private function release(evt:MouseEvent):void {
		_up();
	}
	private function click(evt:MouseEvent):void {
	}
	private function _up():void {
		txt.y = -_height*0.5;
		txt.textColor = upColor;
		base.y = -1;
		light.visible = false;
		light.y = -1;
	}
	private function _over():void {
		txt.y = -_height*0.5;
		txt.textColor = overColor;
		base.y = -1;
		light.visible = true;
		light.y = -1;
	}
	private function _down():void {
		txt.y = -_height*0.5 + 1;
		txt.textColor = overColor;
		base.y = 0;
		light.visible = true;
		light.y = 0;
	}
	private function _off():void {
		txt.y = -_height*0.5 + 1;
		txt.textColor = offColor;
		base.y = 0;
		light.visible = false;
		light.y = 0;
	}
	public function get clicked():Boolean {
		return _clicked;
	}
	public function set clicked(param:Boolean):void {
		_clicked = param;
		enabled = !_clicked;
		if (_clicked) {
			_down();
		} else {
			_up();
		}
	}
	public function get enabled():Boolean {
		return _enabled;
	}
	public function set enabled(param:Boolean):void {
		_enabled = param;
		buttonMode = _enabled;
		mouseEnabled = _enabled;
		useHandCursor = _enabled;
		if (_enabled) {
			_up();
			addEventListener(MouseEvent.MOUSE_OVER, rollOver, false, 0, true);
			addEventListener(MouseEvent.MOUSE_OUT, rollOut, false, 0, true);
			addEventListener(MouseEvent.MOUSE_DOWN, press, false, 0, true);
			addEventListener(MouseEvent.MOUSE_UP, release, false, 0, true);
			addEventListener(MouseEvent.CLICK, click, false, 0, true);
		} else {
			_off();
			removeEventListener(MouseEvent.MOUSE_OVER, rollOver);
			removeEventListener(MouseEvent.MOUSE_OUT, rollOut);
			removeEventListener(MouseEvent.MOUSE_DOWN, press);
			removeEventListener(MouseEvent.MOUSE_UP, release);
			removeEventListener(MouseEvent.CLICK, click);
		}
	}
	private function createBase(target:Shape, w:uint, h:uint, c:uint, color:uint, alpha:Number = 1):void {
		target.graphics.beginFill(color, alpha);
		target.graphics.drawRoundRect(-w*0.5, -h*0.5, w, h, c*2);
		target.graphics.endFill();
	}

}