forked from: Sound Spectrum Ring

もはや、リングですらないという。
* 
* よりデジタル風にしてみた。 
* 
* sound spectrum
* サウンドスペクトル表示
* 
* ♪使用音楽素材について♪
* 音楽素材/魔王魂（http://maoudamashii.jokersounds.com/）の素材を使わせていただきました。
* ありがとうございます。
*

by takishiki 26 Aug 2010

• Forked from takishiki's Sound Spectrum Ring
• Diff: 68
• Related works: 5
Embed

/**
 * Copyright takishiki ( http://wonderfl.net/user/takishiki )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/1RLR
 */

// forked from takishiki's Sound Spectrum Ring
/*
 * もはや、リングですらないという。
 * 
 * よりデジタル風にしてみた。 
 * 
 * sound spectrum
 * サウンドスペクトル表示
 * 
 * ♪使用音楽素材について♪
 * 音楽素材/魔王魂（http://maoudamashii.jokersounds.com/）の素材を使わせていただきました。
 * ありがとうございます。
 * 
 */

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.display.Graphics;
    import flash.geom.Point;
    import flash.system.Security;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundTransform;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    
    
    [SWF(width = 465, height = 465, frameRate = 30, backgroundColor = 0x000000)]
    public class Main extends Sprite
    {
        // 定数
        private const FFT_MODE    :Boolean = false;
        private const COLOR        :Array = [0xFF0000, 0xFFFF00, 0x990000, 0x999900];
        // 変数
        private var _sp            :Sprite;
        
        // constructor
        public function Main():void {
            stage.frameRate = 30;
            
            _sp = new Sprite();
            _sp.x = 0;
            _sp.y = 0;
            this.addChild(_sp);
            
            // mp3
            var snd:Sound = new Sound();
            Security.loadPolicyFile("http://mutast.heteml.jp/crossdomain.xml");
            var req:URLRequest = new URLRequest("http://vaindog.raindrop.jp/wonderfl/sound/bgm_maoudamashii_cyber06.mp3");
            var context:SoundLoaderContext = new SoundLoaderContext(10, true);
            snd.load(req, context);
            
            var channel:SoundChannel = snd.play();
            var transform:SoundTransform = new SoundTransform();
            transform.volume = 0.5;    // ボリュームを半分に
            transform.pan = 0.0;    // パンは中央
            channel.soundTransform = transform;
            // 再生終了時
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
            
            // フレーム処理
            this.addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
        
        // 再生終了時
        private function onPlaybackComplete(event:Event):void {
            this.removeEventListener(Event.ENTER_FRAME, onEnterFrame);
            _sp.graphics.clear();
        }
        
        // フレーム処理
        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const CHANNEL_LENGTH:int = 256;
            const MAX:int = 300;
            const OFFSET:int = stage.stageWidth / 3;
            
            var color:uint;
            var i:int;
            var index:uint;
            var n:Number;
            var pos_y:Number;
            
            var w:int = stage.stageWidth;
            var h:int = stage.stageHeight;
            
            var g:Graphics = _sp.graphics;
            g.clear();
            
            SoundMixer.computeSpectrum(bytes, FFT_MODE, 0);
            
            // L
            index = 0;
            for (i = 0; i < CHANNEL_LENGTH; i++) {
                n = bytes.readFloat() * MAX;
                
                if (i % 8 != 0) continue;
                
                color = n >= 0 ? COLOR[index] : COLOR[index + 2];
                pos_y = h / CHANNEL_LENGTH * i;
                
                g.lineStyle(1, color, 0.8);
                g.beginFill(color, 0.5);
                g.drawRect(OFFSET, pos_y, n, 8);
                g.endFill();
            }
            
            // R
            index = 1;
            for (i = 0; i < CHANNEL_LENGTH; i++) {
                n = bytes.readFloat() * MAX;
                
                if (i % 8 != 0) continue;
                
                color = n >= 0 ? COLOR[index] : COLOR[index + 2];
                pos_y = h / CHANNEL_LENGTH * i;
                
                g.lineStyle(1, color, 0.8);
                g.beginFill(color, 0.5);
                g.drawRect(w - OFFSET, pos_y, -n, 8);
                g.endFill();
            }
        }
    }
}