Object vs Class

by uwi 03 Nov 2009

Talk

makc3d at 05 Nov 2009 12:38
I have "class"/"class directly" 375/328 ms, the opposite of author results
uwi at 06 Nov 2009 09:34
Recalculating many times, the two appear to be alike, don't they?
Embed

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/4A4g
 */

package {

import flash.display.*;
import flash.geom.*;
import flash.events.*;
import flash.text.*;
import flash.utils.*;

public class Main extends Sprite
{
    static private const N:uint = 500000;
    
    private function _init():void
    {
        _debug(
            "各テスト " + N + " 回処理させた計算結果 [単位 ： ミリ秒]\n" +
            "(誤差は多少生じます)\n"
        );
        
        _measure("ループのみ", function ():void
        {
            for (var i:uint = 0; i < N; i++) {
                
            }
        });
        
        _measure("Object", function ():void
        {
            for (var i:uint = 0; i < N; i++) {
                var b : Object = {x : 123.45, y : 678};
            }
        });
        
        _measure("Class", function ():void
        {
            for (var i:uint = 0; i < N; i++) {
                var b : Bullet = new Bullet(123.45, 678);
            }
        });
        
        _measure("Class Directly", function ():void
        {
            for (var i:uint = 0; i < N; i++) {
                var b : Bullet2 = new Bullet2();
                b.x = 123.45;
                b.y = 678;
            }
        });
        
        _debug("\n結果については言及しませんので, 各自ご判断ください.");
    }
    
    private var _field:TextField;
    private var _time:uint;
    
    public function Main():void
    {
        _setup();
        _init();
    }
    
    private function _measure(title:String, func:Function, ...params):void
    {
        _time = getTimer();
        func.apply(null, params);
        _time = getTimer() - _time;
        
        _debug("[ " + title + " ] --> " + _time + " ms");
    }
    
    private function _debug(log:String):void
    {
        _field.appendText(log + "\n");
    }
    
    private function _setup():void
    {
        _field = new TextField();
        _field.width = stage.stageWidth - 40;
        _field.height = stage.stageHeight - 60;
        _field.x = 20;
        _field.y = 60;
        _field.multiline = true;
        _field.wordWrap = true;
        
        var format:TextFormat = _field.defaultTextFormat;
        format.font = "_sans";
        _field.defaultTextFormat = format;
        
        addChild(_field);
        
        var button:Sprite = new Sprite();
        button.graphics.lineStyle(1, 0xBBBBBB);
        button.graphics.beginFill(0xEEEEEE);
        button.graphics.drawRoundRect(0, 0, 100, 20, 5, 5);
        button.graphics.endFill();
        
        addChild(button);
        
        button.x = 20;
        button.y = 20;
        button.mouseChildren = false;
        button.buttonMode = true;
        
        var field:TextField = new TextField();
        field.width = 100;
        field.height = 20;
        field.htmlText = "<p align='center'><font face='_sans'>再計算</span></p>";
        
        button.addChild(field);
        
        button.addEventListener(MouseEvent.CLICK, function ():void
        {
            _field.text = "";
            _init();
        });
    }
}

}

class Bullet
{
    public var x : Number;
    public var y : int;
    
    public function Bullet(x : Number, y : int){
        this.x = x;
        this.y = y;
    }
}

class Bullet2
{
    public var x : Number;
    public var y : int;
}